Évolution liée emplacement de la table par programmation

Il peut être utile de disposer d'un formulaire de démarrage qui vous permet de parcourir pour le back-end, vous souhaitez une table et des tables qui doivent être reliées. Vous pourriez parcourir la collection de tables, mais je pense que la liste est un peu plus sûr. Après cela, un peu de code est tout ce qui est nécessaire, voici un extrait:

''Connection string with database password 
strConnect = "MS Access;PWD=pw;DATABASE=" & Me.txtNewDataDirectory

Set rs = CurrentDb.OpenRecordset("Select TableName From LinkTables " _
& "WHERE TableType = 'LINK'")

Do While Not rs.EOF
    ''Check if the table is already linked, if it is, update the connection
    ''otherwise, link the table. 

    If IsNull(DLookup("[Name]", "MSysObjects", "[Name]='" & rs!TableName & "'")) Then
        Set tdf = db.CreateTableDef(rs!TableName, dbAttachSavePWD, _
            rs!TableName, strConnect)
        db.TableDefs.Append tdf
    Else
        db.TableDefs(rs!TableName).Connect = strConnect
    End If
    db.TableDefs(rs!TableName).RefreshLink
    rs.MoveNext
Loop

J'ai utilisé usncahill de la solution et l'a modifié pour mes besoins propres. Je n'ai pas assez de réputation afin de voter pour leur solution, donc si vous aimez mon code supplémentaire, veuillez nous voter tous les deux.

Je voulais un moyen rapide pour basculer entre les deux bases de données, l'un contenant les données en direct et l'autre contenant les données de test. J'ai donc modifié le mentionné précédemment code comme suit:

Private Sub ReplaceLink(oldLink As String, newLink As String)
    Dim tbl As TableDef, db As Database

    Set db = CurrentDb

    For Each tbl In db.TableDefs
        If InStr(tbl.Connect, oldLink) > 0 Then
            tbl.Connect = Replace(tbl.Connect, oldLink, newLink)
            tbl.RefreshLink
        End If
    Next
End Sub

Public Function ConnectTestDB()
    ReplaceLink "Data.accdb", "Test.accdb"
End Function

Public Function ConnectLiveDB()
    ReplaceLink "Test.accdb", "Data.accdb"
End Function

Public Function TestDBSwitch()
    Dim tbl As TableDef, db As Database
    Dim wasData As Boolean
    Dim wasTest As Boolean

    wasData = False
    wasTest = False

    Set db = CurrentDb

    For Each tbl In db.TableDefs
        If InStr(tbl.Connect, "JGFC Flooring Data") > 0 Then
            wasData = True
        ElseIf InStr(tbl.Connect, "JGFC Flooring Test") > 0 Then
            wasTest = True
        End If
    Next

    If wasData = True And wasTest = True Then
        MsgBox "Data Mismatch.  Both Test and Live Data are currently linked! Connecting all tables to Test database. To link to Live database, please run again.", , "Data Mismatch"
        ConnectTestDB
    ElseIf wasData = True Then
        ConnectTestDB
        MsgBox "You are now connected to the Test database.", , "Connection Changed"
    ElseIf wasTest = True Then
        ConnectLiveDB
        MsgBox "You are now connected to the Live database.", , "Connection Changed"
    End If
 End Function

(Le code précédent suppose que la Tester et de Vivre des fichiers de Données sont situés dans le même répertoire et le nom du fichier se termine dans l'Essai et des Données, mais peut être facilement adapté à d'autres chemins/noms de fichiers)

J'appelle TestSwitchDB à partir d'un bouton dans mon avant la fin de DB pour changer rapidement entre les tests et les environnements de production. Mon Accès DB, les contrôles de l'utilisateur de basculer entre les environnements d'utilisateur, de sorte que lorsque l'utilisateur admin se connecte à l'avant la fin de DB, j'utilise le ConnectTestDB directement à la fonction par défaut de l'utilisateur admin pour se connecter à l'essai DB. De même, j', utilisez le ConnectLiveDB fonction lorsque d'autres utilisateurs de connexion pour le front-end.

Il y a aussi une rapide détection d'erreur dans l'TestSwitchDB fonction de me dire si il y a un mélange de connexions à la fois les environnements avant l'appel de la fonction de commutation. Si cette erreur est récurrente, il pourrait être un signe d'autres problèmes.