Groovy 2d tableaux

J'ai 3 tableaux, l1[,,,,], l2[,,,,] and l3[,,,,]. Chacune dispose de 5 caractères.

e.g. l1["A","B","C","D","E"]

Le tableau 2d est constitué de ces

screen = [l1[],l2[],l3[]]

donc à chercher, comme ça:

screen = [[,,,,],[,,,,],[,,,,]]

Comment puis-je parcourir ce tableau?

dois-je appeler screen[5]? ou screen[l1[5]]?

puis-je:

for (i in 1..15){

 println screen[i]
}

s'il vous plaît aider!!!

Comment puis-je effectuer une itération dans le tableau et appelle les différentes parties, par exemple la 1st element de chaque sous tableau?

Grâce

OriginalL'auteur user3514792 | 2014-04-10

  1. 13

    Donc, compte tenu de:

    List l1 = ['A', 'B', 'C', 'D', 'E']
List l2 = ['a', 'b', 'c', 'd', 'e']
List l3 = ['1', '2', '3', '4', '5']

List screen = [ l1, l2, l3 ]

    Pour itérer sur tous les éléments, vous pouvez faire:

    3.times { y ->
    5.times { x ->
        println screen[ y ][ x ]  
    }
}

    Ou, vous pouvez utiliser mod et intdiv de travailler positions x et y:

    15.times { p ->
    def x = p % 5
    def y = p.intdiv( 5 )
    println screen[ y ][ x ]
}

    Ou, si vous souhaitez que le premier élément de chaque sous-liste, vous pouvez le faire:

    println screen*.head()

    Ou dites que vous voulez le 3ème élément de chaque sous-liste:

    println screen*.getAt( 2 )

    Sinon, vous pourriez mettre tous les éléments dans une dimension de la Liste:

    def inlineScreen = [ *l1, *l2, *l3 ]

    Puis accès par:

    15.times { p ->
    println inlineScreen[ p ]
}

    ou:

    def x = 1, y = 1
println inlineScreen[ x + y * 5 ]

    Ou, s'il est important que vous en voulez toujours obtenir les éléments de l'ensemble (c'est à dire, vous voulez toujours la deuxième éléments de tous les tableaux), alors vous pouvez faire:

    //groupedScreen == [['A', 'a', '1'], ['B', 'b', '2'], ['C', 'c', '3'], ['D', 'd', '4'], ['E', 'e', '5']]
def groupedScreen = [ l1, l2, l3 ].transpose()

    Puis, à la 3ème éléments, il vous suffit de faire:

    groupedScreen[ 2 ]

    OriginalL'auteur tim_yates