JSON en manutention dans ROBOT

La solution la plus simple serait d'écrire un python de mots clés qui peuvent modifier la valeur pour vous. Cependant, vous pouvez résoudre ce problème avec un robot mots-clés en effectuant les étapes suivantes:

1. convertir la chaîne JSON à un dictionnaire
2. modifier le dictionnaire
3. convertir le dictionnaire de retour pour une chaîne JSON

Convertir la chaîne JSON à un dictionnaire

Python dispose d'un module (json) pour travailler avec des données JSON. Vous pouvez utiliser le évaluer mot-clé pour convertir votre chaîne JSON à un dictionnaire python à l'aide de la charges (charge de chaîne) de ce module.

En supposant que vos données JSON est dans un robot variable nommée ${json_string}vous pouvez convertir en un dictionnaire python comme ceci:

${json}=    evaluate    json.loads('''${json_string}''')    json

Ci-dessus, ${json} détient maintenant une référence à un dictionnaire qui contient toutes les données json.

Modifier le dictionnaire

La Collections bibliothèque qui vient avec le robot a un mot-clé nommée set de dictionnaire qui peut être utilisée pour définir la valeur d'un dictionnaire de l'élément. Dans ce cas, vous devez modifier la valeur d'un dictionnaire imbriquée à l'intérieur de la vt élément de l'objet JSON. Nous pouvons référence qui nichaient dictionnaire à l'aide du robot étendue variable syntaxe.

Par exemple:

set to dictionary    ${json["vt"]}    dp=the new value

${json} A maintenant la nouvelle valeur. Cependant, il est encore un dictionnaire python plutôt que des données JSON, donc il y a une étape de plus.

Convertir le dictionnaire de retour json

Convertir le dictionnaire de retour JSON est l'inverse de la première étape. À savoir, l'utilisation de la dumps (vidage de la chaîne) méthode du json module:

${json_string}=    evaluate    json.dumps(${json})    json

${json_string} Contiendra une chaîne JSON valide avec les données modifiées.

---

Exemple complet

Le suivant est un exemple de travail. La chaîne json sera imprimé avant et après la substitution de la nouvelle valeur:

*** Settings ***
Library    Collections

*** Test Cases ***
Example
    ${json_string}=    catenate
    ...  {
    ...    "p": "10",
    ...    "v": 100,
    ...    "vt": {
    ...            "dp": "Field to be edited"
    ...          }
    ...  }

    log to console       \nOriginal JSON:\n${json_string}
    ${json}=             evaluate        json.loads('''${json_string}''')    json
    set to dictionary    ${json["vt"]}    dp=the new value
    ${json_string}=      evaluate        json.dumps(${json})                 json
    log to console       \nNew JSON string:\n${json_string}