Excel VBA - Passer d'une Rangée de Valeurs des Cellules d'un Tableau, puis Collez ce Tableau une Référence Relative de Cellules

À l'aide d'Excel (2010) VBA, je suis en train de copier (passer) une constante de la plage de cellules (dont les valeurs recalculer) à un tableau. Alors je suis en train de passer ce tableau à une nouvelle plage de cellules, directement au-dessous. Après j'ai fait cela, je tiens encore une fois à copier (passer) la constante de la gamme de nouvelles valeurs dans le tableau, et de transmettre ces nouvelles valeurs d'une plage directement en dessous de celui que j'ai déjà passé.

Je sais que ce code est atroce (je suis nouvelle dans les tableaux en VBA).

Sub ARRAYER()

Dim anARRAY(5) As Variant

Number_of_Sims = 10

For i = 1 To Number_of_Sims
   anARRAY = Range("C4:G4")
   Range("C4").Select
   ActiveCell.Offset(Number_of_Sims, 0).Select
   ActiveCell = anARRAY
   Range("C4").Select
Next

End Sub

Je vous remercie de votre aide!

Merci.

Respectueusement,

Jonathan

Pourquoi voulez-vous utiliser un tableau? Ai-je raison de la compréhension que vous souhaitez copier la (changer) les valeurs en C4:G4 dans la ligne ci-dessous?
Salut Jonathan, pouvez-vous pls ajouter un exemple de ce que vous faites, peut-être une capture d'écran? Il n'est pas clair pour moi (au moins)

OriginalL'auteur Jonathan Ross Charlton | 2013-02-10

9

Vous sont légèrement sur quelques choses ici, donc j'espère que la suite aide.

Tout d'abord, vous n'avez pas besoin de sélectionner des plages d'accéder à leurs propriétés, vous pouvez simplement spécifier leur adresse, etc. Deuxièmement, si vous manipulez les valeurs de la plage, vous n'avez pas besoin de les mettre à une variante. Si vous ne souhaitez manipuler les valeurs, vous pouvez les laisser dehors des limites du tableau tel qu'il sera défini lorsque vous définissez la plage.

C'est aussi une bonne pratique de l'utilisation Option Explicit en haut de vos modules à la force de la déclaration de la variable.

La suite à faire ce que vous êtes après:
```
Sub ARRAYER()
    Dim Number_of_Sims As Integer, i As Integer

    Number_of_Sims = 10

    For i = 1 To Number_of_Sims
       'Do your calculation here to update C4 to G4
       Range(Cells(4 + i, "C"), Cells(4 + i, "G")).Value = Range("C4:G4").Value
    Next
End Sub
```
Si vous ne souhaitez manipuler les valeurs dans le tableau, puis faire ceci:
```
Sub ARRAYER()
    Dim Number_of_Sims As Integer, i As Integer
    Dim anARRAY as Variant

    Number_of_Sims = 10

    For i = 1 To Number_of_Sims
       'Do your calculation here to update C4 to G4
       anARRAY= Range("C4:G4").Value

       'You can loop through the array and manipulate it here

       Range(Cells(4 + i, "C"), Cells(4 + i, "G")).Value = anARRAY
    Next
End Sub
```
Merci Cuber Chasse! À l'aide de votre réponse et Chuff, je suis arriver à une meilleure compréhension du présent. J'ai vraiment l'apprécier.
Cela fonctionne merveilleusement bien!
Pas de soucis :). À l'aide de tableaux est presque toujours plus rapide et bénéfique que de travailler directement avec les gammes. C'est une bonne habitude à prendre.
À la ligne 3 du deuxième bloc, il vous manque un caractère d'espace.

OriginalL'auteur CuberChase
3

Pas besoin de tableau. Suffit d'utiliser quelque chose comme ceci:
```
Sub ARRAYER()

    Dim Rng As Range
    Dim Number_of_Sims As Long
    Dim i As Long
    Number_of_Sims = 10

    Set Rng = Range("C4:G4")
    For i = 1 To Number_of_Sims
       Rng.Offset(i, 0).Value = Rng.Value
       Worksheets("Sheetname").Calculate   'replacing Sheetname with name of your sheet
    Next

End Sub
```
Merci Chuff. La raison pour laquelle je suis à la recherche d'utiliser un tableau est parce qu'actuellement, je suis en cours d'exécution d'environ 10 000 à 100 000 simulations. Actuellement, je suis juste la copie de la plage, et puis le coller au bon endroit à l'aide d'Active de la Cellule de Décalage. J'ai vraiment apprécié les conseils. Juste une question, serait-ce de travailler aussi vite qu'un tableau? J'essaye de prendre mon temps d'exécution vers le bas à partir de 1 heure à 5 à 10 minutes.
GÉNIAL! Merci beaucoup!

OriginalL'auteur chuff

Puisque vous êtes la copie tha mêmes données pour toutes les lignes, vous n'avez pas besoin de boucle. Essayez ceci:

Sub ARRAYER()
    Dim Number_of_Sims As Long
    Dim rng As Range

    Application.Calculation = xlCalculationManual
    Application.ScreenUpdating = False
    Number_of_Sims = 100000

    Set rng = Range("C4:G4")
    rng.Offset(1, 0).Resize(Number_of_Sims) = rng.Value

    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
End Sub

OriginalL'auteur chris neilsen

Quand j'ai Essayé votre Code je l'ai eu en Erreur quand j'ai voulu remplir le Tableau.

vous pouvez essayer de remplir le Tableau de Ce genre.

Sub Testing_Data()
Dim k As Long, S2 As Worksheet, VArray

Application.ScreenUpdating = False
Set S2 = ThisWorkbook.Sheets("Sheet1")
With S2
    VArray = .Range("A1:A" & .Cells(Rows.Count, "A").End(xlUp).Row)
End With
For k = 2 To UBound(VArray, 1)
    S2.Cells(k, "B") = VArray(k, 1) / 100
    S2.Cells(k, "C") = VArray(k, 1) * S2.Cells(k, "B")
Next

End Sub

OriginalL'auteur Moosli

Vous devez vous connecter pour publier un commentaire.