Graal tableau JSON

J'ai eu un coup d'oeil à la docs de l'API JSON et il ne semble pas être un moyen d'analyser une chaîne JSON à un type spécifique de l'objet.

Vous n'aurez qu'à écrire le code vous-même à la conversion de chaque JSONObject à un Foo. Quelque chose comme ceci devrait fonctionner:

import grails.converters.JSON
import org.codehaus.groovy.grails.web.json.*

class Foo {
  def name

  Foo(name) {
    this.name = name
  }

  String toString() {
    name
  }
}


List list = [new Foo("first"), new Foo("second")]
def jsonString = (list as JSON).toString()

List parsedList = JSON.parse(jsonString)

//Convert from a list of JSONObject to a list of Foo
def foos = parsedList.collect {JSONObject jsonObject ->
    new Foo(name: jsonObject.get("name"))
}

Plus générale, la solution serait d'ajouter une nouvelle statique parse méthode telle que la JSON métaclasse, qui tente d'analyser la chaîne JSON à une Liste d'objets d'un type particulier:

import grails.converters.JSON
import org.codehaus.groovy.grails.web.json.*

class Foo {
  def name

  Foo(name) {
    this.name = name
  }

  String toString() {
    name
  }
}

List list = [new Foo("first"), new Foo("second")]
def jsonString = (list as JSON).toString()


List parsedList = JSON.parse(jsonString)

//Define the new method
JSON.metaClass.static.parse = {String json, Class clazz ->

    List jsonObjs = JSON.parse(json)

    jsonObjs.collect {JSONObject jsonObj ->

        //If the user hasn't provided a targetClass read the 'class' proprerty in the JSON to figure out which type to convert to
        def targetClass = clazz ?: jsonObj.get('class') as Class
        def targetInstance = targetClass.newInstance()        

        //Set the properties of targetInstance
        jsonObj.entrySet().each {entry ->

            if (entry.key != "class") {
                targetInstance."$entry.key" = entry.value
            }
        }
        targetInstance
    }

}

//Try the new parse method
List<Foo> foos = JSON.parse(jsonString, Foo)

//Confirm it worked
assert foos.every {Foo foo -> foo.class == Foo && foo.name in ['first', 'second'] }

Vous pouvez essayer le code ci-dessus dans la console groovy. Quelques mises en garde

• J'ai seulement effectué des tests très limités sur le code ci-dessus
• Il y a deux JSON classes dans le dernier Grain de presse, je suis en supposant que vous êtes à l'aide de l'un qui n'est pas obsolète

OriginalL'auteur Dónal

J'ai pris ce code et l'a étendue à travailler avec des structures imbriquées. Il s'appuie sur un attribut 'class' existant dans le JSON. Si il ya une meilleure façon, maintenant, dans Graal s'il vous plaît laissez-moi savoir.

     //The default JSON parser just creates generic JSON objects.  If there are nested

    //JSON arrays they are not converted to theirs types but are left as JSON objects
    //This converts nested JSON structures into their types.
    //IT RELIES ON A PROPERTY 'class' that must exist in the JSON tags
    JSON.metaClass.static.parseJSONToTyped = {def jsonObjects ->

        def typedObjects = jsonObjects.collect {JSONObject jsonObject ->
            if(!jsonObject.has("class")){
                throw new Exception("JSON parsing failed due to the 'class' attribute missing: " + jsonObject)
            }

            def targetClass = grailsApplication.classLoader.loadClass(jsonObject.get("class"))
            def targetInstance = targetClass.newInstance()

            //Set the properties of targetInstance
            jsonObject.entrySet().each {entry ->
                //If the entry is an array then recurse
                if(entry.value instanceof org.codehaus.groovy.grails.web.json.JSONArray){
                    def typedSubObjects = parseJSONToTyped(entry.value)
                    targetInstance."$entry.key" = typedSubObjects
                }
                else if (entry.key != "class") {
                    targetInstance."$entry.key" = entry.value
                }
            }

            targetInstance
        }

        return typedObjects
    }

OriginalL'auteur Sandman