Est-il possible dans un script batch pour garder la console ouverte uniquement lorsqu'elle est invoquée à partir de Windows Manager?

Voir cette question: La détection de la façon dont un fichier de commandes a été exécuté

Ce script ne va pas mettre en pause si vous exécutez à partir de la console de commande, mais si un double-clic dans l'Explorateur:

@echo off
setlocal enableextensions

set SCRIPT=%0
set DQUOTE="

:: Detect how script was launched
@echo %SCRIPT:~0,1% | findstr /l %DQUOTE% > NUL
if %ERRORLEVEL% EQU 0 set PAUSE_ON_CLOSE=1

:: Run your app
java com.example.myApp

:EXIT
if defined PAUSE_ON_CLOSE pause

OriginalL'auteur Patrick Cuff

cmd /K java com.example.myApp & pause & exit

va faire le travail. Le & exécuter la commande, l'un après l'autre. Si vous utilisez des && vous pouvez rompre si l'on échoue.

OriginalL'auteur Totonga

J'ai souvent recours à d'autres coquillages (principalement TCC/LE de jpsoft.com) et sous-coquille. J'ai trouvé que ce code fonctionne pour un plus large, plus général (et il ne nécessite pas FINDSTR):

@echo off & setlocal
if "%CMDEXTVERSION%"=="" ( echo REQUIRES command extensions & exit /b 1 ) &:: REQUIRES command extensions for %cmdcmdline% and %~$PATH:1 syntax

call :_is_similar_command _FROM_CONSOLE "%COMSPEC%" %cmdcmdline%
if "%_PAUSE_NEEDED%"=="0" ( goto :_START )
if "%_PAUSE_NEEDED%"=="1" ( goto :_START )
set _PAUSE_NEEDED=0
if %_FROM_CONSOLE% equ 0 ( set _PAUSE_NEEDED=1 )
goto :_START
::
:_is_similar_command VARNAME FILENAME1 FILENAME2
:: NOTE: not _is_SAME_command; that would entail parsing PATHEXT and concatenating each EXT for any argument with a NULL extension
setlocal
set _RETVAL=0
:: more than 3 ARGS implies %cmdcmdline% has multiple parts (therefore, NOT direct console execution)
if NOT [%4]==[] ( goto :_is_similar_command_RETURN )
:: deal with NULL extensions (if both NULL, leave alone; otherwise, use the non-NULL extension for both)
set _EXT_2=%~x2
set _EXT_3=%~x3
if NOT "%_EXT_2%"=="%_EXT_3%" if "%_EXT_2%"=="" (
    call :_is_similar_command _RETVAL "%~2%_EXT_3%" "%~3"
    goto :_is_similar_command_RETURN
    )
if NOT "%_EXT_2%"=="%_EXT_3%" if "%_EXT_3%"=="" (
    call :_is_similar_command _RETVAL "%~2" "%~3%_EXT_2%"
    goto :_is_similar_command_RETURN
    )
::if /i "%~f2"=="%~f3" ( set _RETVAL=1 )  &:: FAILS for shells executed with non-fully qualified paths (eg, subshells called with 'cmd.exe' or 'tcc')
if /i "%~$PATH:2"=="%~$PATH:3" ( set _RETVAL=1 )
:_is_similar_command_RETURN
endlocal & set "%~1=%_RETVAL%"
goto :EOF
::

:_START

if %_FROM_CONSOLE% EQU 1 (
    echo EXEC directly from command line
  ) else (
    echo EXEC indirectly [from explorer, dopus, perl system call, cmd /c COMMAND, subshell with switches/ARGS, ...]
    )
if %_PAUSE_NEEDED% EQU 1 ( pause )

Au début, j'avais utilisé if /i "%~f2"=="%~f3" dans le _is_similar_command sous-routine. Le changement de if /i "%~$PATH:2"=="%~$PATH:3" et les autres le code de vérification pour les NULS extensions permet au code du travail pour les coques/sous-coquille ouvert avec les chemins d'accès complets (par exemple, sous-coquille appelée avec juste "cmd.exe" ou "cci"). la

Pour les arguments sans les extensions, ce code n'est pas d'analyser et d'utiliser les extensions à partir de %PATHEXT%. Il ignore le plus souvent la hiérarchie des extensions CMD.exe utilise lors de la recherche pour une commande sans l'extension (première tentative FOO.com puis FOO.exe puis FOO.chauve-souris, etc.). Donc, _is_similar_command vérifie pour la ressemblance, pas d'équivalence entre les deux arguments des commandes shell. Cela pourrait être une source de confusion ou d'erreur, mais, en toute probabilité, jamais comme un problème, dans la pratique, pour cette application.

Edit: code Initial était une vieille version. Le code est maintenant mis à jour à la version la plus récente qui a: (1) un échangés %COMSPEC% et %cmdcmdline% dans l'appel initial, (2) ajout d'une vérification pour plusieurs %cmdcmdline% arguments, (3) l'écho des messages sont plus spécifiques au sujet de ce qui est détecté, et (4) une nouvelle variable %_PAUSE_NEEDED% a été ajouté.

Il convient de noter que %_FROM_CONSOLE% est définie spécifiquement, si le fichier de commandes a excecuted directement à partir de la console de ligne de commande ou indirectement par l'intermédiaire d'explorer ou d'autres moyens. Ces "autres moyens" peut inclure un perl appel system() ou par l'exécution d'une commande telle que cmd /c COMMAND.

La variable %_PAUSE_NEEDED% a été ajoutée afin que les processus (tels que perl) qui exécutez le fichier de commandes indirectement pouvez contourner les pauses dans le fichier de commandes. Cela pourrait être important dans les cas où la production n'est pas canalisée vers le visible de la console (par exemple, perl -e "$o = qx{COMMAND}"). Si une interruption se produit dans un tel cas, le message "Appuyez sur n'importe quelle touche pour continuer . . ." pause invite à ne jamais être affiché à l'utilisateur et le processus va se bloquer en attente pour spontanées saisie de l'utilisateur. Dans les cas où l'interaction de l'utilisateur n'est pas possible ou n'est pas autorisé, le %_PAUSE_NEEDED% variable peut être réglé à "0" ou "1" (faux ou vrai, respectivement). %_FROM_CONSOLE% est toujours correctement définies par le code, mais la valeur de %_PAUSE_NEEDED% n'est pas par la suite basées sur %_FROM_CONSOLE%. Il est juste passé à travers.

Et également à noter que le code de détecter à tort de l'exécution indirecte (%_FROM_CONSOLE%=0) dans un shell interne est exécuté que si shell interne est exécuté est ouvert avec une commande contenant des commutateurs/options (par exemple, cmd /x). En général, ce n'est pas un gros problème en tant que sous-coquille sont généralement ouvert sans supplément de commutateurs et %_PAUSE_NEEDED% peut être réglé à 0, lorsque cela est nécessaire.

Mise en garde codor.

OriginalL'auteur rivy