La meilleure façon de savoir si un utilisateur a des privilèges d'administrateur à partir d'un script VBScript

J'ai besoin de vérifier que l'utilisateur qui exécute le script dispose des privilèges d'administrateur sur la machine.

J'ai précisé à l'utilisateur qui exécute le script parce que le script pourrait avoir été exécuté avec un utilisateur autre que celui connecté à l'aide de quelque chose de semblable à "Runas".

@Javier: les Deux solutions fonctionnent sur un PC avec une version anglaise de Windows installé, mais pas si l'installation est dans une autre langue. C'est parce que les Administrateurs de groupe n'existe pas, le nom est différent, par exemple en espagnol. J'ai besoin de la solution de travail dans toutes les configurations.

OriginalL'auteur Javier De Pedro | 2008-11-19

privileges vbscript

2

Vous pouvez utiliser le script si vous voulez voir si l'utilisateur est un administrateur
```
Set objNetwork = CreateObject("Wscript.Network")
strComputer = objNetwork.ComputerName
strUser = objNetwork.UserName

isAdministrator = false

Set objGroup = GetObject("WinNT://" & strComputer & "/Administrators")
For Each objUser in objGroup.Members
    If objUser.Name = strUser Then
        isAdministrator = true        
    End If
Next

If isAdministrator Then
    Wscript.Echo strUser & " is a local administrator."
Else
    Wscript.Echo strUser & " is not a local administrator."
End If
```
Je ne suis pas sûr de savoir comment y faire face quand le script est exécuté avec "Runas" j'ai peur.

Salut Tim C, merci. Je l'ai vérifié un, il semble que cela fonctionne très bien aussi dans mon cas. Le nom d'utilisateur je reçois n'est pas connecté mais celle que le script est en cours d'exécution. Juste un commentaire. C'est un peu lentement. Je suis l'appel de ce script de démarrage d'une page HTML et il prend environ 2/3 secondes.
Cela ne fonctionne pas si l'utilisateur n'est pas directement dans le groupe des Administrateurs, mais par le biais de certains appartenance à un groupe.

OriginalL'auteur Tim C
4

En faisant cela, vous rompre les scénarios où l'utilisateur dispose de la privs pour votre script, mais il n'appartient pas aux Administrateurs. Au lieu de vérifier l'appartenance à un groupe, vérifiez les compétences spécifiques dont vous avez besoin.

Je suis d'accord qu'il serait un meilleur moyen de le mettre en œuvre mais c'est un requeriment que l'utilisateur dispose des privilèges d'administrateur pour installer le logiciel, donc à mon avis de vérification qui serait plus facile.

OriginalL'auteur Jay Bazuzi

Que sur la recherche pour "\\computername\Admin$\system32"?

function IsLoggedInAsAdmin()
    isAdmin = false
    set shell = CreateObject("WScript.Shell")
    computername = WshShell.ExpandEnvironmentStrings("%computername%")
    strAdmin = "\\" & computername & "\Admin$\System32"

    isAdmin = false

    set fso = CreateObject("Scripting.FileSystemObject")

    if fso.FolderExists(strAdmin) then
        isAdmin = true
    end if

    IsLoggedInAsAdmin = isAdmin
end function

OriginalL'auteur JohnZaj

2

J'ai essayé de Tim C de la solution sur un Windows 7 sur mon réseau d'entreprise où je n'ai fait disposer des droits d'administrateur. Mais ce que montre mon utilisateur comme n'ayant pas les droits admin.

Au lieu de cela, j'ai utilisé un hackier méthode, que l'appel à la "défragmentation" dans l'invite de cmd nécessite un accès administrateur. Alors qu'il travaille, méfiez-vous que XP et 7 (et éventuellement les futures versions de Windows) diffèrent dans le code de retour. Il peut y avoir plus de choix cohérents de défragmentation, mais il fonctionne pour l'instant.
```
Function isAdmin
    Dim shell
    set shell = CreateObject("WScript.Shell")
    isAdmin = false
    errlvl = shell.Run("%comspec% /c defrag /?>nul 2>nul", 0, True)
    if errlvl = 0 OR errlvl = 2 Then '0 on Win 7, 2 on XP
        isAdmin = true
    End If
End Function
```
+1 c'est une bonne idée

OriginalL'auteur Dss

Je sais que ce fil est très ancienne et a marqué une réponse, mais la réponse n'est pas vraiment à donner ce que l'OP a demandé à propos.

Pour quelqu'un d'autre recherche et de trouver cette page, voici une alternative qui ne se rapport fondé sur les droits de ne pas l'appartenance à un groupe, de sorte Runas Administrateur montre des droits d'admin comme Vrai.

Option Explicit 

msgbox isAdmin(), vbOkonly, "Am I an admin?"

Private Function IsAdmin()
    On Error Resume Next
    CreateObject("WScript.Shell").RegRead("HKEY_USERS\S-1-5-19\Environment\TEMP")
    if Err.number = 0 Then 
        IsAdmin = True
    else
        IsAdmin = False
    end if
    Err.Clear
    On Error goto 0
End Function

OriginalL'auteur RLH

Cet article a un joli morceau de code sur la manière d'énumérer les membres d'un groupe (copié ici pour plus de commodité et édité pour ne pas utiliser l'adresse de courrier électronique):

Function RetrieveUsers(domainName,grpName)

dim GrpObj
dim mbrlist
dim mbr

'-------------------------------------------------------------------------------
' *** Enumerate Group Members ***
'-------------------------------------------------------------------------------

' Build the ADSI query and retrieve the group object
Set GrpObj = GetObject("WinNT://" & domainName & "/" & grpName & ",group")

' Loop through the group membership and build a string containing the names
for each mbr in GrpObj.Members
   mbrlist = mbrlist & vbTab & mbr.name & vbCrLf
Next

RetrieveUsers=mbrlist

End Function

Vous pouvez ensuite écrire une fonction pour voir si un utilisateur est dans la liste...

Function IsAdmin(user)
    IsAdmin = InStr(RetrieveUsers("MachineName", "Administrators"), user) > 0
End Function

...et de l'appeler comme ceci:

If IsAdmin("LocalAccount") Then
    Wscript.Echo "LocalAccount is an admin"
Else
    Wscript.Echo "LocalAccount is not an admin"
End If

OriginalL'auteur Patrick Cuff

Encore une autre rapide n sale méthode. De retour <> 0 Si IsNotAdmin

Function IsNotAdmin()
    With CreateObject("Wscript.Shell")
        IsNotAdmin = .Run("%comspec% /c OPENFILES > nul", 0, True)
    End With
End Function

OriginalL'auteur spudw

Utilisateur peut ne pas être dans le groupe administrateur local. Par exemple - admins du domaine.
Contrôle de compte d'utilisateur bloque généralement d'un accès administrateur du registre, des actions e.t.c. même pour les administrateurs(onl y manuel "exécuter en tant qu'administrateur" obtient de droit)...

Voici mes fous:

Set Shell = CreateObject("WScript.Shell")
set fso = CreateObject("Scripting.FileSystemObject")
strCheckFolder = Shell.ExpandEnvironmentStrings("%USERPROFILE%") 
strCheckFolder = strCheckFolder+"\TempFolder"

if fso.FolderExists(strCheckFolder) then
        fso.DeleteFolder(strCheckFolder)
end if

fso.CreateFolder(strCheckFolder)
tempstr = "cmd.exe /u /c chcp 65001 | whoami /all >" & strCheckFolder & "\rights.txt"
Shell.run tempstr

tempstr = strCheckFolder & "\rights.txt"
WScript.Sleep 200
Set txtFile = FSO.OpenTextFile(tempstr,1)

IsAdmin = False

Do While Not txtFile.AtEndOfStream
  x=txtFile.Readline
  If InStr(x, "S-1-5-32-544") Then
      IsAdmin = True
  End If
Loop

txtFile.Close

OriginalL'auteur OlegSu

Function isAdmin
    Dim shell
    Set shell = CreateObject("WScript.Shell")
    isAdmin = false
    errorLevel = shell.Run("%comspec% /c net session >nul 2>&1", 0, True)
    if errorLevel = 0
        isAdmin = true
    End If
End Function

OriginalL'auteur lygstate

À l'aide de "localhost" au lieu du vrai nom d'hôte augmente l'exécution du script sur 10x!
Mon code final est:

' get_admin_status.vbs
Option Explicit

Dim oGroup:   Set oGroup   = GetObject("WinNT://localhost/Administrators,group")
Dim oNetwork: Set oNetwork = CreateObject("Wscript.Network")

Dim sSearchPattern: sSearchPattern = "WinNT://" & oNetwork.UserDomain & "/" & oNetwork.UserName

Dim sMember
For Each sMember In oGroup.Members
  If sMember.adsPath = sSearchPattern Then
    ' Found...
    Call WScript.Quit(0)
  End If
Next

' Not found...
Call WScript.Quit(1)

Ce script renvoie le code de sortie 0 si l'utilisateur courant est un compte administrateur local.

Utilisation: cscript.exe get_admin_status.vbs

OriginalL'auteur Stefan Bohlein

Vous devez vous connecter pour publier un commentaire.