Forcer MSXML pour le format de sortie XML avec des tirets et des retours à la ligne

Je suis l'aide de MSXML 3.0 avec Visual Basic 6 pour stocker et récupérer la configuration de mon application. Lors de l'enregistrement de l'résultant DOMDocument à un fichier XML de l'objet racine est rendu qu'une seule très longue ligne de texte:

<?xml version="1.0"?>
<!--WORKAPP 2011 Configuration file-->
<profile version="1.0"><frmPlan><left>300</left><top>300</top><width>24600</width><height>13575</height></frmPlan><preferences><text1/><text2/><text3/><background_color/><grid-major-step-x>50</grid-major-step-x><grid-major-step-y>50</grid-major-step-y></preferences></profile>

Est-il possible de forcer MSXML pour formater le fichier XML résultant en tirets et des retours à la ligne?

OriginalL'auteur ezpresso | 2011-06-19

  1. 7

    De minuscules fichiers de config de la surcharge de l'aide de XSL n'est probablement pas important de toute façon. La puissance de SAX est plus important lorsque vous faites affaire avec de gros fichiers ou des tonnes de petits tels que le côté serveur d'un Service Web - et là, vous ne devriez probablement pas être en utilisant le poids lourd DOM en premier lieu.

    Private Sub FormatDocToFile(ByVal Doc As MSXML2.DOMDocument, _
                            ByVal FileName As String)
    'Reformats the DOMDocument "Doc" into an ADODB.Stream
    'and writes it to the specified file.
    '
    'Note the UTF-8 output never gets a BOM.  If we want one we
    'have to write it here explicitly after opening the Stream.
    Dim rdrDom As MSXML2.SAXXMLReader
    Dim stmFormatted As ADODB.Stream
    Dim wtrFormatted As MSXML2.MXXMLWriter

    Set stmFormatted = New ADODB.Stream
    With stmFormatted
        .Open
        .Type = adTypeBinary
        Set wtrFormatted = New MSXML2.MXXMLWriter
        With wtrFormatted
            .omitXMLDeclaration = False
            .standalone = True
            .byteOrderMark = False 'If not set (even to False) then
                                   '.encoding is ignored.
            .encoding = "utf-8"    'Even if .byteOrderMark = True
                                   'UTF-8 never gets a BOM.
            .indent = True
            .output = stmFormatted
            Set rdrDom = New MSXML2.SAXXMLReader
            With rdrDom
                Set .contentHandler = wtrFormatted
                Set .dtdHandler = wtrFormatted
                Set .errorHandler = wtrFormatted
                .putProperty "http://xml.org/sax/properties/lexical-handler", _
                             wtrFormatted
                .putProperty "http://xml.org/sax/properties/declaration-handler", _
                             wtrFormatted
                .parse Doc
            End With
        End With
        .SaveToFile FileName
        .Close
    End With
End Sub

    OriginalL'auteur Bob77

  2. 3

    Probablement cette réponse ne va pas aider dans votre cas particulier, mais en général, il peut être utile. Cela concerne les cas où le document est chargé et enregistré sans trop de modification. DomDocument a preserveWhitespace de la propriété, qui est initialement fixé à False. Si vous le réglez à True avant load, alors il sera enregistré à l'aide de la même indentation que le fichier d'origine.

    Pour ajouter l'indentation manuellement on peut créer des nœuds de texte et de les insérer à créer de nouvelles lignes et les espaces entre les éléments, comme ceci:

    Set txt = doc.createTextNode(vbCrLf & "  ")
Call node.parentNode.insertBefore(txt, node)
    En fait, c'était tout à fait utile. Je ne crois pas que toutes les propositions de transformations xslt va fonctionner pour les versions de msxml avant 6.0: j'ai passé de nombreuses heures sur ce, et bien que je n'ai pas encore trouver une explication pourquoi pas, je ne pense pas que le "tiret" drapeau est pris en charge avant la 6.0

    OriginalL'auteur Jarekczek

  3. 2

    Vous pouvez prendre un coup d'oeil à cette autre question sur DONC et le code C++ de réponses. Mais c'est trop de travail. Vous voulez dire que vous êtes tout simplement de stocker un fichier de config. Donc, utiliser une transformation XSLT:

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

    N'oubliez pas de sortie pour un ADODB.Flux, non pas d'un DOM. Si vous la sortie d'un DOM, XSLT sérialiseur sera ignoré.

    Pourriez-vous inclure quelque chose sur l'endroit où vous le mettez dans MSXML?
    Vous placez le code dans un fichier XSLT (comme pretty.xsl), puis exécutez une transformation, ce qui peut être fait à l'aide de la Microsoft msxsl.exe utilitaire de ligne de commande ou tout autre processeur XSLT. Vous pouvez aussi utiliser le MSXML API pour faire la transformation.
    Merci; cependant, le résultat n'est pas sortir comme prévu et j'ai a commencé une nouvelle question

    OriginalL'auteur Lumi

  4. 1

    Voici une brève indentation fonction utilitaire qui travaille sur les objets DOM et les chaînes de caractères en entrée et retourne une chaîne formatée. Gestion des fichiers (utf-8) est laissé en dehors de son champ d'application. Ne pas utiliser ADODB ruisseaux et n'a pas besoin de MSXML dans les références du projet.

    Public Function FormatXmlIndent(vDomOrString As Variant, sResult As String) As Boolean
    Dim oWriter         As Object ' MSXML2.MXXMLWriter

    On Error GoTo QH
    Set oWriter = CreateObject("MSXML2.MXXMLWriter")
    oWriter.omitXMLDeclaration = True
    oWriter.indent = True
    With CreateObject("MSXML2.SAXXMLReader")
        Set .contentHandler = oWriter
        '--- keep CDATA elements
        .putProperty "http://xml.org/sax/properties/lexical-handler", oWriter 
        .parse vDomOrString
    End With
    sResult = oWriter.output
    '--- success
    FormatXmlIndent = True
    Exit Function
QH:
End Function

    Peut être utilisé comme cela

        sXml = ReadTextFile("doc.xml")
    FormatXmlIndent sXml, sXml

    ... donc, si quelque chose échoue (XML non valide, etc.) sXml détient toujours d'origine non formaté entrée.

    OriginalL'auteur wqw