la validation du schéma avec msxml en delphi

Je suis en train de valider un fichier XML contre les schémas qu'il référence. (À l'aide de Delphi et MSXML2_TLB.) La (partie de la) code ressemble à ceci:

procedure TfrmMain.ValidateXMLFile;
var
    xml: IXMLDOMDocument2;
    err: IXMLDOMParseError;
    schemas: IXMLDOMSchemaCollection;
begin
    xml := ComsDOMDocument.Create;
    if xml.load('Data/file.xml') then
    begin
        schemas := xml.namespaces;
        if schemas.length > 0 then
        begin
            xml.schemas := schemas;
            err := xml.validate;
        end;
    end;
end;

Cela a pour conséquence que le cache est chargé (schemas.length > 0), mais alors la prochaine cession soulève une exception: "seulement XMLSchemaCache-schemacollections peut être utilisé."

Comment dois-je aller à ce sujet?

OriginalL'auteur Miel | 2009-01-15

Je suis venu avec une approche qui semble fonctionner. J'ai d'abord charger le schéma est explicite, puis ajouter themn à la schemacollection. Ensuite, je charge le fichier xml et d'attribuer le schemacollection à ses schémas de propriété. La solution ressemble maintenant à ceci:

uses MSXML2_TLB  
That is:  
//Type Lib: C:\Windows\system32\msxml4.dll  
//LIBID: {F5078F18-C551-11D3-89B9-0000F81FE221}

function TfrmMain.ValidXML(
    const xmlFile: String; 
    out err: IXMLDOMParseError): Boolean;
var
    xml, xsd: IXMLDOMDocument2;
    cache: IXMLDOMSchemaCollection;
begin
    xsd := CoDOMDocument40.Create;
    xsd.Async := False;
    xsd.load('http://the.uri.com/schemalocation/schema.xsd');

    cache := CoXMLSchemaCache40.Create;
    cache.add('http://the.uri.com/schemalocation', xsd);

    xml := CoDOMDocument40.Create;
    xml.async := False;
    xml.schemas := cache;

    Result := xml.load(xmlFile);
    if not Result then
      err := xml.parseError
    else
      err := nil;
end;

Il est important d'utiliser XMLSchemaCache40 ou plus tard. Les versions antérieures ne suivent pas le Schéma W3C XML standard, mais seulement de valider l'encontre de Schéma XDR, une spécification MicroSoft.

L'inconvénient de cette solution est que j'ai besoin de charger le schéma est explicite. Il me semble qu'il devrait être possible de les récupérer automatiquement.

comment définissez-vous xmlDoc?
désolé, je pense qu'il devrait être xml, pas xmlDoc. Juste pour être sûr, je vais vérifier avant que je modifie.

OriginalL'auteur Miel

Tout BennyBechDk peut-être sur la bonne voie, j'ai quelques problèmes avec son code, que je vais corriger ci-dessous:

uses Classes, XMLIntf, xmlDoc, SysUtils;

function IsValidXMLDoc(aXmlDoc: IXMLDocument): boolean;
var
  validateDoc: IXMLDocument;
begin
  result := false;  //eliminate any sense of doubt, it starts false period.
  validateDoc := TXMLDocument.Create(nil);
  try   
    validateDoc.ParseOptions := [poResolveExternals, poValidateOnParse];
    validateDoc.XML := aXmlDoc.XML;
    validateDoc.Active := true;
    Result := True;
  except
    //for this example, I am going to eat the exception, normally this
    //exception should be handled and the message saved to display to 
    //the user.
  end;
end;

Si vous voulez que le système de simplement soulever l'exception, alors il n'y a pas de raison d'en faire une fonction en premier lieu.

uses Classes, XMLIntf, XMLDoc, SysUtils;

procedure ValidateXMLDoc(aXmlDoc: IXMLDocument);
var
  validateDoc: IXMLDocument;
begin
  validateDoc := TXMLDocument.Create(nil);
  validateDoc.ParseOptions := [poResolveExternals, poValidateOnParse];
  validateDoc.XML := aXmlDoc.XML;
  validateDoc.Active := true;
end;

Parce que validateDoc est une interface, il sera disposé de manière que la fonction/procédure s'arrête, il n'est pas nécessaire d'effectuer la disposition de vous-même. Si vous appelez ValidateXmlDoc et n'obtenez pas une exception, il est valable. Personnellement, j'aime bien le premier appel, IsValidXMLDoc qui renvoie true si les valide ou false si pas (et ne pas soulever des exceptions à l'extérieur de lui-même).

Je ne peux pas obtenir que cela fonctionne. Je reçois un "identificateur non déclaré" erreur de TXMLDocument. Ai-je besoin d'importer quelque chose d'autre que msxml pour obtenir que cela fonctionne?
Vous devez utiliser le XMLDoc unité aswell.

OriginalL'auteur skamradt

J'ai travaillé sur les Miels solution pour résoudre le disadventage. J'ouvre le xml, une fois pour obtenir les espaces de noms, et de l'autre, après avoir créer le schéma de collecte, pour valider le fichier. Il fonctionne pour moi.
Il semble que le IXMLDOMDocument2, une fois ouvert, n'accepte de définir la propriété schémas.

function TForm1.ValidXML2(const xmlFile: String;
  out err: IXMLDOMParseError): Boolean;
var
  xml, xml2, xsd: IXMLDOMDocument2;
  schemas, cache: IXMLDOMSchemaCollection;
begin
  xml := CoDOMDocument.Create;
  if xml.load(xmlFile) then
    begin
    schemas := xml.namespaces;
    if schemas.length > 0 then
      begin
      xsd := CoDOMDocument40.Create;
      xsd.Async := False;
      xsd.load(schemas.namespaceURI[0]);
      cache := CoXMLSchemaCache40.Create;
      cache.add(schemas.namespaceURI[1], xsd);
      xml2 := CoDOMDocument40.Create;
      xml2.async := False;
      xml2.schemas := cache;
      Result := xml2.load(xmlFile);
      //err := xml.validate;
      if not Result then
        err := xml2.parseError
      else
        err := nil;
      end;
    end;

OriginalL'auteur Luis Enrique

J'ai déjà validé des documents XML en utilisant le code suivant:

Uses
  Classes, 
  XMLIntf, 
  SysUtils;

Function ValidateXMLDoc(aXmlDoc: IXMLDocument): boolean;
var
  validateDoc: IXMLDocument;
begin
  validateDoc := TXMLDocument.Create(nil);

  validateDoc.ParseOptions := [poResolveExternals, poValidateOnParse];
  validateDoc.XML := aXmlDoc.XML;

  validateDoc.Active := true;
  Result := True;
end;

OriginalL'auteur BennyBechDk

Vous devez vous connecter pour publier un commentaire.