Erreur de Procédure trop grande dans les Macros VBA (Excel)

Je suis Procedure too Large Error dans une macro VBA.

Je suis à l'aide de MS-Excel 2003.

Veuillez ne jamais rédiger des procédures qui ont plus de 65534 lignes de code.
Je crois que c'est pas le nombre de lignes qui compte. On peut obtenir cette erreur en 4k lignes. C'est la taille de la procédure. La procédure, lors de la compilation ne peut pas dépasser 64kilobytes. Niraj, briser la procédure en petites parties et si vous avez enregistré une macro puis supprimez pas pertinent de code.
Grâce Siddharth
Plus de 64 ko. Je suis impressionné. Et perplexe.
Tout comme une note de côté, si vous êtes venus ici à partir de google, il est probable que vous voyez ce parce que vous avez quitté l'enregistreur de macro en cours d'exécution pour un long moment

OriginalL'auteur Code Hungry | 2012-07-12

Vous obtiendrez cette erreur si votre procédure est plus de 64 ko. Ce sont certaines des choses que vous pouvez compacter votre code

1) se débarrasser de code répétitif. Voir cet exemple

Sub Sample()
    Range("A1") = "Blah Blah"
    Range("A2") = "Blah Blah"
    Range("A3") = "Blah Blah"
    Range("A4") = "Blah Blah"
    Range("A5") = "Blah Blah"
    Range("A6") = "Blah Blah"
    Range("A7") = "Blah Blah"
End Sub

Ce code peut être écrit comme

Sub Sample()
    For i = 1 To 7
        Range("A" & i) = "Blah Blah"
    Next i
End Sub

Un autre exemple

Sub Sample()
    Range("A1") = (Range("A1") * 10) + (Range("A1") + 30) + (Range("A1") / 30)
    Range("A5") = (Range("A5") * 10) + (Range("A5") + 30) + (Range("A5") / 30)
    Range("A11") = (Range("A11") * 10) + (Range("A11") + 30) + (Range("A11") / 30)
    Range("A6") = (Range("A6") * 10) + (Range("A6") + 30) + (Range("A6") / 30)
    Range("A8") = (Range("A8") * 10) + (Range("A8") + 30) + (Range("A8") / 30)
    Range("A56") = (Range("A56") * 10) + (Range("A56") + 30) + (Range("A56") / 30)
End Sub

Ce code peut être écrit comme

Sub Sample()
    Range("A1") = GetVal(Range("A1"))
    Range("A5") = GetVal(Range("A5"))
    Range("A11") = GetVal(Range("A11"))
    Range("A6") = GetVal(Range("A6"))
    Range("A8") = GetVal(Range("A8"))
    Range("A56") = GetVal(Range("A56"))
End Sub

Function GetVal(rng As Range) As Variant
    GetVal = (rng.Value * 10) + (rng.Value + 30) + (rng.Value / 30)
End Function

Cela permettra d'assurer que vous couper vers le bas sur l'espace et ne pas écrire de code répétitif.

2) Si vous le code généré par la macro, alors vous pouvez obtenir quelque chose comme cela. Se débarrasser de l'inutile code comme ActiveWindow.ScrollRow = 8968

Option Explicit
'~~> This procedure fills Excel's 10000 cells with random values and then removes the duplicates
Sub FillExcelCells()
Dim rowCount As Long
'~~> Activate the necesary Sheet
Sheets("Sheet1").Activate
'~~> Loop through all the cells and store random numbers
For rowCount = 1 To 10000
Sheets("Sheet1").Range("A" & rowCount).Select
Sheets("Sheet1").Range("A" & rowCount).Value = Int((10000 - 1) * Rnd() + 1)
Next rowCount
'~~> Sort the Range
Sheets("Sheet1").Range("A1").Select
Sheets("Sheet1").Range(Selection, Selection.End(xlDown)).Select
Application.CutCopyMode = False
Range(Selection, Selection.End(xlDown)).Select
ActiveWindow.SmallScroll Down:=-39
ActiveWindow.ScrollRow = 9838
ActiveWindow.ScrollRow = 9709
ActiveWindow.ScrollRow = 9449
ActiveWindow.ScrollRow = 8968
ActiveWindow.ScrollRow = 8319
ActiveWindow.ScrollRow = 7245
ActiveWindow.ScrollRow = 6003
ActiveWindow.ScrollRow = 4818
ActiveWindow.ScrollRow = 4040
ActiveWindow.ScrollRow = 3317
ActiveWindow.ScrollRow = 3076
ActiveWindow.ScrollRow = 2521
ActiveWindow.ScrollRow = 2298
ActiveWindow.ScrollRow = 2113
ActiveWindow.ScrollRow = 1724
ActiveWindow.ScrollRow = 1372
ActiveWindow.ScrollRow = 1038
ActiveWindow.ScrollRow = 872
ActiveWindow.ScrollRow = 668
ActiveWindow.ScrollRow = 538
ActiveWindow.ScrollRow = 464
ActiveWindow.ScrollRow = 446
ActiveWindow.ScrollRow = 427
ActiveWindow.ScrollRow = 409
ActiveWindow.ScrollRow = 390
ActiveWindow.ScrollRow = 353
ActiveWindow.ScrollRow = 334
ActiveWindow.ScrollRow = 297
ActiveWindow.ScrollRow = 279
ActiveWindow.ScrollRow = 242
ActiveWindow.ScrollRow = 223
ActiveWindow.ScrollRow = 205
ActiveWindow.ScrollRow = 168
ActiveWindow.ScrollRow = 149
ActiveWindow.ScrollRow = 112
ActiveWindow.ScrollRow = 94
ActiveWindow.ScrollRow = 57
ActiveWindow.ScrollRow = 20
ActiveWindow.ScrollRow = 1
Selection.Sort Key1:=Sheets("Sheet1").Range("A1"), Order1:=xlAscending, Header:=xlGuess, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
'~~> Delete duplicates
For rowCount = 10000 To 2 Step -1
Sheets("Sheet1").Range("A" & rowCount).Select
If Range("A" & rowCount).Value = Range("A" & rowCount - 1).Value Then
Sheets("Sheet1").Rows(rowCount).Delete shift:=xlUp
End If
Next rowCount
End Sub

Ci-dessus peut être écrite comme

'~~> This procedure fills Excel's 10000 cells with random values and then removes the duplicates
Sub FillExcelCells()
Dim rowCount As Long
With Sheets("Sheet1")
'~~> Loop through all the cells and store random numbers
For rowCount = 1 To 10000
.Range("A" & rowCount).Value = Int((10000 - 1) * Rnd() + 1)
Next rowCount
'~~> Sort Range
.Range("A1:A10000").Sort Key1:=.Range("A1"), Order1:=xlAscending, Header:=xlGuess, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
'~~> Delete duplicates
For rowCount = 10000 To 2 Step -1
If .Range("A" & rowCount).Value = .Range("A" & rowCount - 1).Value Then
.Rows(rowCount).Delete shift:=xlUp
End If
Next rowCount
End With
End Sub

3) Déclarer des Objets de sorte que vous n'avez pas à continuer à répéter. Voir cet exemple

Sub Sample()
Range("A1").Select
ActiveCell.FormulaR1C1 = "sdasds"
Range("A1").Select
With Selection.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = 65535
.TintAndShade = 0
.PatternTintAndShade = 0
End With
Selection.Font.Bold = True
Selection.Font.Italic = True
Selection.Font.Underline = xlUnderlineStyleSingle
With Selection
.HorizontalAlignment = xlGeneral
.VerticalAlignment = xlBottom
.WrapText = True
.Orientation = 0
.AddIndent = False
.IndentLevel = 0
.ShrinkToFit = False
.ReadingOrder = xlContext
.MergeCells = False
End With
End Sub

Cela peut être écrite comme

Sub Sample()
Dim ws As Worksheet, rng As Range
Set ws = Sheet1
Set rng = ws.Range("A1")
With rng
.FormulaR1C1 = "sdasds"
With .Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = 65535
.TintAndShade = 0
.PatternTintAndShade = 0
End With
.Font.Bold = True
.Font.Italic = True
.Font.Underline = xlUnderlineStyleSingle
.HorizontalAlignment = xlGeneral
.VerticalAlignment = xlBottom
.WrapText = True
.Orientation = 0
.AddIndent = False
.IndentLevel = 0
.ShrinkToFit = False
.ReadingOrder = xlContext
.MergeCells = False
End With
End Sub

4) Briser votre procédure en cas de besoin. et d'appeler la 2ème procédure, à partir du 1er

5) Éviter d'utiliser .Select et .Activate Ils n'ont pas seulement de rendre votre code lente, mais aussi prendre beaucoup d'espace dans votre code si largement utilisé. Comment éviter à l'aide de Select dans Excel macros VBA

cela a de bons conseils
+1 d'Où obtenez-vous le temps d'écrire de telles réponses longues?
lol@PradeepKumar
J'ai eu une méthode avec beaucoup, beaucoup de Round(ThisWorkbook.Worksheets("Sheet5").Range("NamedRange").Value, 5). J'ai remplacé le tout avec un seul integer variable, de sorte que Round(...) a été appelé qu'une seule fois. Cela a également fait la méthode la plus facile à entretenir. Il court sans doute plus vite maintenant.

OriginalL'auteur Siddharth Rout

0

Macros taille est limitée à 64 ko, après quoi vous obtiendrez un message d'erreur à partir d'Excel.

J'ai rencontré un problème, pour lequel il n'y a pas d'explication ou de message d'erreur à partir d'Excel, où Excel a pas été à même de calculer un classeur par le manque de ressources, lorsque j'ai écrit une macro qui appelle de multiples autres macros.

Je suis en supposant que la somme de la longueur de toutes les macros dans la chaîne devra être envisagée.

On dirait que vous essayez de poser votre propre question plutôt que de donner une réponse.

OriginalL'auteur Mike Benstead

Vous devez vous connecter pour publier un commentaire.