Excel VBA supprimer toute la ligne, si la cellule dans la colonne D est vide

Solution: C'est de travailler pour moi:

Sub DeleteRowsWithEmptyColumnDCell()
    Dim rng As Range
    Dim i As Long
    Set rng = ThisWorkbook.ActiveSheet.Range("D13:D40")
    With rng
        ' Loop through all cells of the range
        ' Loop backwards, hence the "Step -1"
        For i = .Rows.Count To 1 Step -1
            If .Item(i) = "" Then
                ' Since cell is empty, delete the whole row
                .Item(i).EntireRow.Delete
            End If
        Next i
    End With
End Sub

Explication: Exécuter un for boucle dans toutes les cellules de votre Range dans la colonne D et de supprimer la totalité de la ligne si la valeur de la cellule est vide. Important: Lorsqu'une boucle à travers les lignes et la suppression de certains d'entre eux en fonction de leur contenu, vous devez boucle en arrière, pas avant. Si vous allez de l'avant et vous supprimez une ligne, toutes les lignes suivantes obtenir un autre numéro de ligne (-1). Et si vous avez deux cellules vides à côté de l'autre, seule la ligne de la première sera supprimé parce que la deuxième est un déplacement d'une ligne vers le haut, mais la boucle continue à la ligne suivante.

Voici mon prendre sur elle. Voir les commentaires dans le code pour ce qui se passe le long du chemin.

Sub deleterow()
  ' First declare the variables you are going to use in the sub
  Dim i As Long, safety_net As Long
  ' Loop through the row-numbers you want to change.
  For i = 13 To 40 Step 1
    ' While the value in the cell we are currently examining = "", we delete the row we are on
    ' To avoid an infinite loop, we add a "safety-net", to ensure that we never loop more than 100 times
    While Worksheets("Sheet3").Range("D" & CStr(i)).Value = "" And safety_net < 100
      ' Delete the row of the current cell we are examining
      Worksheets("Sheet3").Range("D" & CStr(i)).EntireRow.Delete
      ' Increase the loop-counter
      safety_net = safety_net + 1
    Wend
    ' Reset the loop-counter
    safety_net = 0
  ' Move back to the top of the loop, incrementing i by the value specified in step. Default value is 1.
  Next i
End Sub

Pour empêcher un utilisateur d'exécuter du code par accident, je serais probablement juste ajouter Option Private Module en haut du module, et protéger par mot de passe VBA-projet, mais là encore, il n'est pas que facile à exécuter par accident dans la première place.

Il n'est pas nécessaire pour les boucles ou les filtres pour trouver les cellules vides dans la Plage spécifiée. La Gamme.SpecialCells propriété peut être utilisée pour trouver toutes les cellules vides dans la Plage couplée à la Gamme.EntireRow propriété pour supprimer ces. Afin de préserver l'état d'exécution, le code ajoute un Commentaire à la première cellule de la plage. Cela permettra de préserver l'état d'exécution, même si le Classeur est fermé (en supposant qu'il a été enregistré).

Sub DeleteEmpty()
   Dim ws As Excel.Worksheet
   Set ws = ActiveSheet       ' change this as is appropriate
   Dim sourceRange As Excel.Range
   Set sourceRange = ws.Range("d13:d40")
   Dim cmnt As Excel.Comment
   Set cmnt = sourceRange.Cells(1, 1).Comment

   If Not cmnt Is Nothing Then
      If cmnt.Text = "Deleted" Then
         If MsgBox("Do you wish to continue with delete?", vbYesNo, "Already deleted!") = vbNo Then
            Exit Sub
         End If
      End If
   End If

   Dim deletedThese As Excel.Range
   On Error Resume Next
   ' the next line will throw an error if no blanks cells found
   ' hence the 'Resume Next'
   Set deletedThese = sourceRange.SpecialCells(xlCellTypeBlanks)
   On Error GoTo 0
   If Not deletedThese Is Nothing Then
      deletedThese.EntireRow.Delete
   End If

   ' for preserving run state
   If cmnt Is Nothing Then Set cmnt = sourceRange.Cells(1, 1).AddComment
   cmnt.Text "Deleted"
   cmnt.Visible = False
End Sub