“Expression régulière”style remplacer en XSLT 1.0

J'ai besoin d'effectuer une rechercher et remplacer à l'aide de XSLT 1.0 qui est vraiment adapté à des expressions régulières. Malheureusement, elles ne sont pas disponibles en 1.0 et je suis également incapables d'utiliser les bibliothèques d'extension tels que EXSLT en raison des paramètres de sécurité je ne peux pas changer.

La chaîne, je travaille avec des regards comme:

19;#John Smith;#17;#Ben Reynolds;#1;#Terry Jackson

J'ai besoin de remplacer les numéros et ; # caractères avec un ,. Pour l'exemple ci-dessus serait de changer:

John Smith, Ben Reynolds, Terry Jackson

Je sais récursif de la fonction de chaîne est nécessaire, probablement à l'aide de sous-chaîne et de la traduire, mais je ne suis pas sûr où commencer.

Quelqu'un aurait-il quelques conseils sur la façon de faire ce travail? Voici ce que j'ai commencé avec:

<xsl:template name="TrimMulti">
    <xsl:param name="FullString" />
    <xsl:variable name="NormalizedString">
        <xsl:value-of select="normalize-space($FullString)" />
    </xsl:variable>
    <xsl:variable name="Hash">#</xsl:variable>
    <xsl:choose>
        <xsl:when test="contains($NormalizedString, $Hash)">
            <!-- Do something and call TrimMulti -->
        </xsl:when>
    </xsl:choose>
</xsl:template>

OriginalL'auteur Alex Angas | 2009-06-25

  1. 8

    J'espère que vous n'avez pas simplifié le problème de trop pour lui demander, parce que ce ne devrait pas être beaucoup d'un problème.

    Vous pouvez définir un modèle et de manière récursive l'appeler aussi longtemps que vous gardez l'entrée de la chaîne de format uniforme.

    Par exemple,

    <xsl:template name="TrimMulti">
  <xsl:param name="InputString"/>
  <xsl:variable name="RemainingString" 
    select="substring-after($InputString,';#')"/>
  <xsl:choose>
    <xsl:when test="contains($RemainingString,';#')">
      <xsl:value-of 
        select="substring-before($RemainingString,';#')"/>
      <xsl:text>, </xsl:text>
      <xsl:call-template name="TrimMulti">
        <xsl:with-param 
          name="InputString"
          select="substring-after($RemainingString,';#')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$RemainingString"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

    J'ai testé ce modèle avec l'appel suivant:

    <xsl:template match="/">
  <xsl:call-template name="TrimMulti">
    <xsl:with-param name="InputString">19;#John Smith;#17;#Ben Reynolds;#1;#Terry Jackson</xsl:with-param>
  </xsl:call-template>
</xsl:template>

    Et a obtenu le résultat suivant:

    John Smith, Ben Reynolds, Terry Jackson

    Qui semble être ce que vous êtes après.

    L'explication de ce qu'il fait est facile à expliquer si vous êtes familier avec la programmation fonctionnelle. Le InputString paramètre est toujours dans la forme [number];#[name];#[rest of string]. Chaque appel de la TrimMulti modèle de côtelettes au large de la [number];# partie et imprime le [name] partie, puis passe le reste de l'expression de lui-même de manière récursive.

    Le cas de base est quand InputString est dans la forme [number];#[name], auquel cas le RemainingString variable ne contiennent pas ;#. Puisque nous savons que c'est la fin de l'entrée, nous n'avons pas sortie une virgule de ce temps.

    Pas simplifié, mais j'ai du mal à savoir par où commencer avec les plus avancés XSLT trucs! Je ne travaille pas avec elle souvent.
    Angas: Ouais, XSLT + de manipulation de chaîne = une douleur dans le cul. Heureusement, dans votre cas particulier, les noms ne sont pas très difficile à analyser. J'ai vu bien pire.
    Fonctionne parfaitement et je la comprends. Merci!!!!
    Là vous allez. 🙂 +1
    AHA! Je vous l'ai dit!

    OriginalL'auteur Welbog

  2. -1

    Si le ';' et '#' caractères ne sont pas valides dans l'entrée parce qu'ils sont des délimiteurs alors pourquoi ne pas la fonction de traduction de travail? Il peut être laid (vous devez spécifier tous les caractères valides dans le deuxième argument et de les répéter dans le troisième argument), mais il serait plus facile à déboguer.

    translate($InputString, ';#abcdefghijklmnopqrstuvABCDEFGHIJKLMNOPQRSTUZ0123456789,- ', ', abcdefghijklmnopqrstuvABCDEFGHIJKLMNOPQRSTUZ0123456789,- ')
    Comment savez-vous que vous avez la liste de tous les caractères valides? Vous n'avez pas. Même si vous l'avez fait, c'est un échec car la liste pourrait changer. Peut-on sort de l'UTF-8?

    OriginalL'auteur Don