Formule Excel pour trouver le premier non-alpha de caractères dans une cellule?

Pour aller dans un peu plus de détails sur la façon dont la formule de tableau de travaux (@Jacob formule semble être un peu mal dans quelques cas, par exemple 0 pour "A1A"), donc voici ce que je pense que c'est une version de travail, élargi pour en faciliter la lecture. S'il vous plaît laissez-moi savoir des exemples où ça ne fonctionne pas.

=IF(
    LEN(A1)=0
    ,0
    ,MIN(
        IF(
            ISNUMBER(
                1*MID(
                    A1,
                    ROW(INDIRECT("A1:A"&LEN(A1))),
                    1
                )
            ),
            ROW(INDIRECT("A1:A"&LEN(A1))),
            LEN(A1)+1
        )
    )
)

1. Au cœur de ce est la ligne (le) de la fonction, qui en mode de groupe est évaluée une fois pour chacune des cellules de la plage a1:a*n*, où n est la longueur de la chaîne dans la cellule A1, la création d'un tableau {1,2,...,n}.
2. Le tableau est transmis à la fonction MID, qui à son tour produit un tableau {*char_1*,*char_2*,...,*char_n*}.
3. Le tableau est multiplié par 1 afin d'empêcher que des caractères numériques pour être analysée comme texte dans les étapes suivantes. Cela pourrait aussi être fait en utilisant la VALEUR de().
4. Il est ensuite passé à la ISNUMBER() fonction qui renvoie un tableau de valeurs logiques.

C'est le tableau de conditions passé de SI. Un second tableau est alors construite en répétant l'étape 1, contenant la position de chaque caractère. La fonction SI, en mode de groupe, produit une gamme de sorties. Les cas dont la condition est VRAIE sont fixés à la valeur correspondante de la matrice de positions de caractères, et le reste sont tous mis à LEN(A1)+1, de sorte qu'elles sont plus grandes que n'importe quelle position possible des valeurs pour tous les caractères numériques.

La fonction MIN, puis évalue la matrice de sortie par SI, en retournant la valeur la plus petite, qui est la position du premier caractère numérique dans la chaîne de caractères dans la cellule A1. De l'extérieur SI la fonction des forces de la formule pour renvoyer 0 si il n'y a pas de texte dans la cellule, plutôt que de 1; sinon, INDIRECT renvoie un #REF! erreur lors de la recherche de cellule A0, qui se propage vers le haut, et le FAUX de l'état est retourné par SI, en renvoyant 0 + 1 = 1.

À la recherche de la position du premier caractère non numérique au lieu de cela, tout ce que vous avez à faire est d'inverser l'ordre de la seconde 2 arguments SI:

=IF(
    LEN(A1)=0
    ,0
    ,MIN(
        IF(
            ISNUMBER(
                1*MID(
                    A1,
                    ROW(INDIRECT("A1:A"&LEN(A1))),
                    1
                )
            ),
            LEN(A1)+1,
            ROW(INDIRECT("A1:A"&LEN(A1)))

        )
    )
)