La résolution “Ne peut pas effectuer DML à l'intérieur d'une requête” erreur dans Oracle

J'ai créé fonction régulière. Il a été créé avec succès. Mais quand je le lance avec 

select reg('awlad','01968688680','545466455','12345') from dual

Il me donne cette erreur:

ORA-14551: cannot perform a DML operation inside a query

Comment puis-je résoudre ce problème?

CREATE OR REPLACE FUNCTION reg(
name in varchar2,
cellNo in varchar2,
voterId in varchar2,
pass in varchar2
)
RETURN NUMBER
IS 
succ NUMBER;
BEGIN 
      succ:=0;
      insert into logInfo values(loginfo_seq.nextval,cellNo,pass,0);
      succ:=1;
      insert into passInfo values(name,cellNo,voterId);
      succ:=2;
      RETURN succ;
END;
InformationsquelleAutor Awlad Liton | 2012-04-01
  1. 6

    Une fonction est censé calculer et retourner un résultat, pas de changement de l'état de la base de données. Si vous voulez faire DML dans une fonction (par exemple, si vous souhaitez insérer des lignes dans les tables), vous ne pouvez pas appeler cette fonction dans un SELECT déclaration depuis un SELECT instruction ne peut pas changer l'état de la base de données. En général, vous seriez mieux de la création de ce genre de chose comme une procédure stockée plutôt que d'une fonction stockée.

    Vous pouvez appeler cette fonction à partir d'un PL/SQL bloc comme vous le feriez pour appeler une procédure stockée

    DECLARE
  l_success_code NUMBER;
BEGIN
  l_success_code := reg('awlad','01968688680','545466455','12345');
END;

    Si vous souhaitez créer une procédure à cette

    CREATE OR REPLACE PROCEDURE reg( name in varchar2, 
                                 cellNo in varchar2, 
                                 voterId in varchar2, 
                                 pass in varchar2, 
                                 succ out NUMBER ) 
AS 
BEGIN 
  succ:=0; 
  insert into logInfo values(loginfo_seq.nextval,cellNo,pass,0); 
  insert into passInfo values(name,cellNo,voterId); 
  succ:=1; 
END;

    puis vous auriez besoin d'appeler la procédure en passant par la OUT paramètre

    DECLARE
  l_success_code NUMBER;
BEGIN
  reg('awlad','01968688680','545466455','12345', l_success_code);
END;
    • Grâce Grotte. j'ai essayé, mais quand j'appel la procédure, il me montrer l'erreur: un mauvais numéro ou les types d'arguments dans l'appel à 'REG'. ma procédure est la suivante:CREATE or replace PROCEDURE reg( nom varchar2, cellNo in varchar2, voterId in varchar2, pass in varchar2, succ NOMBRE ) as BEGIN succ:=0; insert into logInfo valeurs(loginfo_seq.nextval,cellNo,pass,0); insert into passInfo valeurs(nom,cellNo,voterId); succ:=1; END;
    • Vous auriez besoin de passer dans un cinquième paramètre si vous avez créé la procédure avec un OUT paramètre. Édité ma réponse à montrer comment le faire.
    InformationsquelleAutor Justin Cave
  2. 3

    Si tout ce que vous voulez faire est de les informations du journal, il serait approprié d'utiliser un autonome transaction pour faire de la plaquette intermédiaire.

    CREATE OR REPLACE FUNCTION reg(NAME IN VARCHAR2, 
                               cellNo IN VARCHAR2, 
                               voterId IN VARCHAR2, 
                               pass IN VARCHAR2)
   RETURN NUMBER IS
   --
   PROCEDURE do_loginfo (p_id NUMBER, 
                         p_cellNo VARCHAR2, 
                         p_pass VARCHAR2, 
                         p_x NUMBER) IS
   PRAGMA AUTONOMOUS_TRANSACTION
   BEGIN
      INSERT INTO logInfo VALUES (p_id, p_cellNo, p_pass, p_x);
      COMMIT;
   END do_loginfo;
   PROCEDURE do_passInfo (p_name VARCHAR2, 
                          p_cellNo VARCHAR2, 
                          p_voterId VARCHAR2) IS
   PRAGMA AUTONOMOUS_TRANSACTION
   BEGIN
      INSERT INTO passInfo VALUES (p_name, p_cellNo, p_voterId);
      COMMIT;
   END do_passInfo;
   --
   succ NUMBER;
BEGIN
   succ := 0;
   do_logInfo (loginfo_seq.NEXTVAL, cellNo, pass, 0);
   succ := 1;
   do_passInfo (NAME, cellNo, voterId);
   succ := 2;
   RETURN succ;
END;

    Noter qu'il sera utile pour le débogage but, mais comme il n'est pas transactionnel, il ne devrait pas être utilisé pour enregistrer les données (depuis les lignes insérées va rester, même si la transaction est annulée).

    InformationsquelleAutor Vincent Malgrat