Excel: Unité de Conversion (MO, GO, KO, etc.)

J'ai une valeur d'un certain nombre de cellules dans une feuille de calcul, de tout ce qui cointain de données qui est un numéro de suivi par les Unités

E. g

1.13 GB
134.3 MB
104.34 MB

Ce que je suis après à essayer de normaliser tous ceux de GO.

donc:

1.13 GB -> 1.13 
    134.3 MB -> 0.1343
    104.34 MB -> 0.10434

etc.

J'ai trouvé beaucoup de méthodes de le faire dans le sens inverse, mais aucun de cette façon.

Virtuel de la bière sur la ligne pour la formule gagnante 🙂

InformationsquelleAutor KingJohnno | 2015-07-14

excel

Dans B1 entrée:

=IF(RIGHT(A1,2)="GB",--MID(A1,1,FIND(" ",A1)-1),--MID(A1,1,FIND(" ",A1)-1)/1000)

et copier vers le bas:

Excel: Unité de Conversion (MO, GO, KO, etc.)

InformationsquelleAutor Gary's Student

11

Voici une autre méthode:
- Suppose que la valeur de A1 est valable
- Œuvres de PB de KO (ou rien) et est facilement extensible si nécessaire
- Comme l'écrit normalise la GB, mais qui est facilement changé.
- Suppose que les UNITÉS sont les deux derniers caractères de la chaîne, si elle est présente
```
 =LEFT(A1,LEN(A1)-2)/10^((IFERROR(MATCH(RIGHT(A1,2),{"PB","TB","GB","MB","KB"},0),6)-3)*3)
```
- A travaillé comme un charme pour MB GB de conversion
- Très élégant, merci! J'ai utilisé la formule semblable à normaliser à partir Kio, Mio, Gio d'octets: =IFERROR(LEFT(AE2, SEARCH(" /",AE2,1)-5)*10^((IFERROR(MATCH(RIGHT(LEFT(AE2, SEARCH(" /",AE2,1)-1),3),{"kib","Mib","gib"},0),0))*3),0)
- ma formule est correcte pour GO, pas de GiB. GiB doit être une puissance de 2, pas de puissance de 10: =IFERROR(LEFT(AE12, SEARCH(" /",AE12,1)-5)*2^( (IFERROR(MATCH(RIGHT(LEFT(AE12, SEARCH(" /",AE12,1)-1),3),{"kib","Mib","gib"},0),0)) *10),0)
InformationsquelleAutor Ron Rosenfeld
1

Ce que vous pouvez faire est de construire deux tableaux:

1. La construction de la légende de la table exemple place dans la feuille de calcul: (=E1:F3)
Celui-ci est prévu de mettre en place l'unité de mesure:
```
unit    in GB
 GB       1
 MB   =1/1024
 KB   =1/1048576
```
Ce qui signifie que 1 GO = 1 GO ; 1 MO = 1/1024 GBand 1 KO = 1/1048576 GO

Comme ça, tout le tableau est normalisé dans le Sgb

2. La construction de la table de travail exemple place dans la feuille de calcul: (=A1:C3)
```
unit    size               size in GB
 GB     1.13      =VLOOKUP(A1,$E$1:$F$3,2,FALSE)*B1
 MB     134.3     =VLOOKUP(A1,$E$1:$F$3,2,FALSE)*B2
 KB     104.34    =VLOOKUP(A1,$E$1:$F$3,2,FALSE)*B3
```
Comme ça, vous pouvez faire glisser le taille en GO formule et devrait-il y avoir quelque chose à corriger, vous faites cela dans la légende de la table et de l'ajuster en conséquence dans la formule une fois.

Voici le visuel:

Espère que cette aide et je chill avec une biere.

InformationsquelleAutor Newskooler

Excel: Unité de Conversion (MO, GO, KO, etc.) Dans B2:

=IF(ISERROR(FIND("M",A1))=FALSE,VALUE(LEFT(A1,FIND(" ",A1)-1))/1000,IF(ISERROR(FIND("K",A1))=FALSE,VALUE(LEFT(A1,FIND(" ",A1)-1))/1000000,VALUE(LEFT(A1,FIND(" ",A1)-1))))

InformationsquelleAutor Abe Gold

0

C'est assez long, mais en supposant que votre valeur est à A1:
```
=VALUE(IFERROR(LEFT(A1,FIND(" ",A1)),A1)) /
  IF(ISERROR(SEARCH("gb",A1)), IF(ISERROR(SEARCH("mb",A1)),
  IF(ISERROR(SEARCH("kb",A1)), 1000000000, 1000000), 1000), 1)
```
Cette traite le cas de go, mo, ko et rien n'est spécifié (en octets). Il n'est pas sensible à la casse (go,go,GO,Go), et la seule restriction est d'avoir un caractère d'espace après la valeur (ou rien en cas d'octets)

InformationsquelleAutor Amit
0

J'ai aimé Amit réponse, mais avec des octets au lieu de bits, et depuis je n'ai pas vu de réponse, en octets, je poste celui-ci.
Aussi mes paramètres régionaux utilise ; au lieu de ,
```
=VALUE(IFERROR(LEFT(D2;FIND(" ";D2));D2)) /IF(ISERROR(SEARCH("gb";D2)); IF(ISERROR(SEARCH("mb";D2));IF(ISERROR(SEARCH("kb";D2)); 1073741824; 1048576); 1024); 1)
```
InformationsquelleAutor Lucas 'Ktulu789'
0

Je serai heureux de partager une bière avec Abe Or. Ou si vous tous pouviez me faire la réputation de l'endroit où je peux faire des commentaires sur Abe Or de l'entrée, ce serait très bien aussi.

Voici la solution qui a fonctionné pour moi, à partir du gouvernement Abe. Il utilise la norme NOUS formatage (modifié par des points-virgules des virgules) et retourne la valeur de la cellule étant évalué si (go,mo,ko,b) ne sont pas trouvés. (coller ce texte à A2, puis copier à l'endroit où vous en avez besoin pour plus de mises à jour):
```
=IFERROR(VALUE(IFERROR(LEFT(A1,FIND(" ",A1)),A1))/IF(ISERROR(SEARCH("gb",A1)), IF(ISERROR(SEARCH("mb",A1)),IF(ISERROR(SEARCH("kb",A1)), 1073741824, 1048576), 1024), 1),A1)
```
Si vous avez Office 2019/Office365, vous pouvez utiliser ceci:
```
=IFERROR(VALUE(IFERROR(LEFT(A1,FIND(" ",A1)),A1))/IFS(ISERROR(SEARCH("gb",A1)),1,ISERROR(SEARCH("mb",A1)),1024,ISERROR(SEARCH("kb",A1)),1048576,ISERROR(SEARCH("b",A1)),1073741824),A1)
```
InformationsquelleAutor Oesten Nelson

Vous devez vous connecter pour publier un commentaire.