filtre en continu à l'aide de zone de texte

J'ai besoin de laisser aux utilisateurs de filtrer un formulaire continu à l'aide de valeurs que l'utilisateur entre dans une zone de texte. Et le continu de la forme imbriquée à l'intérieur d'un couple de niveaux de navigation des sous-formulaires. Cela semble assez facile, mais tous les exemples que j'ai trouver sur le web l'utilisation de macros au lieu de vba.

J'ai mis en place la structure et a écrit une procédure AfterUpdate pour une zone de texte txtFilter comme suit:

Private Sub txtFilter_AfterUpdate()
    Dim filterval As String
    filterval = txtFilter.Value
    With Forms!Main!NavigationSubform.Form!NavigationSubform.Form
        .Filter = "LastName Like " & filterval
        .FilterOn = True
    End With
End Sub

J'ai joué avec une syntaxe différente, mais aucune ne semble fonctionner correctement. Voici un lien pour télécharger les parties pertinentes de la base de données à partir d'un fichier, le site de partage: http://jmp.sh/v/HGctZ4Ru74vDAjzN43Wq

Quelqu'un peut me montrer comment modifier cela afin que les utilisateurs peuvent utiliser la zone de texte pour filtrer le formulaire continu?

InformationsquelleAutor CodeMed | 2013-11-13

2

Je l'ai eu à travailler à l'aide de ceci: .Filter = "LastName Like """ & filterval & """"

Besoin de ces ennuyeux Chaîne Identificateurs de même pour les chaînes parfois.

Ok, Pour obtenir le formulaire pour ouvrir avec aucun enregistrement, puis tirez vers le haut uniquement les enregistrements que vous (ou l'utilisateur) indique est plus facile avec un peu de re-travail.
(Je vous recommande de travailler avec une copie et non l'original de votre)
1:Sur votre Formulaire Continu, retirez la Source, nous allons utiliser la Liaison Tardive (un Peu)
2:supprimez le code sous la txtFilter boîte, puis de les supprimer de la boîte elle-même.
3:Ajouter une zone de liste déroulante avec quelque chose comme ce que la source:
SELECT DISTINCT myTable.LastName FROM myTable ORDER BY myTable.LastName; (Ainsi, vous obtenez une liste unique des noms de famille afin de savoir comment épeler le nom ne sera pas nécessaire, de plus il assure au moins un match)
4:Dans l'Après événement de mise à Jour de la zone de liste déroulante, ajoutez le code comme ceci:
```
Dim strSource As String
strSource = "SELECT mt.IntakeNumber, mt.ClientNumber, " & _
    "mt.LastName, mt.FirstName, mt.ConsultationDate " & _
    " FROM myTable mt " & _
    "WHERE (mt.LastName)= '" & Me.cboFilter.Value & "'"

Me.RecordSource = strSource
Me.Requery
```
Évidemment, vous aurez besoin de changer la table et les noms de champs que nécessaire, mais j'espère que vous obtenez l'idée.
- Vous avez probablement besoin d'astérisques ou des étoiles encore trop: Filter = "LastName Like '*" & filterval & "*'"
- HK1 la réponse est mieux que la volonté de permettre à tous les matches, pas seulement exact.
- Je vous remercie. Maintenant, comment puis-je obtenir de sorte que le continu formulaire se vide lorsque le formulaire est chargé? Il y aura des dizaines de milliers d'enregistrements dans la base de données de la table, et je ne veux que l'utilisateur puisse voir les sous-ensembles d'enregistrements qui répondent à des critères entrés dans le txtFilter zone de texte. Actuellement, la totalité du contenu de la table sont en train d'apparaître dans les résultats lors du chargement du formulaire. Mais le filtre de recherche fonctionne lorsque l'utilisateur entre quelque chose dans txtFilter
- Veuillez voir la mise à jour ci-dessus.
- Je vous remercie. Je vais donner la réponse. Cependant, je suis juste en utilisant HK1 d'édition de votre suggestion parce que je veux avoir un code simple pour faciliter la maintenabilité au fil du temps.
- Pas de soucis, content que nous pourrions les aider.
InformationsquelleAutor craig.white

Option Compare Database
Option Explicit '<- always include this!!!!!

Private Sub txtFilter_AfterUpdate()
    Dim strFilter As String

    ' only set Filter when text box contains something
    ' to search for ==> don't filter Null, empty string,
    ' or spaces
    If Len(Trim(Me.txtFilter.Value & vbNullString)) > 0 Then
        strFilter = "LastName Like '*" & _
            Replace(Me.txtFilter.Value, "'", "''") & _
            "*'"
        ' that Replace() prevents the procedure from breaking
        ' when the user enters a name with an apostrophe
        ' into the text box (O'Malley)
        Debug.Print strFilter ' see what we built, Ctrl+g
        Me.Filter = strFilter
        Me.FilterOn = True
    Else
        ' what should happen here?
        ' maybe just switch off the filter ...
        Me.FilterOn = False
    End If
End Sub

InformationsquelleAutor HansUp

Vous devez vous connecter pour publier un commentaire.