Flash - Play clip dans le sens inverse?

Que j'essaie de faire un clip pour jouer en sens inverse quand je mouse_out (il joue sur mouse_over).

Mon actionscript est comme suit:

mc.stop();
mc.addEventListener(MouseEvent.MOUSE_OVER,mover);
mc.addEventListener(MouseEvent.MOUSE_OUT,mout);

function mover(e:MouseEvent):void
{
    mc.play();
}

function mout(e:MouseEvent):void
{
   //Play in reverse
}

Comment pourrais-je y parvenir?

Grâce

OriginalL'auteur Probocop | 2010-01-12

  1. 15

    Le meilleur moyen serait d'utiliser un écouteur d'événement ENTER_FRAME. Fondamentalement, ce est ce que vous voulez faire

    function mover(e:MouseEvent):void {
    stopPlayReverse();
    mc.play();
}

function mout(e:MouseEvent):void {
    this.addEventListener(Event.ENTER_FRAME, playReverse, false, 0, true);
}

function playReverse(e:Event):void {
    if (mc.currentFrame == 1) {
        stopPlayReverse();
    } else {
        mc.prevFrame();
    }
}

function stopPlayReverse():void {
    if (this.hasEventListener(Event.ENTER_FRAME)) {
        this.removeEventListener(Event.ENTER_FRAME, playReverse);
    }
}

    Ce serait jouer votre MovieClip dans le sens inverse jusqu'à ce qu'il frappe l'image 1, puis il s'arrête.

    Merci beaucoup cela a parfaitement fonctionné!
    Pas de problème. Comme l'a suggéré, vous pouvez essayer de l'aide de l'Interpolation de la classe ou de l'autre de l'interpolation de la bibliothèque. La meilleure chose à propos de la ENTER_FRAME approche est que l'animation prend la même quantité de temps de reculer ou d'avancer quel que soit votre taux de trame.

    OriginalL'auteur sberry

  2. 5

    Si le mouvement le permet, vous pouvez utiliser une Interpolation (par exemple, si vous souhaitez modifier l'alpha, l'emplacement ou l'échelle). Sur le MouseOut que vous pouvez appeler .yoyo() pour l'Interpolation, qui jouera dans le sens inverse.

    Quelque chose comme ceci:

    var tween:Tween;

mc.addEventListener(MouseEvent.MOUSE_OVER,mover);
mc.addEventListener(MouseEvent.MOUSE_OUT,mout);

function mover(e:MouseEvent):void
{
    tween = new Tween(obj, "alpha", None.easeNone, 1, 0, 1, true);
}

function mout(e:MouseEvent):void
{
   tween.yoyo();
}

    OriginalL'auteur Pbirkoff

  3. 4
    TweenLite.to(mc, 2, {frame:1});

    OriginalL'auteur a--m

  4. 1

    Si votre adolescent n'est pas grave, vous pouvez littéralement faire une toute nouvelle série d'images en sens inverse et tout simplement jouer il de l'image clé.

    C'est que le pauvre homme à l'inverse interpolation.

    Très vrai, et comment il a été fait pendant des siècles.

    OriginalL'auteur M. Ryan

  5. 0

    À l'aide d'un booléen qui fonctionne comme un déclencheur et Event.ENTER_FRAME, vous pouvez effectuer les opérations suivantes pour inverser les images:

    //Boolean and Event.ENTER_FRAME
var reversing:Boolean = false;
AddEventListener(Event.ENTER_FRAME, reverse);

function reverse(e:Event){
    if(reversing)
    {
        //mc is displaying previous frame every frame
        mc.prevFrame();

        //until the currentFrame is 1
        if(mc.currentFrame == 1)
            reversing = false;
    }
}

    Votre //Play in reverse serait mis reversing = true;

    OriginalL'auteur Xerxous

  6. 0

    Vous pouvez le faire en passant l'objet de clip pour trouver le bon objet à l'inverse. De cette manière vous aide à utiliser avec l'enfant que vous voulez. Vous pouvez vous le procurer:

    fMoveBack(ce.getChildByName("my_clip"));

    function fMoveBack(my_clip:MovieClip):void {
    this.addEventListener(Event.ENTER_FRAME, playReverse(my_clip));
}

function playReverse(mc:MovieClip):Function {
    return function playReverse(e:Event):void {
        if (mc.currentFrame == 1) {
            stopPlayReverse(mc);
        } else {
            mc.prevFrame();
        }
    };
}

function stopPlayReverse(mc:MovieClip):void {
    if (this.hasEventListener(Event.ENTER_FRAME)) {
        this.removeEventListener(Event.ENTER_FRAME, playReverse);
    }
}

    OriginalL'auteur Sky Games Inc