La liaison d'une VB.NET de l'étiquette.texte à un objet de propriété

Je veux avoir une étiquette dans un formulaire dont la valeur de texte change en fonction de la valeur d'une instance d'une classe. Il semble que j'ai peut lier la valeur de texte de l'étiquette d'un objet source de données. Quand j'essaye de cela, il ne semble pas fonctionner.

Me.Label4.DataBindings.Add(New System.Windows.Forms.Binding("Text", Me.ItemInfoBindingSource, "ItemNumber", True, System.Windows.Forms.DataSourceUpdateMode.OnPropertyChanged))

Mon itemInfoBindingSource:

Me.ItemInfoBindingSource.DataSource = GetType(CFP.ItemInfo)

et la définition de la classe:

Public Class ItemInfo
    Public Property ItemNumber As String = "rename"
    Public Property Description As String
    Public Property FileLocation As String
    Public Property CompileHistory As List(Of CompileHistory)
End Class

Je pense que ce que j'ai fait est de se lier à une classe, une instance d'une classe. Penser à ce sujet, ce que je veux vraiment faire est de lier une instance d'une classe à une étiquette... Comment?
Est-ce possible?

OriginalL'auteur Eric | 2013-09-29

  1. 8

    Oui, c'est possible, mais vous avez besoin de déclencher un événement de laisser l'étiquette de savoir que la propriété a changé. Si vous utilisez un type comme une BindingList, ce serait fait automatiquement, mais vous êtes en essayant de se lier à un String qui ne soulève pas PropertyChanged événements.

    Pour ajouter l'événement à votre classe:

    • Changer votre définition de classe pour implémenter INotifyPropertyChanged
    • Ajouter le correspondant événement PropertyChanged
    • Changement de la fonction d'auto-mise en œuvre de la propriété par l'extension de la propriété et de déclencher l'événement.

    Voici le résultat de ces changements pour tout le ItemNumber bien dans votre classe:

    Public Class ItemInfo
    Implements System.ComponentModel.INotifyPropertyChanged

    Private _itemNumber As String = "rename"
    Public Property ItemNumber As String
        Get
            Return _itemNumber
        End Get
        Set(value As String)
            _itemNumber = value
            RaiseEvent PropertyChanged(Me, 
                New System.ComponentModel.PropertyChangedEventArgs("ItemNumber"))
        End Set
    End Property

    Public Event PropertyChanged(sender As Object, 
        e As System.ComponentModel.PropertyChangedEventArgs) _
        Implements System.ComponentModel.INotifyPropertyChanged.PropertyChanged
End Class

    J'ai ajouté une zone de texte d'étiquette et à une forme, ajout de la liaison de données dans le Form.Load cas, l'ajout d'un champ appelé ItemInfoBindingSource de type ItemInfo, et mise à jour de la ItemNumber dans le TextBox.TextChanged événement.

    Private ItemInfoBindingSource As New ItemInfo

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Label1.DataBindings.Add("Text", Me.ItemInfoBindingSource, "ItemNumber")
End Sub

Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) _
        Handles TextBox1.TextChanged

    ItemInfoBindingSource.ItemNumber = TextBox1.Text
End Sub

    Maintenant, lorsque vous tapez dans la zone de texte, ItemNumber.Ensemble est appelé, et génère un événement de laisser quelque chose à l'écoute sais qu'il a été modifié. L'étiquette est à l'écoute, et il met à jour son Texte à la propriété, de sorte que vous pouvez voir la nouvelle valeur.

    Merci! Juste ce que je cherchais aujourd'hui.

    OriginalL'auteur kvermeer