Indy TIdTCPClient recevoir des sms

J'essaie de recevoir du texte dans un idtcpclient mais il ne fonctionne pas. C'est le code que j'utilise un timer:

procedure TForm1.Timer2Timer(Sender: TObject);
var
  receivedtext:string;
begin
  if idtcpclient1.Connected = true then
  begin
    with idtcpclient1 do
    begin
      if not IOHandler.InputBufferIsEmpty then
      begin
        try
          receivedtext := IOHandler.ReadLn;
        finally
          if receivedtext = '' = false then
          begin
            showmessage(receivedtext);
            idtcpclient1.IOHandler.InputBuffer.Clear;
            receivedtext := '';
          end;
        end;
      end;
    end;
  end
  else
  begin
    timer2.Enabled := false;
  end;
end;

De l'intervalle du minuteur est de 8 ms.
La minuterie est activée automatiquement lors de la connexion.
Mais je n'ai pas une messagebox ou une erreur lorsque j'envoie quelque chose.
Je suis sûr que j'ai écrit les données, car quand j'utilise tclientsocket je ne le recevoir.

Ce que je fais de mal?

  • Ne receivedtext = '' = false même compiler? (Montrer votre vrai code s'il vous plaît)
  • Pourquoi avez-vous effacer la InputBuffer? Après un succès en Lecture... opération, Indy va supprimer les octets lus à partir de la InputBuffer.
  • Pourquoi avez-vous ce code dans un timer? Avec le code comme indiqué, vous aurez re-entrancy questions, en particulier avec une valeur de minuterie de 8ms.
  • Je pense que ton code est complètement faux. Utiliser google pour rechercher des exemples, comme la ... sourceforge.net/projects/indy10clieservr Première démo dans il devrait y aider "1_sample Chaîne Simple Échange"
InformationsquelleAutor jwz104 | 2014-04-03
  1. 8

    Utiliser quelque chose comme ceci à la place:

    procedure TForm1.Timer2Timer(Sender: TObject);
var
  receivedtext: string;
begin
  with IdTCPClient1 do
  begin
    try
      if IOHandler.InputBufferIsEmpty then
      begin
        IOHandler.CheckForDataOnSource(0);
        IOHandler.CheckForDisconnect;
        if IOHandler.InputBufferIsEmpty then Exit;
      end;
      receivedtext := IOHandler.ReadLn;
    except
      Timer2.Enabled := False;
      Exit;
    end;
    if receivedtext <> '' then
      ShowMessage(receivedtext);
  end;
end;

    Avec cela dit, ce genre de code serait mieux mis en œuvre à l'aide d'un thread au lieu d'une minuterie.

    1 - Créer une nouvelle classe dérivée de TThread (Fichier > Nouveau > Autres > Objet Thread)

    type
  TDataEvent = procedure(const Data: string) of object;

  TReadingThread = class(TThread)
  private
    FClient: TIdTCPClient;
    FData: string;
    FOnData: TDataEvent;
    procedure DataReceived;
  protected
    procedure Execute; override;
  public
    constructor Create(AClient: TIdTCPClient); reintroduce;
    property OnData: TDataEvent read FOnData write FOnData;
  end;

constructor TReadingThread.Create(AClient: TIdTCPClient);
begin
  inherited Create(True);
  FClient := AClient;
end;

procedure TReadingThread.Execute;
begin
  while not Terminated do
  begin
    FData := IdTCPClient1.IOHandler.ReadLn;
    if (FData <> '') and Assigned(FOnData) then
      Synchronize(DataReceived);
  end;
end;

procedure TReadingThread.DataReceived;
begin
  if Assigned(FOnData) then
    FOnData(FData);
end;

    2 - Modifier votre code de connexion:

    IdTCPClient1.Connect;
try
  Thread := TReadingThread.Create(IdTCPClient1);
  Thread.OnData := DataReceived;
  Thread.Resume;
except
  IdTCPClient1.Disconnect;
  raise;
end;

...

if Assigned(Thread) then Thread.Terminate;
try
  IdTCPClient1.Disconnect;
finally
  if Assigned(Thread) then
  begin
    Thread.WaitFor;
    FreeAndNil(Thread);
  end;
end;

...

procedure TForm1.DataReceived(const Data: string);
begin
  ShowMessage(Data);
end;
    InformationsquelleAutor Remy Lebeau