La conversion xls en csv à l'aide de VBScript et de les séparer par des points-virgules

J'ai un VBScript extrait de code qui convertit mon xls et xlsx fichiers dans des fichiers csv. Cependant, je veux que chaque cellule pour être séparés par un point-virgule plutôt qu'une virgule. Sur mon ordinateur, le séparateur de liste est définie pour le point-virgule au lieu d'une virgule, donc, quand j'ouvre une fenêtre d'excel et de le faire enregistrer au format csv, il sépare par un point-virgule. Cependant, mon VBScript produit un fichier csv séparé par des virgules. J'ai trouvé l'extrait de code en ligne que je ne sais pas vraiment VBScript (je suis principalement un Programmeur Java). Comment puis-je changer l'extrait de code pour séparer les fichiers csv par un point-virgule plutôt que par des virgules?

if WScript.Arguments.Count < 2 Then
WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv"
Wscript.Quit
End If
Dim oExcel
Set oExcel = CreateObject("Excel.Application")
Dim oBook
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
oBook.SaveAs WScript.Arguments.Item(1), 6
oBook.Close False
oExcel.Quit
WScript.Echo "Done"

OriginalL'auteur Luke Mat | 2012-02-09

vous pouvez garder votre script d'origine, seulement besoin de donner un paramètre pour indiquer le contexte local doit s'appliquer. Cela permet d'économiser mon CSV avec un ; séparateur

if WScript.Arguments.Count < 2 Then 
  WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv" 
  Wscript.Quit 
End If 
Dim oExcel 
Set oExcel = CreateObject("Excel.Application") 
oExcel.DisplayAlerts = FALSE 'to avoid prompts
Dim oBook, local
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
local = true 
call oBook.SaveAs(WScript.Arguments.Item(1), 6, 0, 0, 0, 0, 0, 0, 0, 0, 0, local) 'this changed
oBook.Close False 
oExcel.Quit 
WScript.Echo "Done"

OriginalL'auteur peter

1

L'utilisation d'une virgule dans les fichiers texte délimités trouve ses racines dans les paramètres régionaux. Tandis que la virgule est standard aux états-unis, d'autres pays comme l'Allemagne utilisez le point-virgule à la place. Vous pouvez modifier le Séparateur de Liste de valeur dans les paramètres Régionaux et de Langue, puis choisissez CSV (délimité par des Virgules) (.csv) à partir d'Excel de la fenêtre Enregistrer sous. Le fichier résultant sera délimité par ce que la valeur est dans les paramètres du système. Ce script changements défaut, le Séparateur de Liste de réglage. Puis il ouvre la feuille de calcul et resauvegarde. Il reprend le système de réglage à sa valeur précédente avant de finir.

Il accepte deux paramètres de ligne de commande. La première est l'entrée de feuille de calcul; le second est le nom de fichier de sortie pour le fichier exporté.
```
strDelimiter = ";"

strSystemDelimiter = ""           ' This will be used to store the current sytem value
Const HKEY_CURRENT_USER = &H80000001

' Get the current List Separator (Regional Settings) from the registry
strKeyPath = "Control Panel\International"
strValueName = "sList"
strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.GetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strSystemDelimiter

' Set it temporarily to our custom delimiter
objRegistry.SetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strDelimiter

' Open spreadsheet with Excel and save it in a text delimited format
Const xlCSV = 6

Set objExcel = CreateObject("Excel.Application")
Set objWorkbook = objExcel.Workbooks.Open(WScript.Arguments.Item(0))
objWorkbook.SaveAs WScript.Arguments.Item(1), xlCSV
objWorkbook.Close vbFalse         ' Prevent duplicate Save dialog
objExcel.Quit

' Reset the system setting to its original value
objRegistry.SetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strSystemDelimiter
```
Après quelques tests, il semble que cela ne fonctionne que grâce à Excel de la boîte de dialogue Enregistrer sous et non par le biais de la ligne de commande ou l'automatisation. J'ai modifié le script un peu pour rendre la fenêtre Excel visible et de l'utilisation des raccourcis de touches pour ouvrir la boîte de dialogue Enregistrer sous par le biais de l'interface d'Excel. Ceci devrait faire l'affaire. Il a travaillé pour moi sur Vista x64 avec Excel 2007. J'espère que cela fonctionne pour vous.
```
strDelimiter = ";"

strSystemDelimiter = ""           ' This will be used to store the current sytem value
Const HKEY_CURRENT_USER = &H80000001

' Get the current List Separator (Regional Settings) from the registry
strKeyPath = "Control Panel\International"
strValueName = "sList"
strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.GetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strSystemDelimiter

' Set it temporarily to our custom delimiter
objRegistry.SetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strDelimiter

' Open spreadsheet with Excel and save it in a text delimited format
Const xlCSV = 6

Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = vbTrue
Set objWorkbook = objExcel.Workbooks.Open(WScript.Arguments.Item(0))

WScript.Sleep 500                 ' Delay to make sure the Excel workbook is open
strWorkbookName = objExcel.ActiveWorkbook.Name
strTitlebar = strWorkbookName
Set WshShell = CreateObject("WScript.Shell")
WshShell.AppActivate strTitlebar  ' Make the workbook active so it receives the keystrokes
WshShell.SendKeys "%fa"           ' Keyboard shortcuts for the Save As dialog
WScript.Sleep 500
WshShell.SendKeys "%tc{ENTER}"    ' Change the Save As type to CSV
If WScript.Arguments.Count > 1 Then
    WshShell.SendKeys "+{TAB}" & WScript.Arguments.Item(1)
    WScript.Sleep 500
End If                            ' This If block changes the save name if one was provided
WshShell.SendKeys "{ENTER}"       ' Save the file
WScript.Sleep 500
WshShell.SendKeys "{ENTER}"       ' Dismiss the CSV warning dialog
Set WshShell = Nothing

objWorkbook.Close vbFalse         ' Prevent duplicate Save dialog
objExcel.Quit

' Reset the system setting to its original value
objRegistry.SetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strSystemDelimiter
```
Merci!!!! Cependant, j'ai changé le délimiteur sur mon ordinateur dans le panneau de contrôle, point-virgule, mais lorsque le VBScript s'exécute, il utilise la virgule comme délimiteur qui est bizarre parce que lorsque j'enregistre Que dans Excel, il sépare par un point-virgule. Cela semble être en train de faire exactement la même chose juste à partir d'une ligne de commande au lieu de cliquer, et en modifiant les paramètres dans le panneau de contrôle. Mais je vais essayer ce script et vous permettre de connaître les résultats.
Ouais j'ai obtenu le même résultat. Il était séparé par des virgules. Je suis sur un ordinateur de l'école et peut-être il ne sera pas me permettre de modifier les clés de registre? Je vais essayer quand je suis sur mon ordinateur à la maison. J'espère que c'est la raison. Je vais vous faire part de mes résultats à la maison.
Luc, j'ai compris le problème et a affiché des nouveau code dans ma réponse. Cela devrait fonctionner pour vous.
Cela ne fonctionne pas non plus. Le fichier excel s'ouvre mais le code tente d'utiliser la commande "fatc" dans cmd et il dit ceci "ce n'est pas reconnu comme un interne ou de la commande de traitement par lots, un programme exécutable ou un fichier de commandes." L'habituel message d'erreur pour une commande incorrecte. Et la fenêtre excel se ferme aussi. Je ne sais pas pourquoi cette erreur se produit. Cependant, cette solution peut ne pas fonctionner pour moi, car il me semble que si une fenêtre d'excel sera ouverte pour chaque fichier excel que je suis en train de convertir, ce qui est un problème parce que je vais l'utiliser pour convertir autour de 700 fichiers excel à la fois...c'est beaucoup de excel windows.
Luc, quelle version de Windows et d'Excel que vous utilisez? Il paraît que c'est pas l'activation de la fenêtre Excel. Au lieu de cela, les frappes sont envoyés à l'actif de windows qui se trouve être une commande shell. Aussi, il va ouvrir les fichiers séquentiellement de façon à ce que vous ne devriez pas avoir de 700 excel fenêtres ouvertes en même temps.

OriginalL'auteur Nilpo
1

La Fonction enregistrer sous est défini ainsi :
.SaveAs(Nom De Fichier, FileFormat, Mot De Passe, WriteResPassword, ReadOnlyRecommended, CreateBackup, AccessMode, ConflictResolution, AddToMru, TextCodepage, TextVisualLayout, Local)

De pth est, pour utiliser le point-virgule (si votre langue régionale de l'option sont correctement définies)

ExcelObj.Workbooks(1).SaveAs csvFile, 6,,,,,,,,,,Vrai

je vous remercie, mais je n'ai plus besoin de ce code. je vous remercie beaucoup de bien.
Meilleure réponse ici ... la Seule chose que vous avez à regarder dehors pour est votre version d'Excel Vrai sur la position 12 travaux pour Excel 2013 Pour Excel 2010, il est de 2 arguments moins sur la position 10 On peut aussi vérifier: msdn.microsoft.com/en-us/library/office/... dans ce contexte ...

OriginalL'auteur Martin
0

Vous pouvez rouvrir le fichier avec l'OFS objet, puis de faire un Replace() sur le caractère virgule.
```
Const OpenAsDefault = -2
Const FailIfNotExist = 0
Const ForReading = 1
Const ForWriting = 2

Set oFSO = CreateObject("Scripting.FileSystemObject")
Set fCSVFile = _
  oFSO.OpenTextFile("C:\path\file.csv", ForReading, FailIfNotExist, OpenAsDefault)

sFileContents = fCSVFile.ReadAll
fCSVFile.Close
sFileContents = Replace(sFileContents, ",",";"))

Set fCSVFile = oFSO.OpenTextFile("C:\path\file.csv", ForWriting, True)
fCSVFile.Write(sFileContents)
fCSVFile.Close
```
Ce n'est pas une solution cohérente, car il permettra également de remplacer la virgule dans les littéraux: John Doe,Euro,"1,234.00" permettra de résoudre à John Doe;Euro;"1;234.00", probablement pas ce que veut l'utilisateur.
Évidemment, si c'est le type de données, il ne serait pas utile. Quand j'ai posté il n'y avait pas d'autres réponses, j'ai donc été tout simplement offrir quelque réponse.
Bien sûr. Et si l'utilisateur n'a qu'un ensemble limité de données sans virgule est qu'il va bien fonctionner. Toutefois, la conversion des données dans un bon fichier CSV est ambigeous. Même Microsoft n'a pas à suivre avec les rfc4180 le format de définition.
Oui, il y aura de l'argent dans les fichiers, c'est pourquoi je veux séparer par des points-virgules à la place des virgules. Si je n'étais pas à faire avec l'argent, je garderais avec des virgules et d'en rester là. Mais merci d'essayer de l'aider, je l'apprécie.

OriginalL'auteur Nathan Rice

Vous devez vous connecter pour publier un commentaire.