La portée des variables dans XSLT

Je rencontre un problème à essayer de comprendre var portée sur xslt. Ce que je veux réellement faire de l'ignorer "trip" tags qui ont un répétée de tourcode'.

XML exemple:

<trip>
 <tourcode>X1</tourcode>
 <result>Budapest</result>
</trip>
<trip>
 <tourcode>X1</tourcode>
 <result>Budapest</result>
</trip>
<trip>
 <tourcode>X1</tourcode>
 <result>Budapest</result>
</trip>
<trip>
 <tourcode>Y1</tourcode>
 <result>london</result>
</trip>
<trip>
 <tourcode>Y1</tourcode>
 <result>london</result>
</trip>
<trip>
 <tourcode>Z1</tourcode>
 <result>Rome</result>
</trip>

Processeur XSLT:

<xsl:for-each select="trip">    
    <xsl:if test="not(tourcode = $temp)">
      <xsl:variable name="temp" select="tour"/>
      //Do Something (Print result!)
    </xsl:if>
</xsl:for-each>

De Sortie Souhaité:
Budapest, londres, Rome

Titre de la question aurait été .. quelque chose comme, "Suppression de nœuds dupliqués à partir de xml à l'aide de XSLT"

OriginalL'auteur Mazzi | 2010-02-05

  1. 8

    De Sortie désiré: Budapest, londres, Rome

    Ce que vous êtes après est groupement sortie par le nom de la ville. Il ya deux façons de le faire en XSLT.

    L'un d'eux est: est-ce

    <xsl:template match="/allTrips">
  <xsl:apply-templates select="trip" />
</xsl:template>

<xsl:template match="trip">
  <!-- test if there is any preceding <trip> with the same <result> -->
  <xsl:if test="not(preceding-sibling::trip[result = current()/result])">
    <!-- if there is not, output the current <result> -->
    <xsl:copy-of select="result" />
  </xsl:if>
</xsl:template>

    Et l'autre est appelée Muenchian regroupement et @Rubens Farias viens de poster une réponse qui montre comment le faire.

    Merci s'accoupler, même si de 4 doublons, il montre encore 2 mais il me rapproche de ce que j'avais à l'esprit.
    Il n'? Il n'avait pas quand je l'ai testé avec votre échantillon. Si vous affichez le code XML et XSL-vous travailler avec je suis sûr que je peux point de ce qui est mal.
    Le xsl et xml sont peu encombrants, j'ai essayé de simplifier autant que possible. Je ne sais pas si stackoverflow a envoyer un message fonctionnalités?! Donc, je peux vous l'envoyer directement.
    J'ai uploadé une nouvelle version de votre XSLT tinypaste.com/f3a23. N'hésitez pas à demander de suivi des questions et d'avoir du plaisir à essayer de le comprendre. 🙂
    Oh putain. J'ai fait une petite erreur dans le <xsl:sort>. L'expression de tri est incorrect, mais seulement par un petit peu. C'est assez évident, je vous fait confiance pour trouver très rapidement. 🙂

    OriginalL'auteur Tomalak

  2. 24

    Vous ne peut pas des changements de variables dans XSLT.

    Vous avez besoin d'y réfléchir plus que programmation fonctionnelle au lieu de la procédure, parce que XSLT est un langage fonctionnel. Pensez à la variable de portée dans quelque chose comme ce pseudo-code:

    variable temp = 5
call function other()
print temp

define function other()
  variable temp = 10
  print temp

    Qu'attendez-vous la sortie? Il devrait être 10 5, pas 10 10, parce que le temp l'intérieur de la fonction other n'est pas la même variable que temp en dehors de cette fonction.

    C'est la même chose en XSLT. Variables, une fois créée, ne peut pas être redéfini parce qu'ils sont en écriture une fois, lisez-le nombre de variables de conception.

    Si vous voulez faire de la valeur d'une variable définie de façon conditionnelle, vous devez définir la variable conditionnellement, comme ceci:

    <xsl:variable name="temp">
  <xsl:choose>
    <xsl:when test="not(tourcode = 'a')">
      <xsl:text>b</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text>a</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
</xsl:variable>
<xsl:if test="$temp = 'b'">
  <!-- Do something -->
</xsl:if>

    La variable n'est définie que dans un seul endroit, mais sa valeur est conditionnelle. Maintenant que temp's valeur est définie, elle ne peut pas être redéfini plus tard. En programmation fonctionnelle, les variables sont plus comme des paramètres en lecture seule en qui ils peuvent être définis, mais ne peut pas être modifié ultérieurement. Vous devez comprendre ceci correctement afin d'utiliser des variables dans tout langage de programmation fonctionnel.

    Désolé les mecs, vous la réponse a été grande, cependant, j'ai changer la question d'un peu plus près à ce que je suis après. Merci
    Écrivez toujours question vers ce que vous voulez faire (input->sortie désirée), jamais vers comment vous pensez que vous pouvez le faire. Dans ce cas: Vous ne souhaitez pas modifier les valeurs d'une variable, vous voulez produire une liste de valeurs uniques de l'entrée.
    +1, vraiment grande réponse, @Welbog
    Quelqu'un devrait changer la question, si cette réponse s'inscrit à nouveau. C'est beaucoup mieux que la question. Les Questions sont surfait de toute façon...
    Désolé les gars pour changer la question. Maintenant j'ai ma réponse que voulez-vous me changer la question?

    OriginalL'auteur Welbog

  3. 4

    Essayez ceci:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:key name="trip" match="trip" use="result" />

  <xsl:template match="/trips">

    <xsl:for-each select="trip[count(. | key('trip', result)[1]) = 1]">
      <xsl:if test="position() != 1">, </xsl:if>
      <xsl:value-of select="result"/>
    </xsl:for-each>

  </xsl:template>
</xsl:stylesheet>

    OriginalL'auteur Rubens Farias