Excel macro - coller non seulement les cellules vides à partir d'une feuille à l'autre

Vous ressemble peut-être à prendre en commun certaines erreurs de débutant ici (c'est bien que nous avons tous fait).

---

VBA exemple, ligne par ligne, des explications

ASTUCE: Essayez de ne pas utiliser "Select" ou "Copier". Pourquoi utiliser select lorsque tout ce que vous avez à faire est de référencer les cellules elles-mêmes? Par exemple, au lieu d'utiliser

Sheets("codes").Select
Range("A5:A100").Select
Selection.Copy
Sheets("Sheet2").Select
Range("B28").Select
ActiveSheet.Paste

Suffit d'utiliser

dim mySheet as Worksheet, myOtherSheet as Worksheet, myBook as Workbook 'Define your workbooks and worksheets as variables
set myBook = Excel.ActiveWorkbook
set mySheet = myBook.Sheets("codes")
set myOtherSheet = myBook.Sheets("Sheet2")

dim i as integer, j as integer 'Define a couple integer variables for counting

j = 28 'This variable will keep track of which row we're on in Sheet2 (I'm assuming you want to start on line 28)
for i = 5 to 100 'This is the beginning the the loop which will repeat from 5 to 100 . . .
   if mySheet.Cells(i,1).value <> "" then ' . . . for each digit, it will check if the cell's value is blank. If it isn't then it will . . .
      myOtherSheet.Cells(j,2).value = mySheet.Cells(i,1).value ' . . . Copy that value into the cell on Sheet2 in the row specified by our "j" variable.
      j = j + 1 'Then we add one to the "j" variable so the next time it copies, we will be on the next available row in Sheet2.
   end if
next i 'This triggers the end of the loop and moves on to the next value of "i".

J'ai fait la même chose tout le temps quand j'ai commencé, et ça ne fonctionne jamais. "Sélectionner" les causes des erreurs à gauche et à droite. Utiliser mon code, lisez les commentaires, et vous serez amende. Un rapide AVERTISSEMENT: je n'ai pas Excel sur cet ordinateur donc je ne pouvais pas tester le code. Si cela ne fonctionne pas pour une raison quelconque, laissez-moi un commentaire et demain, je vais le corriger au travail.

Le code ci-dessus va ignorer les cellules vides complètement lors de la copie des données à votre deuxième feuille. Si vous souhaitez saisir un texte particulier pour les cellules vides à la place (comme "N/A"), puis vous pouvez utiliser les éléments suivants:

 dim mySheet as Worksheet, myOtherSheet as Worksheet, myBook as Workbook 'Define your workbooks and worksheets as variables
 set myBook = Excel.ActiveWorkbook
 set mySheet = myBook.Sheets("codes")
 set myOtherSheet = myBook.Sheets("Sheet2")

 dim i as integer, j as integer 'Define a couple integer variables for counting

 j = 28 'This variable will keep track of which row we're on in Sheet2 (I'm assuming you want to start on line 28)
 for i = 5 to 100 'This is the beginning the the loop which will repeat from 5 to 100 . . .
    if mySheet.Cells(i,1).value <> "" then ' . . . for each digit, it will check if the cell's value is blank. If it isn't then it will . . .
       myOtherSheet.Cells(j,2).value = mySheet.Cells(i,1).value ' . . . Copy that value into the cell on Sheet2 in the row specified by our "j" variable.
    else 'If the cell is blank, then . . .
       myOtherSheet.Cells(j,2).value = "N/A" ' . . . place the text "N/A" into the cell in row "j" in Sheet2.
    end if 'NOTICE we moved the "end if" statement up a line, so that it closes the "if" statement before the "j = j + 1" statement. _
      This is because now we want to add one to the "j" variable (i.e., move to the next available row in Sheet2) regardless of whether the cell in the "codes" sheet is blank or not.
       j = j + 1 'Then we add one to the "j" variable so the next time it copies, we will be on the next available row in Sheet2.
 next i 'This triggers the end of the loop and moves on to the next value of "i".

OriginalL'auteur Lopsided

Si vous n'avez pas besoin de formatage que je voudrais utiliser. Il n'est de copier la plage indiquée sur la feuille de calcul à une variable, boucle par le biais de cette variable, vérifier les cellules sont vides et mettre quelle que soit la chaîne de caractères que vous souhaitez. C'est agréable et rapide. Si vous souhaitez conserver la mise en forme, vous pouvez le coller spécial juste les formats de la gamme de sortie.

Sub CopyNonBlankCells(rFromRange As Range, rToCell As Range, sSubIn As String)
    'You have three inputs.  A range to copy from (rFromRange), a range to copy to (rToCell) and a string to put in the blank cells.        

    Dim vData As Variant, ii As Integer, jj As Integer

   'Set to a variable since it's quicker
    vData = rFromRange.Value

    'Loop through to find the blank cells
    For ii = LBound(vData, 1) To UBound(vData, 1)   'Loop the rows
        For jj = LBound(vData, 2) To UBound(vData, 2)    'Loop the columns
            'Check for empty cell.  Quicker to use Len function then check for empty string
            If VBA.Len(vData(ii, jj)) = 0 Then vData(ii, jj) = sSubIn
        Next jj
    Next ii

    'Output to target cell.  Use the 'With' statement because it makes the code easier to read and is more efficient
    With rToCell.Parent
        .Range(.Cells(rToCell.Row, rToCell.Column), .Cells(rToCell.Row + UBound(vData, 1) - 1, rToCell.Column + UBound(vData, 2) - 1)).Value = vData
    End With

End Sub

Et de l'appeler avec:

Call CopyNonBlankCells(Sheets("codes").Range("A5:A100"), Sheets("Sheet2").Range("B28"), "Non-blank")

OriginalL'auteur CuberChase