JSON à l'importation vers Excel

Puisque c'est VBA, je ne l'utiliserais COM pour appeler xmlhttprequest, mais l'utiliser de manière synchrone de ne pas les déranger VBA est mono-thread d'exécution de l'environnement, Un exemple qui illustre une post et get demande dans ce de la manière suivante:

'BEGIN CLASS syncWebRequest

Private Const REQUEST_COMPLETE = 4

Private m_xmlhttp As Object
Private m_response As String

Private Sub Class_Initialize()
    Set m_xmlhttp = CreateObject("Microsoft.XMLHTTP")
End Sub

Private Sub Class_Terminate()
    Set m_xmlhttp = Nothing
End Sub


Property Get Response() As String
    Response = m_response
End Property

Property Get Status() As Long
    Status = m_xmlhttp.Status
End Property

Public Sub AjaxPost(Url As String, Optional postData As String = "")
    m_xmlhttp.Open "POST", Url, False
    m_xmlhttp.setRequestHeader "Content-type", "application/x-www-form-urlencoded"
    m_xmlhttp.setRequestHeader "Content-length", Len(postData)
    m_xmlhttp.setRequestHeader "Connection", "close"
    m_xmlhttp.send (postData)
    If m_xmlhttp.readyState = REQUEST_COMPLETE Then
        m_response = m_xmlhttp.responseText
    End If
End Sub

Public Sub AjaxGet(Url As String)
    m_xmlhttp.Open "GET", Url, False
    m_xmlhttp.setRequestHeader "Connection", "close"
    m_xmlhttp.send
    If m_xmlhttp.readyState = REQUEST_COMPLETE Then
        m_response = m_xmlhttp.responseText
    End If
End Sub

'END CLASS syncWebRequest   

Alors maintenant, vous pouvez appeler la ci-dessus pour retourner la réponse du serveur:

Dim request As New syncWebRequest
request.ajaxGet "http://localhost/ClientDB/AllClients?format=json" 
Dim json as string 
json = request.Response

Le problème ici est que nous voulons être en mesure de lire les données retournées par le serveur d'une certaine façon, plus que de la manipulation de la chaîne JSON directement. Ce qui est travaillé pour moi, c'est à l'aide de la VBA-JSON (google code d'exportation ici) type COM Collection à manipuler du JSON tableaux et Dictionary gérer les membres et leurs déclarations, avec un analyseur d'usine méthode Parse que, fondamentalement, fait de la création de ces collections de dictionnaires beaucoup plus simple.

Ainsi, nous pouvons maintenant analyser le JSON:

[{"Name":"test name","Surname":"test surname","Address":{"Street":"test street","Suburb":"test suburb","City":"test city"}}]

en quelque chose comme ce qui suit:

Set clients = parser.parse(request.Response)
For Each client In clients
    name = client("Name")
    surname = client("Surname")
    street = client("Address")("Street")
    suburb = client("Address")("Suburb")
    city = client("Address")("City")
Next

C'est gentil mais que penser des trucs comme étant en mesure d'éditer et de publier les données? Il y a bien aussi une méthode toString pour créer une chaîne JSON à partir de ci-dessus [Collection/Dictionnaire] les données JSON, en supposant que le serveur accepte de JSON dos.