Fichier de commandes à split .fichier csv

Gratuitement une application windows qui n'a que

http://www.addictivetips.com/windows-tips/csv-splitter-for-windows/

Si le fractionnement des fichiers très volumineux, la solution que j'ai trouvé est une adaptation de cette, avec PowerShell "embedded" dans un fichier de commandes. Cela fonctionne rapide, contrairement à beaucoup d'autres choses que j'ai essayé (je ne sais pas sur les autres options posté ici).

La façon d'utiliser mysplit.bat ci-dessous est

mysplit.bat <mysize> 'myfile'

Remarque: Le script a pour but d'utiliser le premier argument que la répartition de la taille. Il est actuellement codé en dur à 100 mo. Il ne devrait pas être difficile à résoudre ce problème.

Note 2: Le filname doivent être entourés de guillemets simples. D'autres solutions de rechange pour la citation, apparemment, ne fonctionne pas.

Note 3: Il divise le fichier en nombre d'octets, et non pas au nombre de lignes. Pour moi, c'était assez bon.
Quelques lignes de code pourrait être probablement ajoutées pour compléter chaque bloc de lecture, jusqu'à la prochaine CR/LF. Ce sera divisée en lignes pleines (pas avec un nombre constant d'entre eux), sans sacrifice de temps de traitement.

Script mysplit.bat:

@REM Using https://stackoverflow.com/questions/19335004/how-to-run-a-powershell-script-from-a-batch-file
@REM and https://stackoverflow.com/questions/1001776/how-can-i-split-a-text-file-using-powershell
@PowerShell  ^
    $upperBound = 100MB;  ^
    $rootName = %2;  ^
    $from = $rootName;  ^
    $fromFile = [io.file]::OpenRead($from);  ^
    $buff = new-object byte[] $upperBound;  ^
    $count = $idx = 0;  ^
    try {  ^
        do {  ^
            'Reading ' + $upperBound;  ^
            $count = $fromFile.Read($buff, 0, $buff.Length);  ^
            if ($count -gt 0) {  ^
                $to = '{0}.{1}' -f ($rootName, $idx);  ^
                $toFile = [io.file]::OpenWrite($to);  ^
                try {  ^
                    'Writing ' + $count + ' to ' + $to;  ^
                    $tofile.Write($buff, 0, $count);  ^
                } finally {  ^
                    $tofile.Close();  ^
                }  ^
            }  ^
            $idx ++;  ^
        } while ($count -gt 0);  ^
    }  ^
    finally {  ^
        $fromFile.Close();  ^
    }  ^
%End PowerShell%

J'ai trouvé cette question tout en regardant pour une solution similaire. J'ai modifié la réponse de @Dale a donné pour répondre à mes fins. Je voulais quelque chose qui était un peu plus souple et a eu une erreur de piégeage. Juste pensé que je pourrais le mettre ici pour une personne qui cherche la même chose.

@echo off
setLocal EnableDelayedExpansion
GOTO checkvars

:checkvars
    IF "%1"=="" GOTO syntaxerror
    IF NOT "%1"=="-f"  GOTO syntaxerror
    IF %2=="" GOTO syntaxerror
    IF NOT EXIST %2 GOTO nofile
    IF "%3"=="" GOTO syntaxerror
    IF NOT "%3"=="-n" GOTO syntaxerror
    IF "%4"==""  GOTO syntaxerror
    set param=%4
    echo %param%| findstr /xr "[1-9][0-9]* 0" >nul && (
        goto proceed
    ) || (
        echo %param% is NOT a valid number
        goto syntaxerror
    )

:proceed
    set limit=%4
    set file=%2
    set lineCounter=1+%limit%
    set filenameCounter=0

    set name=
    set extension=

    for %%a in (%file%) do (
        set "name=%%~na"
        set "extension=%%~xa"
    )

    for /f "usebackq tokens=*" %%a in (%file%) do (
        if !lineCounter! gtr !limit! (
            set splitFile=!name!_part!filenameCounter!!extension!
            set /a filenameCounter=!filenameCounter! + 1
            set lineCounter=1
            echo Created !splitFile!.
        )
        cls
        echo Adding Line !splitFile! - !lineCounter!
        echo %%a>> !splitFile!
        set /a lineCounter=!lineCounter! + 1
    )
    echo Done!
    goto end
:syntaxerror
    Echo Syntax: %0 -f Filename -n "Number Of Rows Per File"
    goto end
:nofile
    echo %2 does not exist
    goto end
:end