Excel VBA Trouver la dernière ligne de plage

Espère que ce morceau de code permet de !

Sub LastRowInOneColumn()
'Find the last used row in a Column: column A in this example
    Dim LastRow As Long
    With ActiveSheet
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
    End With
    MsgBox LastRow
End Sub

LR_wbSelectNew = wbshtSelect.cells(LR_wbSelect, "B").End(xlUp).Row

Pourquoi êtes-vous à l'aide de "LR_wbSelect" comme la ligne contre? Si vous voulez connaître la dernière ligne de la colonne "B", vous devez utiliser les Lignes.le comte

Lignes.le comte --> Retourne le nombre maximal de lignes (ce qui est 1048576 pour Excel 2007 et plus)
End(xlUp) --> Déplace le pointeur vers le haut pour la dernière ligne

Donc,
les cellules(les Lignes.le comte, "Un").End(xlUp).Ligne --> Cela déplace le pointeur à la dernière ligne si la colonne " A " (comme si vous appuyant sur Ctrl+les touches Haut quand A1048576 cellule est sélectionnée)

Ainsi, l'utilisation de Lignes.le comte de sélectionner la dernière ligne de la colonne " B " ainsi. Si vous avez une exigence particulière relative à LR_wbSelect, veuillez le mentionner.

Alternativement, si vous voulez connaître la dernière ligne utilisée dans une feuille de calcul, vous pouvez utiliser le ci-dessous:

mySheet.Cells.SpecialCells(xlCellTypeLastCell).Row

Je suis venu ici à la recherche d'un moyen de trouver la dernière ligne d'une non contigus gamme. La plupart des réponses ici seulement de vérifier une seule colonne à la fois, alors j'ai créé quelques fonctions différentes pour résoudre ce problème. Je dois admettre, cependant, que Shai Rado réponse est essentiellement le même que celui de mon .Find() mise en œuvre.

Mise en œuvre 1 - Utilise Range().End(xlUp) sur chaque colonne

Function LastRowInRange_xlUp(ByVal rng As Range) As Long

    Dim lastRowCurrent As Long
    Dim lastRowBest As Long

    'loop through columns in range
    Dim i As Long
    For i = rng.Column To rng.Column + rng.Columns.count - 1
        If rng.Rows.count < Rows.count Then
            lastRowCurrent = Cells(rng.row + rng.Rows.count, i).End(xlUp).row
        Else
            lastRowCurrent = Cells(rng.Rows.count, i).End(xlUp).row
        End If

        If lastRowCurrent > lastRowBest Then
            lastRowBest = lastRowCurrent
        End If
    Next i

    If lastRowBest < rng.row Then
        LastRowInRange_xlUp = rng.row
    Else
        LastRowInRange_xlUp = lastRowBest
    End If

End Function

Mise en œuvre 2 - Utilise Range().Find() dans l'ordre inverse

Function LastRowInRange_Find(ByVal rng As Range) As Long

    'searches range from bottom up stopping when it finds anything (*)
    Dim rngFind As Range
    Set rngFind = rng.Find( What:="*", _
                            After:=Cells(rng.row, rng.Column), _
                            LookAt:=xlWhole, _
                            LookIn:=xlValues, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious)

    If Not rngFind Is Nothing Then
        LastRowInRange_Find = rngFind.row
    Else
        LastRowInRange_Find = rng.row
    End If

End Function

Mise en œuvre de 3 Boucles à travers un Tableau dans l'ordre inverse

Function LastRowInRange_Array(ByVal rng As Range) As Long

    'store range's data as an array
    Dim rngValues As Variant
    rngValues = rng.Value2

    Dim lastRow As Long

    Dim i As Long
    Dim j As Long

    'loop through range from left to right and from bottom upwards
    For i = LBound(rngValues, 2) To UBound(rngValues, 2)                'columns
        For j = UBound(rngValues, 1) To LBound(rngValues, 1) Step -1    'rows

            'if cell is not empty
            If Len(Trim(rngValues(j, i))) > 0 Then
                If j > lastRow Then lastRow = j

                Exit For
            End If

        Next j
    Next i

    If lastRow = 0 Then
        LastRowInRange_Array = rng.row
    Else
        LastRowInRange_Array = lastRow + rng.row - 1
    End If

End Function

Je n'ai pas testé lequel de ces mises en œuvres les plus rapides sur de grands ensembles de données, mais j'imagine que le gagnant serait _Array puisqu'il n'est pas une boucle dans chaque cellule de la feuille de manière individuelle, mais plutôt des boucles à travers les données stockées dans la mémoire. Cependant, j'ai inclus tous les 3 pour la variété 🙂

Comment utiliser

Pour utiliser ces fonctions, vous les déposez dans votre feuille de code/module de spécifier une plage comme de leurs paramètres, puis ils seront de retour le "plus" rempli de lignes à l'intérieur de cette gamme.

Voici comment vous pouvez utiliser n'importe quel d'entre eux pour résoudre le problème initial qui a été posée:

Sub answer()

    Dim testRange As Range
    Set testRange = Range("A1:F28")

    MsgBox LastRowInRange_xlUp(testRange)
    MsgBox LastRowInRange_Find(testRange)
    MsgBox LastRowInRange_Array(testRange)

End Sub

Chacun de ces sera de retour 18.

Le problème avec le fait d'essayer de faire, c'est que si une cellule contient une formule, excel pense que c'est peuplée, même si la formule est de retour d'un vide.

Shai Rado première solution est un grand, mais pour certains, il pourrait avoir besoin d'un peu plus d'élaboration:

 Dim rngCurr, lastRow
 rngCurr = wbshtSelect.Range("B10").CurrentRegion
 lastRow = rngCurr.Rows(rngCurr.Rows.Count).Row

Si vous voulez savoir, la dernière ligne de la feuille de calcul entière:

 Dim rngCurr, lastRow
 rngCurr = Range("A1").CurrentRegion
 lastRow = rngCurr.Rows(rngCurr.Rows.Count).Row

Si vous trouvez cela utile, veuillez upvote sa réponse.