EXCEL VBA, les Changements de groupes de cellules et Worksheet_Change événement

J'imagine que ce n'est pas si compliqué que ça, mais je ne vais pas avoir beaucoup de chance de trouver les bons termes pour Google... donc j'en suis venu à les experts!

Donc je suis en train de mettre en œuvre un Worksheet_Change événement. C'est extrêmement simple, en gros, je veux juste faire ce qui suit:

Si la Valeur dans la Colonne C, les changements, et la Valeur de D (en ligne) a une mise en forme spécifique (NumberFormat = "$ 0.00"), puis la Colonne E (en ligne) est le produit de ces deux valeurs. Facile. Pratiquement parlant, je veux juste le VBA équivalente à l'utilisation d'une formule dans le E colonne. Ce que le code que j'utilise:

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Column = 3 And Target.Value <> "" Then
    If Target.Offset(0, 1).NumberFormat = "$ 0.00" Then
        Target.Offset(0, 2).Value = Target.Value * Target.Offset(0, 1).Value
        End If
        End If   
end sub

Mon problème est surgissent lorsque j'essaie de coller à valeurs multiples sur plusieurs lignes de la colonne c. c'est à dire que je suis la copie d'une colonne de données (> 1 ligne) en C et j'ai une erreur d'incompatibilité de type. Je vais faire le gigantesque bond que c'est de ne pas traiter avec ce bien parce que la "cible" est destiné à être une cellule unique, par opposition à un groupe. J'espère qu'il existe un moyen simple de traiter avec ce qui n'implique pas de quelques fous de la boucle à chaque fois qu'une cellule de changements sur la feuille ou de quelque chose.

Merci d'avance!

InformationsquelleAutor Finch042 | 2013-04-21

Est-ce que vous essayez?

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim aCell As Range

    On Error GoTo Whoa

    Application.EnableEvents = False

    If Not Intersect(Target, Columns(3)) Is Nothing Then
        For Each aCell In Target
            If aCell.Value <> "" And aCell.Offset(0, 1).NumberFormat = "$ 0.00" Then
                aCell.Offset(0, 2).Value = aCell.Value * aCell.Offset(0, 1).Value
            End If
        Next
    End If

Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

Vous pouvez également lire CETTE?

Si vous voulais piège que le Col C Coller, mais ici est un autre scénario où l'utilisateur colle dans plusieurs colonnes (l'Un d'eux étant le Col C)

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim aCell As Range

    On Error GoTo Whoa

    Application.EnableEvents = False


    If Not Intersect(Target, Columns(3)) Is Nothing Then
        If Not Target.Columns.Count > 1 Then
            For Each aCell In Target
                If aCell.Value <> "" And aCell.Offset(0, 1).NumberFormat = "$ 0.00" Then
                    aCell.Offset(0, 2).Value = aCell.Value * aCell.Offset(0, 1).Value
                End If
            Next
        Else
            MsgBox "Please paste in 1 Column"
        End If
    End If

Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

Surtout à droite. Cependant, si la Cible s'étend au-delà de la colonne C, ce sera la cause de quelque chose d'horrible à arriver. Je pense que vous devez vérifier que la cible est SEULEMENT la colonne C, et de votre état de santé actuel ne le fait pas. Comme l'erreur étiquettes, et le Resume Letscontinue le flux du programme. Assez pour un upvote.
C'est exactement le genre de solution que je cherchais. Je vais avoir besoin de ruser un peu, mais il m'a sauvé beaucoup d'angoisse mentale, en essayant de faire le tri moi-même. Merci!
Mise à jour du code avec le scénario que vous avez mentionné
Vous êtes les bienvenus 🙂
la solution que j'avais en tête définit une nouvelle gamme à l'intersection de la Cible et le Col C, puis opère sur ces cellules. Il peut être généralisée à l'arbitraire d'un "bon" de la gamme, et pas seulement une seule colonne.
Si vous le souhaitez, vous pouvez poster votre version 🙂 je n'ai pas de problèmes 🙂
fait.

InformationsquelleAutor Siddharth Rout

Dans l'esprit de l'exhaustivité et de la collaboration, je vous poste ici une variation de Siddharth de la Déroute de la méthode; la différence est que cela ne repose pas sur des "cellules de loi sur" tous être dans une colonne. Cela rend les choses un peu plus propre, et plus facile à adapter à d'autres scénarios.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim aCell As Range
    Dim onlyThese As Range   ' collection of ranges that, if changed, trigger some action
    Dim cellsToUse As Range  ' cells that are both in "Target" and in "onlyThese"

    On Error GoTo Whoa

    Application.EnableEvents = False

    Set onlyThese = Range("C:C") ' in this instance, but could be anything - even a union of ranges
    Set cellsToUse = Intersect(onlyThese, Target)
    If cellsToUse Is Nothing Then GoTo Letscontinue

    ' loop over cells that were changed, and of interest:
    For Each aCell In cellsToUse
        If aCell.Value <> "" And aCell.Offset(0, 1).NumberFormat = "$ 0.00" Then
            aCell.Offset(0, 2).Value = aCell.Value * aCell.Offset(0, 1).Value
        End If
    Next

Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

InformationsquelleAutor Floris

Vous devez vous connecter pour publier un commentaire.