Générer projet C# à l'aide de CMake

Je suis en train de générer un projet C# au sein d'une C++ CMake code de base sur Windows. Après quelques recherches, j'ai pu trouver que deux projets qui ont construit leur propre CSharp compilateurs pour CMake:
gdcm et kde.

J'ai essayé les deux d'entre eux. Malheureusement, le premier pas à réaliser un projet C#. Au lieu de cela, il a créé un VS C++ projet avec cs fichiers, et à cause de C++ indicateurs définis pour l'éditeur de liens, construire la toujours a échoué avec l'erreur. Après avoir expérimenté avec l'exemple de projet, qu'ils ont fourni, je me demande si cela pourrait être dû à une limitation de la "Visual Studio 2005 8" générateur de code?

Le deuxième projet vise principalement à Mono, donc je n'ai pas de succès avec elle, soit.

Quelqu'un a eu une expérience positive avec la construction de projets C# à l'aide de l'un de ces CMake modules ou autre chose?

InformationsquelleAutor Leonid | 2010-01-15
  1. 32

    De CMake 3.8.2, CSharp de la génération de projets est officiellement pris en charge par CMake.

    Pour construire la valeur par défaut de Visual Studio 2017 générés C#/WPF projet en utilisant CMake, créer un CMakeList.txt fichier comme suit.

    • Déclaration De Projet

      project(Example VERSION 0.1.0 LANGUAGES CSharp)

    • Inclure CMake CSharpUtilities si vous prévoyez sur l'utilisation de WPF ou de créateurs d'autres propriétés.

      include(CSharpUtilities)

    • Ajouter tous les cs, xaml, settings, properties 

      add_executable(Example
    App.config
    App.xaml
    App.xaml.cs
    MainWindow.xaml
    MainWindow.xaml.cs

    Properties/AssemblyInfo.cs
    Properties/Resources.Designer.cs
    Properties/Resources.resx
    Properties/Settings.Designer.cs
    Properties/Settings.settings)

    • Lien concepteur de fichiers, xaml fichiers, et d'autres propriétés des fichiers avec leurs correspondants cs fichiers

      csharp_set_designer_cs_properties(
    Properties/AssemblyInfo.cs
    Properties/Resources.Designer.cs
    Properties/Resources.resx
    Properties/Settings.Designer.cs
    Properties/Settings.settings)

csharp_set_xaml_cs_properties(
    App.xaml
    App.xaml.cs
    MainWindow.xaml
    MainWindow.xaml.cs)

    • Mis en application App.xaml fichier de propriétés en tant que point d'entrée du programme (si le projet est un projet WPF)

      set_property(SOURCE App.xaml PROPERTY VS_XAML_TYPE "ApplicationDefinition")

    • De définir d'autres csproj fichier indicateurs

      set_property(TARGET Example PROPERTY VS_DOTNET_TARGET_FRAMEWORK_VERSION "v4.6.1")
set_property(TARGET Example PROPERTY WIN32_EXECUTABLE TRUE)
...

    • Ajout de bibliothèques

      set_property(TARGET Example PROPERTY VS_DOTNET_REFERENCES
    "Microsoft.CSharp"
    "PresentationCore"
    "PresentationFramework"
    "System"
    "System.Core"
    "System.Data"
    "System.Data.DataSetExtensions"
    "System.Net.Http"
    "System.Xaml"
    "System.Xml"
    "System.Xml.Linq"
    "WindowsBase")

    Pour un travail WPF exemple, voir https://github.com/bemehiser/cmake_csharp_example

    Pour un WinForms exemple, voir cette réponse.

    • Malheureusement, ce n'est uniquement pris en charge sur Windows
    • Génération de projets Visual Studio par CMake est uniquement pris en charge sur Windows, probablement parce que Visual Studio lui-même, n'a un bon soutien pour Windows. (Oui, il y a une prise en charge partielle sur Mac, mais pas dans CMake.)
    • Droit, mais Visual Studio projets ont été pris en charge par la Mono sous Linux et Mac depuis plus d'une décennie.
    • Est-ce à l'appui projets mixtes? J'ai besoin d'une solution Visual Studio avec les bibliothèques c++ et c# projets
    • Selon la façon dont vous configurez votre structure de répertoire, oui. Par exemple, si vous avez un répertoire avec des fichiers C++ qui se compiler dans une bibliothèque, et un autre répertoire avec C# les fichiers, vous devez utiliser project(CPPExample VERSION 0.1.0 LANGUAGES CPP) dans le dossier C++, construire votre bibliothèque cible, puis utiliser la cible dans le projet C#. Il y a peut être d'autres plus élégante des façons de le faire, mais c'est la façon dont je l'ai fait.
    • En outre, vous pouvez définir le langage C# version (qui est par défaut à la version 3.0) avec la commande: set(CMAKE_CSharp_FLAGS "/langversion:6")
    • Je vous réserve plein de CMake exemple pour une application Windows Forms ici.

    InformationsquelleAutor the_storyteller
  2. 27

    CMake 2.8.9 et ajouter un TYPE paramètre include_external_msproject comme suit:

    include_external_msproject(
    MyProject MyProject.csproj
    TYPE FAE04EC0-301F-11D3-BF4B-00C04F79EFBC)

    Cette option permet d'indiquer que le projet est en C# (la magie GUID ci-dessus), sinon les choses de la lutte (voir les docs).

    Vous aurez probablement souhaitez utiliser le configure_file modèle d'approche mentionné ailleurs avec votre .csproj fichier pour obtenir le bon chemin en elle, sauf si vous êtes en train de construire directement dans votre arborescence des sources.

    La bonne nouvelle est que vous pouvez les génériques de votre C# les fichiers dans le .csproj.template fichier comme ceci:

    <ItemGroup>
  <Compile Include="${DOS_STYLE_SOURCE_DIR}\**\*.cs" />
</ItemGroup>

    Et vous aurez besoin de quelque chose comme cela dans votre CMakeLists.txt pour convertir CMake est de style unix forwardslash des séparateurs de chemin dans le style Windows barres obliques inverses, sinon il va compiler les fichiers, mais ils ne s'affichent pas de liens dans le projet dans Visual Studio:

    FILE(TO_NATIVE_PATH "${CMAKE_CURRENT_SOURCE_DIR}" DOS_STYLE_SOURCE_DIR)

    Alors c'est juste:

    CONFIGURE_FILE(MyProject.csproj.template MyProject.csproj)

    Dans votre CMakeLists.txt pour configurer le fichier de modèle en un véritable fichier de projet avec le droit chemin d'accès générique.

    HTH.

    • Pourriez-vous donner un exemple complet (ou le lien à un) de façon à: (1) Copier le source en C# de dossier et de fichiers; (2) l' .csproj.modèle et comment l'utiliser; et (3) comment mettre à jour CMakeLists.txt pour faire tout cela?
    • Vous n'avez pas besoin de copier le source C# de dossier/fichiers - ils sont référencées sur place. Le csproj.fichier de modèle est le même que n'importe quel autre fichier csproj, sauf pour le générique indiqué ci-dessus. Il suffit de copier un. J'ai ajouté le réel CONFIGURE_FILE commande à ma réponse, qui était la seule chose qui manque.
    • Ai-je besoin d'un extra CMakeLists.txt dans mon C# de dossier ou de faire tous ces changements se produisent dans la racine CMakeLists.txt? Si elles se produisent dans la racine CMakeLists.txt dois-je les mettre avant ou après l'appel à include_external_msproject()?
    • L'ai eu à travailler avec tous les changements dans la racine CMakeLists.txt. Toutefois, afin de [re-]construire mes projets C#, j'ai de décharger et de recharger à chaque fois que la .sln est [re-]généré sinon ils sont "Oubliées". Des idées? J'ai demandé à ce sujet ici: stackoverflow.com/q/15859576/135862
    • Pour info, voici une liste de la magie Guid pour les différents projets Visual Studio: codeproject.com/Reference/720512/...
    InformationsquelleAutor Alastair Maw
  3. 24

    Juste au cas où quelqu'un est toujours à la recherche d'informations à ce sujet, il n'y a vraiment aucune raison pour générer des projets C# avec CMake, ils sont de la croix-plate-forme de conception. Sur Linux, les projets C# sont généralement gérés avec MonoDevelop qui peut lire .csproj fichiers à partir de visual studio très bien. Cela devrait permettre à la croix-plate-forme de développement de projets C#.
    Le seul problème potentiel serait si vous aviez natif c++ projets mixtes avec les projets c# (comme un backend écrit en c++ avec une interface graphique en c#), dans ce cas seulement ont cmake une copie sur votre .csproj fichiers comme s'ils étaient de données et vous devriez être bon d'aller.
    CMake est destiné à configurer votre environnement de compilation pour être multi-plateforme. Cela vient vraiment pratique avec c++, là où le code est construit d'une manière très différente sur linux que sur windows (ou d'autres systèmes d'exploitation si vous êtes dans que), mais est en quelque sorte inutile pour c# qui peut exécuter la croix-plate-forme, et, grâce à des décisions de conception par l'équipe de mono, peut construire de la croix-plate-forme. CMake ne fournissent d'excellents outils pour automatiser les choses, mais beaucoup de ces fonctionnalités peuvent être récupérés avec un correctement configuré .fichier csproj.
    De toute façon je sais que cette question est de plus d'un an, mais c'est l'un des principaux résultats de la recherche je suis tombé sur quand je cherchais comment faire cela. Depuis, j'ai fait cette prise de conscience.

    • Oui, mais alors que cmake offre également la fonctionnalité d'installation de la plaine projets C# (csproj) ne le sont pas. Je serais intéressé par "make && make install" fonctionnalité pour les projets C# si cmake pourrait fournir.
    • Ce n'est pas dur à mettre en place un événement post-construction pour cette. En supposant que vous avez besoin pour intégrer dans un système de compilation cmake, vous pouvez même utiliser le cmake configure_file de commande à remplir le bon emplacement de l'installation.
    • Il y a une bonne raison à générer des projets C# par CMake. Si vous avez mélangé natif + C++/CLI + de projet C# avec beaucoup de configuration fait par CMake, vous avez besoin du projet C# de prendre la configuration faite dans CMake en compte et de consulter les projets générés pour le C++ et être inclus dans la solution.
    • encore une fois, utilisez configure_file (cmake.org/cmake/help/v2.8.8/cmake.html#command:configure_file) pour cela. La plupart des projets, je travaille sur le C++, C++/CLI, et C#, et cela fonctionne très bien en lieu et place de réelles cmake soutien pour le C#.
    • Je dirais que la meilleure raison pour générer des projets C# en utilisant CMake est de sortir de .csproj fichiers. Le plus gros problème que j'ai avec .csproj fichiers est qu'ils ne sont modifiables grâce à un drôle de jeu de dialogues et le résultat est une impénétrable fichier XML. CMake souffre d'aucun de ces problèmes.
    • Je voudrais écrire le msbuild xml à la main quand j'ai eu à faire ces
    • Je ne suis pas surpris que, parfois, c'est le genre de chose que l'on a recours à cause de l'absence d'un bon outillage.

    InformationsquelleAutor Max Ehrlich
  4. 2

    J'ai finalement été en mesure de générer une solution valide à l'aide de la deuxième c# module - kde.
    Bien que, cmake créé un certain nombre de .vcproj fichiers alors que je m'attendais à obtenir .csproj, mais je suppose que c'est la seule forme de "Visual Studio 2005 8" générateur peut offrir.

    Néanmoins, j'ai pu réussir à construire cette solution et de produire des exécutables et les bibliothèques dll.

    • Mise à jour: le fait que cmake créé les projets c++ avec des fichiers source c# en fait le projet presque inutilisable - Intellisense ne fonctionne pas, app.config ne peut pas être consulté par tous moyens, etc. Je suis en arrêt de complément d'enquête dans cette direction et de passer à MsBuild base de la configuration du projet.
    InformationsquelleAutor Leonid
  5. 2

    À piggy-back sur la réponse fournie par @the_storyteller, CMake v3.8 et plus, en effet, prend en charge C# comme un premier de la classe de langue. Parce que WPF exemple était déjà prévu, ici, est un CMake exemple pour une simple application Windows Forms. J'ai fourni les commandes en option pour les liens dans d'autres bibliothèques construites localement dans l'arbre source, et la liaison 3ème partie des dépendances de la bibliothèque.

    Noter que les applications Windows Forms exigent l'utilisation de la csharp_set_windows_forms_properties commande CMake, alors que les projets WPF utilisation csharp_set_designer_cs_properties et csharp_set_xaml_cs_properties.

    CMakeLists.txt

    cmake_minimum_required(VERSION 3.8)

project(MyWinFormApp LANGUAGES CSharp)

# Include CMake utilities for CSharp, for WinForm and WPF application support.
include(CSharpUtilities)

# Define the executable, including any .cs files. 
# The .resx and other Properties files are optional here, but including them makes them visible in the VS solution for easy editing. 
add_executable(MyWinFormApp
    App.config
    Form1.cs
    Form1.Designer.cs
    Form1.resx
    Program.cs
    Properties/AssemblyInfo.cs
    Properties/Resources.Designer.cs
    Properties/Resources.resx
    Properties/Settings.Designer.cs
    Properties/Settings.settings
)

# Set the .NET Framework version for the executable.
set_property(TARGET MyWinFormApp PROPERTY VS_DOTNET_TARGET_FRAMEWORK_VERSION "v4.6.1")
# Set the executable to be 32-bit.
set_property(TARGET MyWinFormApp PROPERTY WIN32_EXECUTABLE TRUE)
# Set the C# language version (defaults to 3.0).
set(CMAKE_CSharp_FLAGS "/langversion:latest")

# Set the source file properties for Windows Forms use.
csharp_set_windows_forms_properties(
    Form1.cs
    Form1.Designer.cs
    Form1.resx
    Program.cs
    Properties/AssemblyInfo.cs
    Properties/Resources.Designer.cs
    Properties/Resources.resx
    Properties/Settings.Designer.cs
    Properties/Settings.settings
)

# If necessary, link in other library dependencies that were built locally in this source tree.
target_link_libraries(MyWinFormApp MyLocalLib)

# If necessary, link in other library/DLL references, such as 3rd party libraries.
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_MyThirdPartyLib /path/to/libs/MyThirdPartyLib.dll)

# Add in the .NET reference libraries.
set_property(TARGET MyWinFormApp PROPERTY VS_DOTNET_REFERENCES
    "Microsoft.CSharp"
    "System"
    "System.Core"
    "System.Data"
    "System.Drawing"
    "System.Windows.Forms"
)
    • Fantastique!!!! Envisagez-vous d'ajouter qu'en tant que deuxième exemple (le premier devra être renommé) pour mon CMake C# exemple de projet sur GitHub? Si vous ajoutez les WinForms exemple et soumettre une demande d'extraction, je vais le renommer pour être plus générique, et nous pouvons le lien ici.
    • Juste créé la pull request. Les deux WinForm et WPF exemples de travail sur VS 2017 et VS 2019.
    InformationsquelleAutor squareskittles
  6. 1

    Vous pouvez créer un projet avec Visual Studio, de le démonter et de le rendre CMake écrire à l'aide de configure_file commande (vous devrez générer un peu de XML avec la liste des sources) et l'ajouter à la solution avec include_external_msproject (pour d'autres générateurs, vous aurez besoin pour créer la cible personnalisée pour exécuter msbuild sur manuellement; cmake ne semblent pas étayer le faire encore). Le projet est assez simple, il devrait donc être possible de le faire.

    InformationsquelleAutor Jan Hudec