générer la chaîne de caractères aléatoires

eh bien, je sais qu'il y a beaucoup de ces fils, mais im nouveau à vb.net pourtant, je ne peux pas modifier les sources de données pour faire ce que je veux vraiment
si je veux une fonction qui va générer au hasard des chaînes de caractères qui contiennent de 15 à 32 caractères chacune et chacun d'entre eux ont de la suite de caractères ( pas tous à la même chaîne, mais certains d'entre eux ) :
A-Z
a-z
0-9
voici mon code si loin

Functon RandomString()
    Dim s As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
    Dim r As New Random
    Dim sb As New StringBuilder
    For i As Integer = 1 To 8
        Dim idx As Integer = r.Next(0, 35)
        sb.Append(s.Substring(idx, 1))
    Next
    return sb.ToString()
End Function

OriginalL'auteur kasf | 2013-03-18

13

Changement de la chaîne d'inclure le a-z) caractères:
```
Dim s As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789"
```
De modifier la boucle pour créer un nombre aléatoire de caractères:
```
Dim cnt As Integer = r.Next(15, 33)
For i As Integer = 1 To cnt
```
Noter que la limite supérieure de la Next méthode est exclusive, de sorte que Next(15, 33) vous donne une valeur qui peut varier de 15 à 32.

Utiliser la longueur de la chaîne à choisir un personnage à partir de:
```
Dim idx As Integer = r.Next(0, s.Length)
```
Que vous allez créer des chaînes aléatoires, et pas une seule chaîne de caractères aléatoires, vous ne devez pas créer le générateur de nombre aléatoire à l'intérieur de la fonction. Si vous appelez la fonction deux fois trop proche dans le temps, vous vous retrouvez avec la même chaîne de caractères aléatoires, comme le générateur aléatoire est ensemencée à l'aide de l'horloge système. Donc, vous devez envoyer le générateur aléatoire à la fonction:
```
Function RandomString(r As Random)
```
Donc, dans l'ensemble:
```
Function RandomString(r As Random)
  Dim s As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789"
  Dim sb As New StringBuilder
  Dim cnt As Integer = r.Next(15, 33)
  For i As Integer = 1 To cnt
    Dim idx As Integer = r.Next(0, s.Length)
    sb.Append(s.Substring(idx, 1))
  Next
  return sb.ToString()
End Function
```
Exemple d'utilisation:
```
Dim r As New Random
Dim strings As New List<string>()
For i As Integer = 1 To 10
  strings.Add(RandomString(r))
Next
```
OriginalL'auteur Guffa

Essayer quelque chose comme cela:-

stringToReturn&= Guid.NewGuid.ToString().replace("-","")

Vous pouvez également vérifier cette:-

Sub Main()
        Dim KeyGen As RandomKeyGenerator
        Dim NumKeys As Integer
        Dim i_Keys As Integer
        Dim RandomKey As String

        ''' MODIFY THIS TO GET MORE KEYS    - LAITH - 27/07/2005 22:48:30 -
        NumKeys = 20

        KeyGen = New RandomKeyGenerator
        KeyGen.KeyLetters = "abcdefghijklmnopqrstuvwxyz"
        KeyGen.KeyNumbers = "0123456789"
        KeyGen.KeyChars = 12
        For i_Keys = 1 To NumKeys
            RandomKey = KeyGen.Generate()
            Console.WriteLine(RandomKey)
        Next
        Console.WriteLine("Press any key to exit...")
        Console.Read()
    End Sub

guid de ne pas utiliser les lettres G-Z
One-liner Guid.NewGuid.ToString() est utile!

OriginalL'auteur Rahul Tripathi

À l'aide de votre fonction en tant que guide, je l'ai modifié pour:

Aléatoire de la longueur (entre minChar & maxCharacters)
De rendre aléatoire la chaîne de produit à chaque fois (à l'aide de la statique Aléatoire)

Code:

Function RandomString(minCharacters As Integer, maxCharacters As Integer)
    Dim s As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
    Static r As New Random
    Dim chactersInString As Integer = r.Next(minCharacters, maxCharacters)
    Dim sb As New StringBuilder
    For i As Integer = 1 To chactersInString
        Dim idx As Integer = r.Next(0, s.Length)
        sb.Append(s.Substring(idx, 1))
    Next
    Return sb.ToString()
End Function

OriginalL'auteur Nathan Koop

0

Vous avez besoin de changer la ligne For i As Integer = 1 To 8 à For i As Integer = 1 To ? où ? est le nombre de caractères de la chaîne. Cela modifie le nombre de fois qu'il répète le code ci-dessous pour plus de caractères sont ajoutés à la chaîne.
```
    Dim idx As Integer = r.Next(0, 35)
    sb.Append(s.Substring(idx, 1))
```
OriginalL'auteur user1937198

Mon $.02

Dim prng As New Random
Const minCH As Integer = 15 'minimum chars in random string
Const maxCH As Integer = 35 'maximum chars in random string

'valid chars in random string
Const randCH As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789"

Private Function RandomString() As String
    Dim sb As New System.Text.StringBuilder
    For i As Integer = 1 To prng.Next(minCH, maxCH + 1)
        sb.Append(randCH.Substring(prng.Next(0, randCH.Length), 1))
    Next
    Return sb.ToString()
End Function

OriginalL'auteur dbasnett

0

veuillez noter que le
```
r.Next(0, 35)
```
ont tendance à se figer et de montrer le même résultat Pas sûr pourquoi; mieux utiliser
```
CInt(Math.Ceiling(Rnd() * N)) + 1
```
voir ici Entier aléatoire dans VB.NET

Si vous obtenez le Next méthode à "accrocher", alors vous êtes probablement à la création de nouveaux générateurs aléatoires trop proche dans le temps. N'utilisez pas de Math.Ceiling comme ça. Voir les commentaires pour la réponse que vous avez lié.

OriginalL'auteur Adil Al-Hilali

Essayez ceci:

Private Function RandomString(ByRef Length As String) As String
    Dim str As String = Nothing
    Dim rnd As New Random
    For i As Integer = 0 To Length
        Dim chrInt As Integer = 0
        Do
            chrInt = rnd.Next(30, 122)
            If (chrInt >= 48 And chrInt <= 57) Or (chrInt >= 65 And chrInt <= 90) Or (chrInt >= 97 And chrInt <= 122) Then
                Exit Do
            End If
        Loop
        str &= Chr(chrInt)
    Next
    Return str
End Function

OriginalL'auteur HighTechProgramming15

J'ai renforcé Nathan Koop fonction de mes besoins, et j'ai pensé partager.

J'ai ajouté:

Possibilité d'ajouter Ajouté et le texte Ajouté à la chaîne aléatoire
Possibilité de choisir le boîtier de caractères autorisés (lettres)
Capacité de choisir d'inclure ou d'exclure les numéros pour les caractères autorisés

REMARQUE: Si strictement à la recherche pour une longueur exacte de la chaîne tout en ajoutant pré/ajouté chaînes que vous aurez besoin pour faire face à cela; j'ai laissé de côté toute la logique de gérer cela.

Exemple D'Utilisation:

' Straight call for a random string of 20 characters
' All Caps + Numbers
String_Random(20, 20, String.Empty, String.Empty, 1, True)

' Call for a 30 char string with prepended string
' Lowercase, no numbers
String_Random(30, 30, "Hey_Now_", String.Empty, 2, False)

' Call for a 15 char string with appended string
' Case insensitive + Numbers
String_Random(15, 15, String.Empty, "_howdy", 3, True)

Public Function String_Random(
    intMinLength As Integer,
    intMaxLength As Integer,
    strPrepend As String,
    strAppend As String,
    intCase As Integer,
    bIncludeDigits As Boolean) As String

    ' Allowed characters variable
    Dim s As String = String.Empty

    ' Set the variable to user's choice of allowed characters
    Select Case intCase

        Case 1

            ' Uppercase
            s  = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"

        Case 2

            ' Lowercase
            s = "abcdefghijklmnopqrstuvwxyz"                

        Case Else

            ' Case Insensitive + Numbers
            s  = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz" 

    End Select

    ' Add numbers to the allowed characters if user chose so
    If bIncludeDigits = True Then s &= "0123456789"

    Static r As New Random

    Dim chactersInString As Integer = r.Next(intMinLength, intMaxLength)
    Dim sb As New StringBuilder

    ' Add the prepend string if one was passed
    If String.IsNullOrEmpty(strPrepend) = False Then sb.Append(strPrepend)

    For i As Integer = 1 To chactersInString

        Dim idx As Integer = r.Next(0, s.Length)

        sb.Append(s.Substring(idx, 1))

    Next

    ' Add the append string if one was passed
    If String.IsNullOrEmpty(strAppend) = False Then sb.Append(strAppend)

    Return sb.ToString()

End Function

OriginalL'auteur J. Scott Elblein

Vous devez vous connecter pour publier un commentaire.