Excel VBA Regex Match de Position

Comment puis-je récupérer la position de la première appariés résultat dans une expression régulière? Voir ci-dessous.

Function MYMATCH(strValue As String, strPattern As String, Optional blnCase As Boolean = True, Optional blnBoolean = True) As String
    Dim objRegEx As Object
    Dim strPosition As Integer

    ' Create regular expression.
    Set objRegEx = CreateObject("VBScript.RegExp")
    objRegEx.Pattern = strPattern
    objRegEx.IgnoreCase = blnCase

    ' Do the search match.
    strPosition = objRegEx.Match(strValue)

    MYMATCH = strPosition
End Function

Pour l'un, je ne suis pas tout à fait certaine de ce que .Match est de retour (string, integer, etc.). La seule solution que j'ai trouvé a dit que je devrais créer un Match objet pour ensuite attraper la position à partir de là, mais à la différence de vb, vba ne reconnaît pas le Match objet. J'ai aussi vu un peu de code comme le suivant, mais je ne suis pas nécessairement à la recherche de la valeur, la première chaîne de placement:

If allMatches.count <> 0 Then
    result = allMatches.Item(0).submatches.Item(0)
End If

Un peu ignorant les éventuelles erreurs de syntaxe ci-dessus (principalement en raison de m'en changeant les types de variables à droite et à gauche), comment puis-je facilement/simplement accomplir cette?

Merci!

Vous avez raison, ma faute (j'ai oublié qu'il aide tout le monde à la réputation sur ce site)...en plus de cela, je me suis rendu compte sur mon propre...encore une fois.
Cependant, je vais poster ma réponse: 8 heures pour le bénéfice de quelqu'un d'autre qui s'exécute ce problème.
Pourquoi 8 heures et pas maintenant?
Parce que je n'avais pas assez de réputation pour poster immédiatement.

OriginalL'auteur Jonathan | 2011-11-28

  1. 12

    Vous pouvez utiliser FirstIndex pour renvoyer la position de correspondances à l'aide de la Execute méthode, c'est à dire

    Function MYMATCH(strValue As String, strPattern As String, Optional blnCase As Boolean = True, Optional blnBoolean = True) As String
    Dim objRegEx As Object
    Dim strPosition As Integer
    Dim RegMC

    ' Create regular expression.
    Set objRegEx = CreateObject("VBScript.RegExp")
    With objRegEx
        .Pattern = strPattern
        .IgnoreCase = blnCase
        If .test(strValue) Then
            Set RegMC = .Execute(strValue)
            MYMATCH = RegMC(0).firstindex + 1
        Else
            MYMATCH = "no match"
        End If
    End With
End Function

Sub TestMe()
    MsgBox MYMATCH("test 1", "\d+")
End Sub

    OriginalL'auteur brettdj

  2. 4

    Pour le bénéfice de ceux qui peuvent avoir ce problème, j'ai enfin compris.

    Option Explicit

Function CHAMATCH(strValue As String, strPattern As String, Optional blnCase As Boolean = True, Optional blnBoolean = True) As String
    Dim objRegEx As Object
    Dim objPosition As Object
    Dim strPosition As String

    ' Create regular expression.
    Set objRegEx = CreateObject("VBScript.RegExp")
    objRegEx.Pattern = strPattern
    objRegEx.IgnoreCase = blnCase

    ' Do the search match.
    Set objPosition = objRegEx.Execute(strValue)
    strPosition = objPosition(0).FirstIndex

    CHAMATCH = strPosition
End Function

    Au lieu d'un Match type, juste un Object type va faire (en tenant compte de tous, il est de retour en classe). Alors, si vous voulez attraper l'emplacement de l'index, il suffit d'utiliser .FirstIndex sur le match [de votre choix], ou si vous voulez la valeur, nous .Value

    OriginalL'auteur Jonathan