la construction d'un formulaire de recherche dans Access 2010

Je suis en train de faire de la recherche à la clientèle formulaire pour accéder à 2010.

J'aime avoir une option de groupe basé sur une requête de la recherche. J'ai fait une requête de recherche à la recherche pour le prénom ou nom de famille. deux zones de texte sont également présentes sur le formulaire à remplir les entrées de requête (le 1er et le dernier nom)

J'ai besoin d'un groupe d'option, de sorte que je peux sélectionner l'a entraîné nom pour la réservation fins.

Dans le passé, j'ai fait une façon indirecte de faire cela à l'aide de sous-formulaire et une case à cocher.
Puis le charger à la fois des résultats sur un sous-formulaire et case (actualisation) de sorte que l'utilisateur n'a qu'à sélectionner la case à cocher. Mais cette fois, je veux les options pour être le résultat de la requête elle-même! S'il vous plaît aider.

Quel est le problème avec l'aide d'un combobox ou listbox?
Serait-il agréable que par le résultat (option de groupe), je peux sélectionner directement un enregistrement et lorsque j'appuie sur le bouton "Suivant" il a porté sur les données de formulaire suivant. Au lieu d'avoir deux "objets" (sous-formulaire et case à cocher). C'est redondant.
Mon client formulaire de recherche fonctionne de manière similaire à ceci: j'ai une zone de texte recherche en haut. J'ai un formulaire continu de tous les clients en-dessous. Après que l'utilisateur saisit du texte dans la zone de recherche, je l'ai filtrer le jeu d'enregistrements par la création d'un critère basé sur chaque nom de champ comme suit: FirstName Like *%s* Or LastName Like *%s* et remplacer %s avec le texte dans la zone de recherche. Je pense que c'est assez chouette. L'utilisateur clique ensuite sur le bouton flèche à droite du nom du contact pour le sélectionner ou de la vue qui contacter en pleine vue de détail dans une nouvelle forme.

OriginalL'auteur Daytron | 2013-03-27

10

Voici un exemple simple qui utilise une Zone de Liste:

Table: Clients

ID - Numéroauto

Nom - Texte(255)

Prénom - Texte(255)

E-Mail - Texte(255)

Données de Test:
```
ID LastName FirstName Email
-- ---------- -------------- ------------------
1 Thompson Gord [email protected]
2 Loblaw Bob [email protected]
3 Kingsley Hank [email protected]
4 Thompson Hunter S. [email protected]
5 Squarepants Spongebob [email protected]
6 O'Rourke P. J. [email protected]
7 Aldrin Edwin "Buzz" [email protected]
```
Mise en page du formulaire:

Module VBA pour cette forme:
```
Option Compare Database
Option Explicit

Private Sub Form_Load()
Me.lstSearchResults.RowSource = ""
End Sub

Private Sub btnSearch_Click()
Me.lstSearchResults.SetFocus
Me.lstSearchResults.Value = Null
Me.lstSearchResults.RowSource = _
 "SELECT ID, LastName, FirstName FROM Clients " & _
 "WHERE LastName LIKE ""*" & DQ(Me.txtSearchLastName.Value) & _
 "*"" AND FirstName LIKE ""*" & DQ(Me.txtSearchFirstName.Value) & "*"""
End Sub

Private Function DQ(s As Variant) As String
' double-up double quotes for SQL
DQ = Replace(Nz(s, ""), """", """""", 1, -1, vbBinaryCompare)
End Function

Private Sub btnLookupEmail_Click()
If IsNull(Me.lstSearchResults.Value) Then
 Me.txtEmail.Value = ""
Else
 Me.txtEmail.Value = DLookup("Email", "Clients", "ID=" & Me.lstSearchResults.Value)
End If
End Sub
```
Lorsque le formulaire est ouvert, tout est vide.

Tapant "thompson" (sans les guillemets) et cliquez btnSearch remplit la Zone de Liste avec les clients WHERE LastName LIKE "*thompson*". (Si vous regardez le code, vous verrez qu'il trouvera également sur le Prénom si vous en fournir un.)

Sélectionnez l'un des éléments dans la Zone de Liste et cliquez sur btnLookupEmail et l'adresse e-mail est affiché dans la Zone de Texte ci-dessous.

C'est génial. Je ne savais pas qu'il peut également être fait à l'aide de listbox. Je ne suis pas tout à fait dans le savoir sur l'utilisation de SQL codes, mais je n'ai clairement comprendre le code. Mais est-il possible à l'aide de jeu de cadres(option grp) à la place? Mon programme permet de masquer le formulaire lorsque l'utilisateur appuyez sur "Suivant" (en supposant qu'il a choisi un abouti valeur. De sorte que, je peux porter sur la valeur sélectionnée dans le formulaire suivant à l'aide de lien complet formulaire d'adresse, "les formes!formname!objet.de la valeur". Est-il possible d'utiliser currentvalue d'une zone de liste pour la prochaine formulaire? 
re: "Est-il possible d'utiliser currentvalue d'une zone de liste pour la prochaine forme?" - Je ne vois pas pourquoi pas. forms!formname!lstSearchResults.Value devrait fonctionner si formname est toujours chargées, même si elle est cachée. Une Zone de Liste est conçu pour contenir un nombre variable de choix possibles, tandis qu'un Groupe d'options est vraiment destiné pour un nombre fixe de choix.
Merci. J'apprécie l'aide. Dernière question, j'ai découvert trop tard quelques ligne je ne comprends pas. à Partir de la syntaxe de la fonction Remplacer: Remplacer ( string1, trouver, remplacement, [démarrer, [comte, [comparer]]] ) Pourquoi avez-vous avoir à les remplacer et pourquoi la chaîne est de Nz(s,"")?
Le Nz() fonction convertit les valeurs Null pour les spécifiée valeur non Null. Dans ce cas, il est dit: "Si s est vide alors la traiter comme une chaîne vide". Le Replace() assure que tout " caractères de la chaîne sont doublés, comme ils doivent l'être, quand la chaîne est lui-même entre guillemets doubles, par exemple, "Say ""Hello"" for me!".
Merci beaucoup! Tout tourne.

OriginalL'auteur Gord Thompson

Vous devez vous connecter pour publier un commentaire.