La bibliothèque Standard de chiffrement AES pour VB.NET?

Est-il de la bibliothèque standard à utiliser pour le chiffrement AES pour VB.NET? Je veux crypter une chaîne de caractères avec un statique de la clé privée.

J'ai googlé et trouvé beaucoup de variations. Je ne sais pas vraiment comment faire pour déterminer quels algorithmes sont sûrs ou non.

Avez-vous regarder les Système.De sécurité.La cryptographie de l'espace de noms?
Voir stackoverflow.com/questions/273452/...
hey.. je suis tombé sur ce site juste maintenant.. msdn.microsoft.com/en-us/library/... je ne sais pas vraiment quoi faire avec l'exemple de.. =x
pouvez-vous donner un peu plus de "je ne sais pas vraiment quoi faire" ? ... si vous avez un problème particulier, vous trouverez de l'aide ici ...
"Je voulais essayer de chiffrer une chaîne avec un statique de la clé privée. ... Je ne sais pas vraiment comment faire pour déterminer si leur algorithme est sécurisée ou non" Si vous avez un statique de la clé privée stockée dans votre application, alors il n'est pas sûr que les gens peuvent l'extraire à partir de votre application (si l'algorithme utilisé pour chiffrer il n'a pas vraiment d'importance). Comment allez-vous utiliser cette données chiffrées?

OriginalL'auteur ysj | 2013-05-07

  1. 8

    La System.Security.Cryptography espace de noms contient toutes les classes dont vous avez besoin pour effectuer la plupart des tâches de chiffrement. Malheureusement, comme le cryptage est un sujet compliqué, les classes sont un peu difficile à travailler, surtout pour les débutants. Il est parfois difficile de trouver un travail simple exemple pour commencer. Mais, comme je suis sympa, je vais vous donner un exemple simple que vous pouvez jouer avec et de les améliorer 🙂

    La classe que vous voudrez probablement utiliser est appelé RijndaelManaged. C'est la classe qui implémente l'typiques de chiffrement AES. Voici un exemple de classe qui l'utilise pour convertir entre plaine des chaînes de texte et des tableaux d'octets:

    Public Class Aes256Encrypter
Public Function Encrypt(ByVal plainText As String, ByVal secretKey As String) As Byte()
Dim encryptedPassword As Byte()
Using outputStream As MemoryStream = New MemoryStream()
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(outputStream, algorithm.CreateEncryptor(), CryptoStreamMode.Write)
Dim inputBuffer() As Byte = Encoding.Unicode.GetBytes(plainText)
cryptoStream.Write(inputBuffer, 0, inputBuffer.Length)
cryptoStream.FlushFinalBlock()
encryptedPassword = outputStream.ToArray()
End Using
End Using
Return encryptedPassword
End Function
Public Function Decrypt(ByVal encryptedBytes As Byte(), ByVal secretKey As String) As String
Dim plainText As String = Nothing
Using inputStream As MemoryStream = New MemoryStream(encryptedBytes)
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(inputStream, algorithm.CreateDecryptor(), CryptoStreamMode.Read)
Dim outputBuffer(0 To CType(inputStream.Length - 1, Integer)) As Byte
Dim readBytes As Integer = cryptoStream.Read(outputBuffer, 0, CType(inputStream.Length, Integer))
plainText = Encoding.Unicode.GetString(outputBuffer, 0, readBytes)
End Using
End Using
Return plainText
End Function
Private Function getAlgorithm(ByVal secretKey As String) As RijndaelManaged
Const salt As String = "put your salt here"
Const keySize As Integer = 256
Dim keyBuilder As Rfc2898DeriveBytes = New Rfc2898DeriveBytes(secretKey, Encoding.Unicode.GetBytes(salt))
Dim algorithm As RijndaelManaged = New RijndaelManaged()
algorithm.KeySize = keySize
algorithm.IV = keyBuilder.GetBytes(CType(algorithm.BlockSize / 8, Integer))
algorithm.Key = keyBuilder.GetBytes(CType(algorithm.KeySize / 8, Integer))
algorithm.Padding = PaddingMode.PKCS7
Return algorithm
End Function
End Class

    Vous devez changer le salt constante à autre chose. Idéalement, il ne serait même pas une constante, depuis, de le rendre aussi sûr que possible, vous devriez utiliser un autre sel chaque fois que vous effectuez le chiffrement, mais c'est un tout autre sujet.

    Si vous voulez avoir de la valeur chiffrée retourné comme une chaîne de caractères au lieu d'un tableau d'octets, vous pouvez utiliser l'encodage Base 64 pour convertir le tableau d'octets, et de, des chaînes, comme ceci:

    Public Class Aes256Base64Encrypter
Public Function Encrypt(ByVal plainText As String, ByVal secretKey As String) As String
Dim encryptedPassword As String = Nothing
Using outputStream As MemoryStream = New MemoryStream()
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(outputStream, algorithm.CreateEncryptor(), CryptoStreamMode.Write)
Dim inputBuffer() As Byte = Encoding.Unicode.GetBytes(plainText)
cryptoStream.Write(inputBuffer, 0, inputBuffer.Length)
cryptoStream.FlushFinalBlock()
encryptedPassword = Convert.ToBase64String(outputStream.ToArray())
End Using
End Using
Return encryptedPassword
End Function
Public Function Decrypt(ByVal encryptedBytes As String, ByVal secretKey As String) As String
Dim plainText As String = Nothing
Using inputStream As MemoryStream = New MemoryStream(Convert.FromBase64String(encryptedBytes))
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(inputStream, algorithm.CreateDecryptor(), CryptoStreamMode.Read)
Dim outputBuffer(0 To CType(inputStream.Length - 1, Integer)) As Byte
Dim readBytes As Integer = cryptoStream.Read(outputBuffer, 0, CType(inputStream.Length, Integer))
plainText = Encoding.Unicode.GetString(outputBuffer, 0, readBytes)
End Using
End Using
Return plainText
End Function
Private Function getAlgorithm(ByVal secretKey As String) As RijndaelManaged
Const salt As String = "put your salt here"
Const keySize As Integer = 256
Dim keyBuilder As Rfc2898DeriveBytes = New Rfc2898DeriveBytes(secretKey, Encoding.Unicode.GetBytes(salt))
Dim algorithm As RijndaelManaged = New RijndaelManaged()
algorithm.KeySize = keySize
algorithm.IV = keyBuilder.GetBytes(CType(algorithm.BlockSize / 8, Integer))
algorithm.Key = keyBuilder.GetBytes(CType(algorithm.KeySize / 8, Integer))
algorithm.Padding = PaddingMode.PKCS7
Return algorithm
End Function
End Class

    Si vous êtes le stockage de la valeur chiffrée dans un fichier texte, fichier XML, ou même une base de données, il est souvent plus facile de simplement utiliser en Base 64, comme ça.

    -1 Aléatoire sel avec votre code n'est pas vraiment un thème différent, ni simplement idéalement nécessaires, vous êtes de la génération IV de la même entrée que votre clé, donc réutilisé mot de passe avec une constante de sel aura toujours le même IV. Cela rompt avec la sémantique de la sécurité de radio-canada -- IV doit être unique par clé et imprévisibles, c'est une règle de base pour la CBC.
    Vous m'avez sauvé beaucoup de temps. Je vous remercie pour votre réponse.

    OriginalL'auteur Steven Doggart

  2. 1

    Il existe un cryptage de haut niveau bibliothèques qui gèrent les subtils détails de cryptage afin de ne pas faire ces erreurs, Keyczar, Nacl, GPGME.

    J'ai porté Keyczar .net et il utilise AES pour défaut de chiffrement symétrique.

    Vous utilisez un programme en ligne de commande pour créer un jeu de clés avec un aléatoire de la clé AES.

    :> KeyczarTool.exe create --location=path_to_key_set --purpose=crypt
:> KeyczarTool.exe addkey --location=path_to_key_set --status=primary

    Dans votre projet pour chiffrer,

    Using encrypter As New Encrypter("path_to_key_set")
Return encrypter.Encrypt(plaintext)
End Using

    Puis à décrypter

    Using crypter As new Crypter("path_to_key_set")
Return crypter.Decrypt(ciphertext)
End Using

    OriginalL'auteur jbtule