Fetch table spécifique uniquement à partir de site web dans Excel

J'ai besoin de récupérer la table de http://www.zillow.com/homes/comps/67083361_zpid/ dans Excel en utilisant VBA. Je veux juste de la table, rien d'autre. Mais quand je suis en utilisant:

Set objIE = CreateObject("InternetExplorer.Application")

With objIE
    .Visible = True
    .Navigate "http://www.zillow.com/homes/comps/67083361_zpid/"
    Do While .ReadyState <> 4: DoEvents: Loop
    Debug.Print .document.Body.outerText
End With

il me donne un texte comme:

4723 N 63e Dr$63,50008/17/201241.752,0747,6751972$360.11

pour chaque produit dont je ne peux pas analyser et de stocker dans les différentes cellules de Excel.

Donc, il y a un moyen pour que je puisse récupérer les données de la page dans une manière gérable. Je suis OK si j'ai besoin de parcourir une boucle pour cela. Aussi je peux faire un traitement supplémentaire pour remplir la ligne de données dans Excel correctement.

Voir 🙂 ...HTH

OriginalL'auteur Tejas | 2012-10-20

  1. 11

    J'utiliserais ci-dessous depuis que j'ai trouver des tables de requêtes lentes et IE désespérément lente 😉

    Sub GetData()
    Dim x As Long, y As Long
    Dim htm As Object

    Set htm = CreateObject("htmlFile")

    With CreateObject("msxml2.xmlhttp")
        .Open "GET", "http://www.zillow.com/homes/comps/67083361_zpid/", False
        .send
        htm.body.innerhtml = .responsetext
    End With

    With htm.getelementbyid("comps-results")
        For x = 0 To .Rows.Length - 1
            For y = 0 To .Rows(x).Cells.Length - 1
                Sheets(1).Cells(x + 1, y + 1).Value = .Rows(x).Cells(y).innertext
            Next y
        Next x
    End With

End Sub
    Solution parfaite. Merci beaucoup 🙂
    Salut, Pouvez-vous s'il vous plaît regardez dans ma question stackoverflow-question je suis sûr que vous avez la meilleure réponse! 🙂
    J'ai ouvert un module vide et le code s'arrête avec object variable or with block not set sur For x = 0 To .Rows.Length - 1
    Ce que la bibliothèque ne le htmlFile objet venu?
    Microsoft HTML Object Library

    OriginalL'auteur SWa

  2. 5

    Je l'ai fait à l'aide de code suivant:

    Sub FetchData()
    With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://www.zillow.com/homes/comps/67083361_zpid", Destination:=Range( _
        "$A$1"))
        .Name = "67083361_zpid"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .WebSelectionType = xlEntirePage
        .WebFormatting = xlWebFormattingNone
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
End Sub

    OriginalL'auteur Tejas