Excel VBA .Trouver de méthode entre classeurs

Question:
Pourquoi le Range.Find méthode ne fonctionne pas lorsque le référencement d'un autre classeur?

Problème:
Je suis d'essayer de copier des données entre des classeurs, mais le Range.Find méthode est en cours d'arrêt avec une "Erreur d'Exécution 1004". J'utilise Excel 2007 sur une machine Windows 7.

Détails:
Sur deux classeurs, seule la feuille "Sheet1" est référencé ou utilisée pour chaque classeur. J'ai une procédure (ztest) avec le plan suivant:

  1. Format de la feuille
  2. Boucle dans toutes les cellules dans la colonne E du cahier de travail #1
  3. À l'aide de la Range.Find méthode, de trouver de la valeur dans la colonne E du cahier de travail #2
  4. Une fois trouvé, ensemble classeur n ° 1 décalage de colonne = classeur n ° 2 décalage de colonne

J'aimerais le faire avec .Find - pas à l'aide de HLOOKUP ou similaires.

J'ai simplifié le code un peu, à affiner ce qui se passe exactement. Cela ne montre pas l'étape 4 ci-dessus, mais l'erreur se produit à l'étape 3, dans la déclaration contenant les .Find méthode:

Public Sub ztest2()
'set workbook titles
Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"
Dim cl As Variant

With Workbooks(w2).Worksheets(1)
  'format the sheet
  .Range("A1", "D1").EntireColumn.Hidden = True
  'loop through all cells column E of workbook #1
  For Each cl In .Range("E2", Cells(Rows.Count, "E").End(xlUp))
    'find value of current cell in column E, workbook #2
    Workbooks(w1).Worksheets(1) _
    .Range("E2", Cells(Rows.Count, "E").End(xlUp)) _
    .Find(what:=cl.Value, LookIn:=xlValues).Select
  Next
End With

End Sub
Les oiseaux de Vue: il Vous manque un POINT avant de Cellules... Vous avez besoin pour obtenir votre objet de Cellules, en tous lieux.
BTW +1 pour un bien mis à la question...

OriginalL'auteur Aaron Thomas | 2013-09-23

  1. 2

    Il est très important que vous la structure de votre code très bien de sorte qu'il n'y a pas de mal à le comprendre. Si nécessaire, écrire des lignes de code supplémentaires, de sorte que même si vous voyez le code au bout de 6 mois, vous pouvez identifier ce que votre code ne. Aussi qualifier pleinement de vos objets.

    Essayez ceci (non testé). J'ai commenté le code. Donc, si vous ne comprenez pas quelque chose, puis après retour

    Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"

Sub ztest2()
    Dim wb1 As Workbook, wb2 As Workbook
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim cl As Range, ws1Rng As Range, ws2Rng As Range, aCell as Range
    Dim lRowW1 As Long, lRowW2 As Long

    '~~> Define your workbook and worksheets here
    Set wb1 = Workbooks(w1)
    Set ws1 = wb1.Sheets(1)
    Set wb2 = Workbooks(w2)
    Set ws2 = wb2.Sheets(1)

    '~~> Work with First workbook to get last row and define your range
    With ws1
        lRowW1 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws1Rng = .Range("E2:E" & lRowW1)
    End With

    '~~> Work with Second workbook to get last row and define your range
    With ws2
        .Range("A1", "D1").EntireColumn.Hidden = True

        lRowW2 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws2Rng = .Range("E2:E" & lRowW2)

        For Each cl In ws2Rng
            '~~> Do the find
            Set acell = ws1Rng.Find(what:=cl.Value, LookIn:=xlValues)

            '~~> Check if found or not. This is required else you will
            '~~> get an error if no match found
            If Not acell Is Nothing Then
                '
                '~~> Do what ever you want here
                '
            End If
        Next
    End With
End Sub
    Merci pour les bons conseils!!! Votre code fonctionne comme prévu. Je ne suis toujours pas sûr de ce qui se passe avec mon code. Je refais comme vous l'avez suggéré, peut-être qui va aider à réduire certains.
    Your code works as expected. De la musique à mes oreilles :p Comme je l'ai mentionné, votre objet de Cellules ne sont pas pleinement qualifiés et, par conséquent, vous obtenez cette erreur..
    Sid, j'apprécie vraiment l'aider! Désolé, j'aurais dit "Votre code fonctionne et est plus facile de suivre et de résoudre les problèmes." Ainsi, une grande leçon pour moi - assurez-vous que le code est structuré. J'aime bien le "assurez-vous qu'il peut être lu 6 mois plus tard" les conseils, surtout que je commence à construire mon propre sac de trucs à intégrer dans les différents projets. Merci encore!
    Pas de soucis 🙂 especially as I'm starting to build up my own bag of tricks to incorporate in different projects Plus de Conseils? Voir ‘Err’ est Homme

    OriginalL'auteur Siddharth Rout