excel 2007 macro valider les données saisies dans la cellule et de montrer msgbox si incorrect

Svp quelqu'un peut aider avec le code suivant. il me donne une erreur à la ligne suivante:

Set range = "C5:L14"

C'est le code complet:

Private Sub Worksheet_Change(ByVal Target As Excel.range)
Dim ws As Worksheet
Dim range As Worksheet

Set ws = Application.ActiveSheet
Set range = "C5:L14"

If Not Application.Intersect(Target, range("C5:L14")) Is Nothing Then

    If range("C5:L14").Value = "" Then Exit Sub

    If range("C5:L14").Date = "< today()" Then Exit Sub

    If range("C5:L14").Date = "> today()" Then MsgBox ("Future dates not allowed!")

    Else
        MsgBox ("Please enter date as follows yyyy-mm")
    End If

End Sub

La date de la mise en forme "2013 Jan" sur les cellules. Les futures dates ne sont pas autorisés et que l'utilisateur ne devrait entrez la date comme "2013-01". Le format doit changer correctement. Si elles tapez "2013 Jan" la mise en forme Conditionnelle ne pas le ramasser. Ont essayé de VALIDATION des DONNÉES, mais il ne me limite à un.

J'ai besoin de la macro pour s'assurer qu'un utilisateur de ne pas entrer une date incorrecte dans les cellules spécifiée.

Set Rng = ws.Range("C5:L14") Également de ne pas utiliser le Range mot comme une variable Aussi changer Dim range As Worksheet comme Dim rng As Range
BTW, vous n'avez pas besoin de VBA pour cela. Vous pouvez définir manuellement la DataValidation 😉
tout cela ressemble à une réponse pour moi :).

InformationsquelleAutor user1955214 | 2013-01-31

4

Ce que vous essayez peut être résolu sans VBA ainsi. Cependant, je vais vous montrer deux méthodes. Faites votre choix

NON VBA

Sélectionnez la cellule où vous souhaitez appliquer les Données de Validation puis suivez ces étapes.

Étape 1

Étape 2

Étape 3

Étape 4

En Action

VBA

J'ai commenté le code de sorte que vous n'aurez pas de problème dans la compréhension de ce
```
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
    Dim rng As Range
    Dim aCell As Range

    '~~> The below two lines are required. Read up more on
    '~~> http://stackoverflow.com/questions/13860894/ms-excel-crashes-when-vba-code-runs/13861640#13861640
    On Error GoTo Whoa
    Application.EnableEvents = False

    '~~> Set your range
    Set rng = Range("C5:L14")

    If Not Application.Intersect(Target, rng) Is Nothing Then
        '~~> Loop through all cells in the range
        For Each aCell In rng
            If aCell.Value <> "" Then
                If aCell.Value > Date Then
                    aCell.ClearContents
                    MsgBox "Future date not allowed in cell " & aCell.Address
                ElseIf IsDate(aCell.Value) = False Then
                    aCell.ClearContents
                    MsgBox "Incorrect date in cell " & aCell.Address
                Else
                    aCell.Value = Format(aCell.Value, "yyyy-mm")
                End If
            End If
        Next
    End If

Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub
```
Espère que cette aide?

MODIFIER:

Un léger changement. Dans l'Étape 4 de la Non Méthode VBA, j'ai tapé "aaaa mm" par erreur. Changement de "aaaa-mm"
- +1 pour être terriblement approfondie
- merci pour toutes les réponses, essayé tous les d'eux, et ils fonctionnent tous de mieux que prévu. j'apprends un peu plus chaque jour à partir de ce site et toutes vos réponses. merci pour les réponses rapides, allez et apprenez-en plus maintenant.
- juste 1 problème sur la méthode VBA que je ne comprends pas. si je effacer une cellule de la plage, il efface l'ensemble de la feuille de calcul avec les msgbox "des dates futures, ne permet pas" d'une cellule à un moment. il n'y aura jamais une raison de supprimer quoi que ce soit sur la feuille de calcul, mais il me dérange et aimerais comprendre pourquoi pour les futurs codes VBA. merci.
- Il va seulement clair, les cellules qui ont des dates futures ou des dates non valides. Ceci est nécessaire afin que si l'utilisateur fait un copier coller dans plusieurs cellules, puis toutes ces cellules seront traitées correctement
- trouvé, il était le format de la date. la mine a été mis à JJ MMM et le code VBA vérifié pour AAAA-MM, maintenant ça fonctionne, désolé pour la peine. merci Siddharth
InformationsquelleAutor Siddharth Rout

Vous devez vous connecter pour publier un commentaire.