La mise à jour du compteur de XQuery

Je veux créer un compteur en xquery. Ma première tentative a regardé comme suit:

let $count := 0
for $prod in $collection
let $count := $count + 1
return 
<counter>{$count }</counter>

Résultat attendu:

<counter>1</counter>
<counter>2</counter>  
<counter>3</counter>

Résultat réel:

<counter>1</counter>
<counter>1</counter>  
<counter>1</counter>

La $count variable, soit de ne pas mettre à jour ou en cours de réinitialisation. Pourquoi ne puis-je pas réaffecter une variable existante? Ce serait une meilleure façon d'obtenir le résultat souhaité?

OriginalL'auteur Gopal Thakur | 2012-04-24

  1. 21

    Essayez d'utiliser 'à':

    for $d at $p in $collection
return 
element counter { $p }

    Cela vous donnera la position de chaque '$d'. Si vous souhaitez utiliser cette collaboration avec les order by clause, cela ne fonctionne pas depuis le poste est basé sur la commande initiale, et non pas sur le résultat du tri. Pour surmonter cette difficulté, il suffit d'enregistrer le résultat trié de l'expression FLWOR dans une variable, et l'utilisation de la at clause dans un deuxième FLWOR que juste itère sur la première, résultat trié.

    let $sortResult := for $item in $collection
                   order by $item/id
                   return $item

for $sortItem at $position in $sortResult
return <item position="{$position}"> ... </item>
    Merci beaucoup. Il fonctionne très bien pour moi.
    Il fonctionne pour moi aussi Merci man! vous sauver la journée!

    OriginalL'auteur tohuwawohu

  2. 7

    @Ranon dit, tous les XQuery les valeurs sont immuables, de sorte que vous ne pouvez pas mettre à jour une variable. Mais si vous avez vraiment besoin d'un modifiable nombre (il ne devrait pas être trop souvent), vous pouvez utiliser la récursivité:

    declare function local:loop($seq, $count) {
  if(empty($seq)) then ()
  else
    let $prod  := $seq[1],
        $count := $count + 1
    return (
      <count>{ $count }</count>,
      local:loop($seq[position() > 1], $count)
    )
};

local:loop($collection, 0)

    Il se comporte exactement comme vous le souhaitez avec votre exemple.

    Dans XQuery 3.0 une manière plus générale, la version de cette fonction est définie dans la bibliothèque standard: fn:pli-droit($f, $zero, $seq)

    Cela dit, dans votre exemple, vous devriez certainement utiliser at $count comme indiqué par @tohuwawohu.

    OriginalL'auteur Leo Wörteler

  3. 6

    Immuable variables

    XQuery est un langage de programmation fonctionnel, ce qui implique, entre autres, immuables, de variables, de sorte que vous ne peut pas changer la valeur d'une variable. D'autre part, un puissant ensemble de fonctions est disponible pour vous, ce qui résout beaucoup de quotidien les problèmes de programmation.

    let $count := 0
for $prod in $collection]
  let $count := $count + 1
return 
<counter>{$count }</counter>

    let $count , ligne 1, définit cette variable dans la portée de tous, qui sont toutes les lignes suivantes dans ce cas. let $count en ligne 3 définit un nouveau $count qui est 0+1, valable dans toutes les lignes suivantes à l'intérieur de ce bloc de code - ce qui n'est pas défini. Si vous avez en effet incrément $count trois fois par un, mais jeter le résultat est immédiat.

    BaseX' requête info affiche la version optimisée de cette question, qui est

    for $prod in $collection
  return element { "counter" } { 1 }

    La solution

    Pour obtenir le nombre total d'éléments dans $collection, vous pouvez simplement utiliser

    return count($collection)

    Pour une liste des fonctions XQuery, vous pourriez avoir un coup d'oeil à la XQuery partie de functx qui contient une liste de fonctions XQuery et aussi quelques autres fonctions utiles qui peuvent être inclus en tant que module.

    OriginalL'auteur Jens Erat

  4. 6

    Spécifiques à MarkLogic vous pouvez également utiliser xdmp:set. Mais cela casse un langage fonctionnel hypothèses, afin de l'utiliser de façon conservatrice.

    http://docs.marklogic.com/5.0doc/docapp.xqy#display.xqy?fname=http://pubs/5.0doc/apidoc/ExsltBuiltins.xml&category=Extension&function=xdmp:set

    Pour un exemple de xdmp:set dans le monde réel, le code, la recherche de l'analyseur https://github.com/mblakele/xqysp/blob/master/src/xqysp.xqy pourrait être utile.

    OriginalL'auteur mblakele

  5. 6

    Toutes les solutions ci-dessus ne sont valables, mais je tiens à mentionner que vous pouvez utiliser la requête XQuery Script extension pour définir les valeurs de la variable:

    variable $count := 0;

for $prod in (1 to 10)
return {
  $count := $count + 1;
  <counter>{$count}</counter>
}

    Vous pouvez essayer cet exemple live at http://www.zorba-xquery.com/html/demo#twh+3sJfRpHhZR8pHhOdsmqOTvQ=

    Est-ce une requête XQuery 3.0 chose? Sans doute bon de le mentionner.
    XQuery Script est une extension offertes par certains XQuery implémentations. Il est particulièrement précis si vous voulez faire les deux mises à jour et le retour des éléments en même temps (par exemple. pour les services web), mais empêche beaucoup d'optimisations possibles. Vous devez vous en tenir à la base XQuery chaque fois que possible.
    L'exemple vivant a expiré (404) 🙁

    OriginalL'auteur wcandillon

  6. 4

    Utilisation xdmp:set au lieu de la requête ci-dessous

    let $count := 0
for $prod in (1 to 4)
return ( xdmp:set($count,number($count+1)) ,<counter>{$count }</counter>

    OriginalL'auteur Nikunj Vekariya

  7. 2

    Je pense que vous êtes à la recherche pour quelque chose comme:

    XQUERY:

    for $x in (1 to 10)
return
  <counter>{$x}</counter>

    De SORTIE:

    <counter>1</counter>
<counter>2</counter>
<counter>3</counter>
<counter>4</counter>
<counter>5</counter>
<counter>6</counter>
<counter>7</counter>
<counter>8</counter>
<counter>9</counter>
<counter>10</counter>

    OriginalL'auteur Navin Rawat