Faire Des Winforms En Plein Écran

J'ai besoin de faire une winform en plein écran. C'est ce que j'ai trouvé en ligne.

1. Hook WinProc to catch WM_SYSCOMMAND

2. Check wParam == SC_MAXIMIZE and then

3. Set my windiw's attributes

Me.ResizeMode = ResizeMode.NoResize

Me.WindowStyle = WindowStyle.None

Me.WindowState = WindowState.Maximized

Je suis assez nouveau à l'vb.net et ne savent pas comment faire les Étapes 1 ou 2. Quelqu'un peut-il me donner un morceau de code ou me diriger dans la bonne direction?

Grâce giodamelio

OriginalL'auteur giodamelio | 2011-01-10

  1. 6

    L'astuce consiste à obtenir la HwndSource et appeler sa AddHook() la méthode. Cela fonctionne:

    Imports System.Windows.Interop

Class Window1
    Protected Overrides Sub OnSourceInitialized(ByVal e As System.EventArgs)
        MyBase.OnSourceInitialized(e)
        DirectCast(PresentationSource.FromVisual(Me), HwndSource).AddHook(AddressOf WndProc)
    End Sub

    Private Const WM_SYSCOMMAND As Integer = &H112
    Private Const SC_MAXIMIZE As Integer = &HF030

    Private Function WndProc(ByVal hWnd As IntPtr, ByVal msg As Integer, ByVal wp As IntPtr, ByVal lp As IntPtr, ByRef handled As Boolean) As IntPtr
        If msg = WM_SYSCOMMAND AndAlso wp.ToInt32() = SC_MAXIMIZE Then
            Me.ResizeMode = ResizeMode.NoResize
            Me.WindowStyle = WindowStyle.None
            Me.WindowState = WindowState.Maximized
            handled = True
        End If
    End Function

End Class

    Le même code pour un Winforms Forme:

    Public Class Form1
    Private Const WM_SYSCOMMAND As Integer = &H112
    Private Const SC_MAXIMIZE As Integer = &HF030

    Protected Overrides Sub WndProc(ByRef m As Message)
        If m.Msg = WM_SYSCOMMAND AndAlso m.WParam.ToInt32() = SC_MAXIMIZE Then
            Me.FormBorderStyle = FormBorderStyle.None
            Me.WindowState = FormWindowState.Maximized
            Return
        End If
        MyBase.WndProc(m)
    End Sub

    Protected Overrides Function ProcessCmdKey(ByRef msg As Message, ByVal keyData As Keys) As Boolean
        '' Restore window when the user presses Escape
        If Me.WindowState = FormWindowState.Maximized AndAlso keyData = Keys.Escape Then
            Me.FormBorderStyle = Windows.Forms.FormBorderStyle.Sizable
            Me.WindowState = FormWindowState.Normal
        End If
        Return MyBase.ProcessCmdKey(msg, keyData)
    End Function

End Class
    Merci beaucoup. Pouvez-vous me donner un exemple de ce que j'appellerais masquer et afficher la barre des tâches?
    Avez-vous l'essayer? Vous n'avez pas à masquer la barre des tâches, une fenêtre sans bordure est autorisé à se chevaucher.
    Sa me donnant des charges d'erreurs.` 'OnSourceInitialized" n'est pas un membre de 'Système.De Windows.Les formulaires.Formulaire"
    C'est le code WPF, pas Winforms code. C'est ce que vous avez demandé lorsque vous utilisez des propriétés comme ResizeMode et WindowStyle. Je vais devoir modifier mon post 🙁
    Désolé je ne savais pas, merci

    OriginalL'auteur Hans Passant

  2. 0

    Désolé c'est en C# (pas VB) mais c'est peut-être encore plus utile pour vous:

    Voici une méthode que j'utilise pour une application winforms qui a un mode plein écran:

        private void FullScreen(bool Enable)
    {
        SizeChanged -= FormMain_SizeChanged;

        SuspendLayout();
        if (Enable)
        {
            FormBorderStyle = FormBorderStyle.None;
            WindowState = FormWindowState.Maximized;
            if (settings.HideFullScreenCursor)
                Cursor.Hide();
            menuStrip.Visible = false;
        }
        else
        {
            FormBorderStyle = FormBorderStyle.Sizable;
            WindowState = FormWindowState.Normal;
            if (settings.HideFullScreenCursor)
                Cursor.Show();
            menuStrip.Visible = true;
        }
        ResumeLayout();

        SizeChanged += FormMain_SizeChanged;
    }

    Bien sûr, vous aurez probablement envie de les modifier pour les adapter à vos besoins, mais nous espérons que cela vous donne un point de départ.

    Merci, C'est proche. Mais lorsque j'exécute ce code la barre des tâches de windows est toujours là.
    La barre des tâches ne montrent parfois pendant une seconde ou deux, mais disparaît. (Je ne suis pas sûr de ce qu'il provoque à s'attarder un instant.)
    Dans WinXP la barre des tâches n'a pas disparaître au bout de 5 minutes.
    Intéressant. J'ai testé sur Windows 7.

    OriginalL'auteur JYelton