Excel VBA appel de la fonction avec le nom de la variable

Je vais essayer d'appeler une fonction avec un nom de variable qui est généré lors de l'exécution basée sur une zone de liste modifiable valeur. C'est simple dans la plupart des langues, mais je n'arrive pas à le comprendre, à en VBA Excel, je suppose que c'est parce que je ne comprends pas vraiment comment le compilateur travaille. J'ai trouvé plusieurs posts qui en sont proches, mais ne semblent pas tout à fait faire l'affaire. Le code ci-dessous est faux, mais devrait donner une idée de ce que je veux.

Grâce

Sub main()
    'run formatting macros for each institution on format button click

     Dim fn As String
     Dim x As Boolean

     'create format function name from CB value        
     fn = "format_" & CBinst.Value

     'run function that returns bool
     x = Eval(fn)

     ...

End Sub

OriginalL'auteur BWG | 2011-09-13

16

CallByName est ce que vous aurez besoin pour accomplir la tâche.

exemple:
Code dans la feuille Sheet1
```
Option Explicit
Public Function Sum(ByVal x As Integer, ByVal y As Integer) As Long
    Sum = x + y
End Function
```
Code est Module1 (module bas)
```
Option Explicit

Sub testSum()
Dim methodToCall As String
methodToCall = "Sum"

MsgBox CallByName(Sheet1, methodToCall, VbMethod, 1, 2)
End Sub
```
L'exécution de la méthode testSum appelle la méthode Sum en utilisant le nom de la méthode donnée dans une variable de chaîne, en passant par 2 paramètres (1 et 2). La valeur de retour de l'appel à la fonction est retourné en tant que sortie de CallByName.

Nice. J'aurais essayé d'Évaluer, puisque je ne savais pas que l'on.
Excellent, merci!
Salut.. si je ne veux pas que la "somme" de la fonction dans la feuille "Sheet1" .. mais dire dans Module1. Comment puis-je appeler Module1 "somme" de la fonction à l'aide de CallByName. Cela ne semble pas fonctionner. Veuillez informer.
Ce n'est pas possible. Vous pouvez utiliser Application.Run et passer le nom de la méthode, les paramètres à elle.
Merci.. qui fonctionne très bien!. N'Application.Run a aucun inconvénient par rapport à CallByName.. comme c'est lent, moins efficace, ou quelque chose comme ça.

OriginalL'auteur shahkalpesh
1

Ci-dessus fonctionne, mais pas avec un grand nombre de noms de

Utiliser L'Application.Exécuter(MacroName, Paramètres)

Vous avez peut être sûr qu'il existe une macro mais c'est mieux que le ci-dessus comme il n'y a pas d'instruction select.

OriginalL'auteur Adam Law
0

Vous devez écrire une fonction qui accepte la CB comme valeur d'un paramètre, puis utilise un select pour appeler le formatage de la fonction.

Quelque chose de semblable à ce
```
Function SelectFormatting(Name as String) As Boolean
Select Case CBinst.Value
Case "Text1":
   SelectFormatting = Text1FormattingFunction()
Case "Text2":
   .
   .
   .
End Select
End Function
```
Merci pour la réponse. C'est en effet le moyen simple de résoudre ce problème. J'espérais résumé mon chemin autour avoir à ajouter de cas pour chaque CB valeur pour deux raisons: 1) le code sera mis à jour régulièrement par les gens de différentes codage capacité et il serait agréable de les autoriser à ajouter une nouvelle CB option de formatage et de la fonction sans toucher les entrailles du programme et 2) la CB liste peut devenir assez longue. Peut-être que c'est juste ridicule sur l'ingénierie.

OriginalL'auteur Pepe

À l'égard de ma réponse ci-dessus, vous pouvez également trouver utile de vérifier si la macro existe

'=================================================================================
'- CHECK IF A MODULE & SUBROUTINE EXISTS
'- VBA constant : vbext_pk_Proc = All procedures other than property procedures.
'- An error is generated if the Module or Sub() does not exist - so we trap them.
'---------------------------------------------------------------------------------
'- VB Editor : Tools/References - add reference TO ......
'-    .... "Microsoft Visual Basic For Applications Extensibility"
'----------------------------------------------------------------------------------
'- Brian Baulsom October 2007
'==================================================================================
Sub MacroExists()
    Dim MyModule As Object
    Dim MyModuleName As String
    Dim MySub As String
    Dim MyLine As Long
    '---------------------------------------------------------------------------
    '- test data
    MyModuleName = "TestModule"
    MySub = "Number2"
    '----------------------------------------------------------------------------
    On Error Resume Next
    '- MODULE
    Set MyModule = ActiveWorkbook.VBProject.vbComponents(MyModuleName).CodeModule
    If Err.Number <> 0 Then
    MsgBox ("Module : " & MyModuleName & vbCr & "does not exist.")
    Exit Sub
    End If
    '-----------------------------------------------------------------------------
    '- SUBROUTINE
    '- find first line of subroutine (or error)
    MyLine = MyModule.ProcStartLine(MySub, vbext_pk_Proc)
    If Err.Number <> 0 Then
    MsgBox ("Module exists      : " & MyModuleName & vbCr _
           & "Sub " & MySub & "( )  : does not exist.")
    Else
    MsgBox ("Module : " & MyModuleName & vbCr _
        & "Subroutine   : " & MySub & vbCr _
        & "Line Number : " & MyLine)
    End If
End Sub
'-----------------------------------------------------------------------------------

OriginalL'auteur Adam Law

Vous devez vous connecter pour publier un commentaire.