Excel - Tableau de la Formule d'ignorer les cellules vides

J'ai une formule de tableau à remplir dans la cellule quand il contient du texte, mais je veux qu'il ignorer la cellule si son vide et passer à la suivante. La question que je vais avoir, c'est qu'il ne peut pas le faire dans l'ordre que j'ai pour exemple:

Gamme est

-A
-(BLANK CELL)
-(BLANK CELL)
-D
-E
-F
-(BLANK CELL)
-H
-(BLANK CELL)

Résultat de la formule

-A
-E
-F
-H

C'est de sauter les cellules qui contiennent des lettres. QUELQU'UN PEUT-IL AIDER??

FORMULE:

{=IF(ISERROR(SMALL(IF(B4:$B$12<>"",ROW(B4:$B$12)),ROW(B4:$B$12)-3)),"",INDEX(B4:$B$12,MATCH(SMALL(IF(B4:$B$12<>"",ROW(B4:$B$12)),ROW(B4:$B$12)-3),IF(B4:$B$12<>"",ROW(B4:$B$12)),0)))}

OriginalL'auteur PhoenixJay | 2013-12-02

  1. 7

    Je pense que le problème, c'est que vous avez la gamme que B4:$B$12, donc, car il n'existe pas de signes $ autour de B4 qui référence les changements que vous faites glisser la formule vers le bas de la colonne.......mais la formule est un peu plus complexe que ce que vous avez besoin si je préfère proposer une meilleure alternative:

    La version d'Excel que vous utilisez?

    Dans Excel 2007 ou plus tard essayer cette version

    =IFERROR(INDEX(B$4:B$12,SMALL(IF(B$4:B$12<>"",ROW(B$4:B$12)-ROW(B$4)+1),ROWS(D$4:D4))),"")

    Suppose que votre première cellule est D4 (changement ROWS(D$4:D4) partie pour correspondre à votre début réel de la cellule) et que vous faites glisser la formule vers le bas de la colonne

    confirmé avec CTRL+MAJ+ENTRÉE

    Dans les versions antérieures où IFERROR fonction n'est pas disponible, vous pouvez utiliser cette version

    =IF(ROWS(D$4:D4)>COUNTA(B$4:B$12),"",INDEX(B$4:B$12,SMALL(IF(B$4:B$12<>"",ROW(B$4:B$12)-ROW(B$4)+1),ROWS(D$4:D4))))

    +1 toujours là quand il y a une formule de tableau
    Oui, je suis l'aide de 2007.... C'est exactement ce que je cherchais à faire!Merci beaucoup!!
    Pas de problème - vous Pouvez "accepter" ma réponse, merci

    OriginalL'auteur barry houdini

  2. 1

    Trouvé un moyen plus simple et plus facile façon, fondamentalement, Excel considère que toutes les cellules vides ("") égaux, donc un autre moyen facile est de choisir la colonne qui contient les données et cliquez sur Supprimer les Doublons sous l'onglet Données, ce sera l'enlever (ignorer) la totalité de la vierge des cellules vides.

    Excel - Tableau de la Formule d'ignorer les cellules vides

    OriginalL'auteur Francis Laclé