Excel 2007 VBA Convertir les Caractères Accentués à la Régulière

Quelqu'un peut-il m'aider à déterminer pourquoi ce code de Macro VBA n'est pas de travail dans Excel 2007? Je suis en train de remplacer les caractères accentués avec des caractères normaux. Le code compile sans problème mais lorsque j'essaie d'exécuter la macro, il n'apparaît pas dans la liste.

Option Explicit

'-- Add more chars to these 2 string as you want
'-- You may have problem with unicode chars that has code > 255
'-- such as some Vietnamese characters that are outside of ASCII code (0-255)
Const AccChars = "ŠŽšžŸÀÁÂÃÄÅÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖÙÚÛÜÝàáâãäåçèéêëìíîïðñòóôõöùúûüýÿ"
Const RegChars = "SZszYAAAAAACEEEEIIIIDNOOOOOUUUUYaaaaaaceeeeiiiidnooooouuuuyy"

Sub StripAccent(aRange As Range)
'-- Usage: StripAccent Sheet1.Range("A1:C20")
Dim A As String * 1
Dim B As String * 1
Dim i As Integer

For i = 1 To Len(AccChars)
A = Mid(AccChars, i, 1)
B = Mid(RegChars, i, 1)
aRange.Replace What:=A, _
Replacement:=B, _
LookAt:=xlPart, _
MatchCase:=True
Next

End Sub

Je l'ai testé en 2007 et en 2010, et il fonctionne parfaitement. Qu'est-ce exactement ne fonctionne pas?
Je ne vois pas l'option pour exécuter la macro dans ma liste de macros. Le nom de la macro n'apparaît pas dans la liste pour le sélectionner. J'ai activé les macros et j'ai un tas d'autres j'utilise donc je ne comprends pas pourquoi il ne l'est pas.

OriginalL'auteur BvilleBullet | 2012-04-05

Je ne vois pas l'option pour exécuter la macro dans ma liste de macros. Le nom de la macro n'apparaît pas dans la liste pour le sélectionner. J'ai activé les macros et j'ai un tas d'autres j'utilise donc je ne comprends pas pourquoi il ne l'est pas. – BvilleBullet 4 mins ago

Veuillez voir le commentaire dans le code ci-dessus.

'-- Utilisation: StripAccent La Feuille Sheet1.Range("A1:C20")

Vous avez de l'appeler comme cela

Option Explicit

'-- Add more chars to these 2 string as you want
'-- You may have problem with unicode chars that has code > 255
'-- such as some Vietnamese characters that are outside of ASCII code (0-255)
Const AccChars = "ŠŽšžŸÀÁÂÃÄÅÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖÙÚÛÜÝàáâãäåçèéêëìíîïðñòóôõöùúûüýÿ"
Const RegChars = "SZszYAAAAAACEEEEIIIIDNOOOOOUUUUYaaaaaaceeeeiiiidnooooouuuuyy"

'~~> This is how you have to call it. Now You can see the macro "Sample" in the list
Sub Sample()
    StripAccent Sheet1.Range("A1:C20")
End Sub

Sub StripAccent(aRange As Range)
    '-- Usage: StripAccent Sheet1.Range("A1:C20")
    Dim A As String * 1
    Dim B As String * 1
    Dim i As Integer

    For i = 1 To Len(AccChars)
        A = Mid(AccChars, i, 1)
        B = Mid(RegChars, i, 1)
        aRange.Replace What:=A, _
        Replacement:=B, _
        LookAt:=xlPart, _
        MatchCase:=True
    Next
End Sub

Merci cela a fonctionné très bien!

OriginalL'auteur Siddharth Rout

Pour ceux qui en ont besoin pour enlever les marques d'accent de TOUS les caractères Romains, y compris l'étendue, comme ceux utilisés en Vietnamien, puis suivez les instructions ci-dessous.

Tout d'abord, nous allons préparer la feuille de calcul à faire ses VBA de la magie. Dans le Microsoft éditeur VBA, sélectionnez Outils /Références et de mettre une coche à côté de "Microsoft Scripting Runtime". Nous en aurons besoin pour définir un objet dictionary dans les étapes ultérieures.
Ensuite, nous créons un mondial de dictionnaire dans le but de faire correspondre les caractères accentués à leurs équivalents non accentuées. Cela se fait lorsque le Workbook_Open événement est déclenché alors que le dictionnaire n'est lancé une fois que lorsque vous ouvrez la feuille de calcul au lieu de chaque fois que vous appelez la fonction. AsciiDict est définie comme une variable publique dans l'étape 3. Dans le "Projet - VBAProject" panneau de configuration, double-cliquez sur ThisWorkbook pour ouvrir le classeur portée. Collez le code suivant y (ci-dessous Option Explicit):

Private Sub Workbook_Open()
InitDictionary
End Sub
Sub InitDictionary()
AsciiDict(192) = "A"
AsciiDict(193) = "A"
AsciiDict(194) = "A"
AsciiDict(195) = "A"
AsciiDict(196) = "A"
AsciiDict(197) = "A"
AsciiDict(199) = "C"
AsciiDict(200) = "E"
AsciiDict(201) = "E"
AsciiDict(202) = "E"
AsciiDict(203) = "E"
AsciiDict(204) = "I"
AsciiDict(205) = "I"
AsciiDict(206) = "I"
AsciiDict(207) = "I"
AsciiDict(208) = "D"
AsciiDict(209) = "N"
AsciiDict(210) = "O"
AsciiDict(211) = "O"
AsciiDict(212) = "O"
AsciiDict(213) = "O"
AsciiDict(214) = "O"
AsciiDict(217) = "U"
AsciiDict(218) = "U"
AsciiDict(219) = "U"
AsciiDict(220) = "U"
AsciiDict(221) = "Y"
AsciiDict(224) = "a"
AsciiDict(225) = "a"
AsciiDict(226) = "a"
AsciiDict(227) = "a"
AsciiDict(228) = "a"
AsciiDict(229) = "a"
AsciiDict(231) = "c"
AsciiDict(232) = "e"
AsciiDict(233) = "e"
AsciiDict(234) = "e"
AsciiDict(235) = "e"
AsciiDict(236) = "i"
AsciiDict(237) = "i"
AsciiDict(238) = "i"
AsciiDict(239) = "i"
AsciiDict(240) = "d"
AsciiDict(241) = "n"
AsciiDict(242) = "o"
AsciiDict(243) = "o"
AsciiDict(244) = "o"
AsciiDict(245) = "o"
AsciiDict(246) = "o"
AsciiDict(249) = "u"
AsciiDict(250) = "u"
AsciiDict(251) = "u"
AsciiDict(252) = "u"
AsciiDict(253) = "y"
AsciiDict(255) = "y"
AsciiDict(352) = "S"
AsciiDict(353) = "s"
AsciiDict(376) = "Y"
AsciiDict(381) = "Z"
AsciiDict(382) = "z"
AsciiDict(258) = "A"
AsciiDict(259) = "a"
AsciiDict(272) = "D"
AsciiDict(273) = "d"
AsciiDict(296) = "I"
AsciiDict(297) = "i"
AsciiDict(360) = "U"
AsciiDict(361) = "u"
AsciiDict(416) = "O"
AsciiDict(417) = "o"
AsciiDict(431) = "U"
AsciiDict(432) = "u"
AsciiDict(7840) = "A"
AsciiDict(7841) = "a"
AsciiDict(7842) = "A"
AsciiDict(7843) = "a"
AsciiDict(7844) = "A"
AsciiDict(7845) = "a"
AsciiDict(7846) = "A"
AsciiDict(7847) = "a"
AsciiDict(7848) = "A"
AsciiDict(7849) = "a"
AsciiDict(7850) = "A"
AsciiDict(7851) = "a"
AsciiDict(7852) = "A"
AsciiDict(7853) = "a"
AsciiDict(7854) = "A"
AsciiDict(7855) = "a"
AsciiDict(7856) = "A"
AsciiDict(7857) = "a"
AsciiDict(7858) = "A"
AsciiDict(7859) = "a"
AsciiDict(7860) = "A"
AsciiDict(7861) = "a"
AsciiDict(7862) = "A"
AsciiDict(7863) = "a"
AsciiDict(7864) = "E"
AsciiDict(7865) = "e"
AsciiDict(7866) = "E"
AsciiDict(7867) = "e"
AsciiDict(7868) = "E"
AsciiDict(7869) = "e"
AsciiDict(7870) = "E"
AsciiDict(7871) = "e"
AsciiDict(7872) = "E"
AsciiDict(7873) = "e"
AsciiDict(7874) = "E"
AsciiDict(7875) = "e"
AsciiDict(7876) = "E"
AsciiDict(7877) = "e"
AsciiDict(7878) = "E"
AsciiDict(7879) = "e"
AsciiDict(7880) = "I"
AsciiDict(7881) = "i"
AsciiDict(7882) = "I"
AsciiDict(7883) = "i"
AsciiDict(7884) = "O"
AsciiDict(7885) = "o"
AsciiDict(7886) = "O"
AsciiDict(7887) = "o"
AsciiDict(7888) = "O"
AsciiDict(7889) = "o"
AsciiDict(7890) = "O"
AsciiDict(7891) = "o"
AsciiDict(7892) = "O"
AsciiDict(7893) = "o"
AsciiDict(7894) = "O"
AsciiDict(7895) = "o"
AsciiDict(7896) = "O"
AsciiDict(7897) = "o"
AsciiDict(7898) = "O"
AsciiDict(7899) = "o"
AsciiDict(7900) = "O"
AsciiDict(7901) = "o"
AsciiDict(7902) = "O"
AsciiDict(7903) = "o"
AsciiDict(7904) = "O"
AsciiDict(7905) = "o"
AsciiDict(7906) = "O"
AsciiDict(7907) = "o"
AsciiDict(7908) = "U"
AsciiDict(7909) = "u"
AsciiDict(7910) = "U"
AsciiDict(7911) = "u"
AsciiDict(7912) = "U"
AsciiDict(7913) = "u"
AsciiDict(7914) = "U"
AsciiDict(7915) = "u"
AsciiDict(7916) = "U"
AsciiDict(7917) = "u"
AsciiDict(7918) = "U"
AsciiDict(7919) = "u"
AsciiDict(7920) = "U"
AsciiDict(7921) = "u"
AsciiDict(7922) = "Y"
AsciiDict(7923) = "y"
AsciiDict(7924) = "Y"
AsciiDict(7925) = "y"
AsciiDict(7926) = "Y"
AsciiDict(7927) = "y"
AsciiDict(7928) = "Y"
AsciiDict(7929) = "y"
AsciiDict(8363) = "d"
End Sub

Enfin, nous créons une fonction appelée StripDiacritics() à normaliser le texte. Dans le "Projet - VBAProject" panneau de configuration, double-cliquez sur Modules /Module1 pour ouvrir la portée de module (si vous ne le voyez pas, alors vous devez les ajouter en cliquant-droit sur ThisWorkbook, puis sélectionnez Insertion /Module). Collez le code suivant y (ci-dessous Option Explicit):

'Dictionary initiated in Workbook_Open()
Public AsciiDict As New Scripting.Dictionary
Function StripDiacritics(Text As String) As String
Text = Trim(Text)
If Text = "" Then Exit Function
Dim Char As String, _
NormalizedText As String, _
UnicodeCharCode As Long, _
i As Long
'Remove accent marks (diacritics) from text
For i = 1 To Len(Text)
Char = Mid(Text, i, 1)
UnicodeCharCode = AscW(Char)
If (UnicodeCharCode < 0) Then
'See http://support.microsoft.com/kb/272138
UnicodeCharCode = 65536 + UnicodeCharCode
End If
If AsciiDict.Exists(UnicodeCharCode) Then
NormalizedText = NormalizedText & AsciiDict.Item(UnicodeCharCode)
Else
NormalizedText = NormalizedText & Char
End If
Next
StripDiacritics = NormalizedText
End Function

Enregistrer et ré-ouvrez la feuille de calcul pour la cartographie dictionnaire pour être correctement lancé.

Utilisation:

=StripDiacritics("Hermès Prêt à Porter")
Sorties", Hermes Pret a Porter"
=StripDiacritics("Việt Nam Textiles")
Sorties "Viet Nam Textiles"

Pour ceux qui sont curieux, l'ensemble de mappings peuvent être trouvés ici: https://goo.gl/Vvn9px. Le dictionnaire des touches correspondent à la colonne Décembre.

J'ai essayé et testé, cela fonctionne très bien pour les Vietnamiens.

OriginalL'auteur thdoan

Function stripAccent(Text As String) As String
Const AccChars = "ŠŽšžŸÀÁÂÃÄÅÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖÙÚÛÜÝàáâãäåçèéêëìíîïðñòóôõöùúûüýÿ"
Const RegChars = "SZszYAAAAAACEEEEIIIIDNOOOOOUUUUYaaaaaaceeeeiiiidnooooouuuuyy"
Dim A As String * 1
Dim B As String * 1
Dim i As Integer
For i = 1 To Len(AccChars)
A = Mid(AccChars, i, 1)
B = Mid(RegChars, i, 1)
Text = Replace(Text, A, B)
Next
stripAccent = Text
End Function

OriginalL'auteur notGeek

0

Vous dire la liste des macros dans la Boîte de Dialogue Macro ? Si oui, c'est parce que les paramètres de gamme, la Boîte de Dialogue Macro ne contient que la liste des procédures sans paramètres.

OK, donc comment puis-je exécuter ce code alors? Je ussually exécuter la macro via la boîte de dialogue ou le code d'un bouton, mais il n'est pas figurant pour la sélectionner.

OriginalL'auteur xyzasdfasdf

Vous pouvez utiliser un userForm avec un refEdit et bouton de contrôle.
La routine à l'appel de la forme est quelque chose comme:

Sub ShowForm()
Dim d As dlg
Set d = New dlg
d.Show
Set d = Nothing
End Sub

...et dans l'événement click du bouton:

Private Sub cmdBtn_Click()
On Error GoTo cmdBtn_Click_Err
Dim strRange As String
Dim rng As Range
strRange = refeditControl.Text
Set rng = Range(strRange)        
Call StripAccent(rng)        
cmdBtn_Click_Exit:
Exit Sub
cmdBtn_Click_Err:
MsgBox Err.Description
Resume cmdBtn_Click_Exit
End Sub

En supposant que l'objet userForm est le nom de la dlg, le bouton cmdBtn et le contrôle refEdit refEditControl.

OriginalL'auteur xyzasdfasdf

Vous devez vous connecter pour publier un commentaire.