La manipulation de la chaîne en AppleScript

Je voudrais aussi utiliser les décalages. text 1 thru 2 of "xyz" est équivalent à items 1 thru 2 of "xyz" as string.

set x to "First Last ([email protected])"
set pos to offset of " (" in x
{text 1 thru (pos - 1) of x, text (pos + 2) thru -2 of x}

Autant que je sache, vous n'avez pas à rétablir le texte de l'élément de délimiteurs.

set x to "First Last ([email protected])"
set text item delimiters to {" (", ")"}
set {fullname, email} to text items 1 thru 2 of x

Si d'autres personnes étaient à la recherche à propos de la manipulation de la chaîne en général, ici sont les méthodes pour le remplacement et la répartition du texte et de rejoindre les listes:

on replace(input, x, y)
    set text item delimiters to x
    set ti to text items of input
    set text item delimiters to y
    ti as text
end replace

on split(input, x)
    if input does not contain x then return {input}
    set text item delimiters to x
    text items of input
end split

on join(input, x)
    set text item delimiters to x
    input as text
end join

Comparaisons de chaînes ignorer la casse par défaut:

"A" is "a" -- true
"ab" starts with "A" -- true
considering case
    "A" is "a" -- false
    "ab" starts with "A" -- false
end considering

Inversion de texte:

reverse of items of "esrever" as text

Vous pouvez utiliser n'script shell pour modifier la casse du texte:

do shell script "printf %s " & quoted form of "aä" & " | LC_CTYPE=UTF-8 tr [:lower:] [:upper:]" without altering line endings

echo interprète les séquences d'échappement par défaut dans OS X /bin/sh. Vous pouvez également utiliser shopt -u xpg_echo; echo -n au lieu de printf %s. LC_CTYPE=UTF-8 rend les classes de caractères comprennent certains des caractères non-ASCII. Si without altering line endings est à gauche, des sauts de ligne sont remplacés par des retours chariot et un saut de ligne à la fin de la sortie est supprimée.

paragraphs of scissions de chaînes autour de \n, \r, \r\n. Il n'a pas de bande de délimiteurs.

paragraphs of ("a" & linefeed & "b" & return & "c" & linefeed)
-- {"a", "b", "c", ""}

La version texte du presse-papiers utilise CR des fins de ligne. Cette fonction convertit les fins de ligne de LF:

set text item delimiters to linefeed
(paragraphs of (get the clipboard as text)) as text

Unicode text a été équivalent à text et string depuis 10.5:

Il n'existe plus de distinction entre Unicode et non-Unicode texte. Il y a exactement un texte de la classe, nommée “text”: c'est la classe de "foo" retourne le texte.