L'accès à une Base de données SQLite en VBA dans Excel

J'ai été l'ajout d'une base de données MS Access pour VBA afin de procéder à une analyse des navires. Toutefois, la base de données a maintenant changé pour SQlite, dont je n'ai aucune idée de comment accéder à partir de VBA. J'ai essayé de l'utilisation de GitHub SQLiteForExcel, mais je ne comprends pas comment il fonctionne, même avec les exemples. Le code que j'ai pour accéder à la base de données Access est ci-dessous: (la db_path est le lien hypertexte à ma base de données Access)

Sub query_db()

On Error GoTo Errorhandler
Dim v_db As DAO.Database
Dim rst As DAO.Recordset
Dim vessels_db As Variant
Dim strSQL As String
Dim i As Long
Dim ws As Worksheet

Set ws = Worksheets("results")
ws.Select

vessels_db = [db_path]
Set v_db = OpenDatabase(vessels_db)


Worksheets("results").Select
[x_0].Select
Range(Selection, Selection.Offset(40000, 1)).ClearContents

strSQL = " SELECT Vessels.vsl_name, Vessels.dwt FROM Vessels " & _
          " GROUP BY Vessels.vsl_name, Vessels.dwt ORDER BY Vessels.vsl_name ; "
Set rst = v_db.OpenRecordset(strSQL)
...

Quelqu'un a une idée de comment je peux modifier ce code à l'aide de SQLiteForExcel afin que je puisse accéder à la base de données SQLite.

Merci beaucoup à l'avance

Je voudrais le convertir en ADO - il y a exemples. Vous pouvez trouver SQLite chaînes de connexion ici.

InformationsquelleAutor Ollie | 2017-02-28

13

MS Access " défaut moteur, Jet/ACE, et SQLite partager la même qualité qu'ils sont au niveau des fichiers de bases de données où les fichiers de base de données résident au niveau des disques dans des répertoires, par opposition à un serveur de bases de données (SQL Server, Oracle, MySQL, Postgres).

À la fluidité des échanges entre bases de données principales, envisager de connecter des bases de données dans Excel à l'aide d'ADO. Droit maintenant, vous utilisez DAO qui est la valeur par défaut de la connexion de la couche pour MS Access.

La première chose que vous avez besoin est de télécharger un SQLite Pilote ODBC, celui qui correspond à votre version (SQLite 3 le plus probable) et votre niveau de bits de Windows (32/64 bits). En comparaison, votre machine le plus probable a déjà installé un MS Access ODBC Driver. Une fois terminé, il suffit de configurer votre chaîne de connexion:

SQLite
```
Dim conn As Object, rst As Object

Set conn = CreateObject("ADODB.Connection")
Set rst = CreateObject("ADODB.Recordset")

' OPEN CONNECTION
conn.Open "DRIVER=SQLite3 ODBC Driver;Database=C:\Path\To\SQLite\Database.db;"

strSQL = "SELECT Vessels.vsl_name, Vessels.dwt FROM Vessels " & _
         " GROUP BY Vessels.vsl_name, Vessels.dwt ORDER BY Vessels.vsl_name ; "

' OPEN RECORDSET
rst.Open strSQL, conn

' OUTPUT TO WORKSHEET
Worksheets("results").Range("A1").CopyFromRecordset rst
rst.Close

' FREE RESOURCES
Set rst = Nothing: Set conn = Nothing
```
MS Access

Comme la comparaison, avec ADO vous pouvez tout simplement l'interrupteur de chaînes de connexion de référencement, le Pilote ODBC pour la base de données différents backends. Avis, comme ci-dessus, la base de données source est un chemin d'accès au répertoire:
```
Dim conn As Object, rst As Object

Set conn = CreateObject("ADODB.Connection")
Set rst = CreateObject("ADODB.Recordset")

' OPEN CONNECTION
conn.Open "DRIVER={Microsoft Access Driver (*.mdb, *.accdb)};DBQ=C:\Path\To\Access\DB.accdb;"

strSQL = "SELECT Vessels.vsl_name, Vessels.dwt FROM Vessels " & _
         " GROUP BY Vessels.vsl_name, Vessels.dwt ORDER BY Vessels.vsl_name ; "

' OPEN RECORDSET
rst.Open strSQL, conn

' OUTPUT TO WORKSHEET
Worksheets("results").Range("A1").CopyFromRecordset rst
rst.Close

' FREE RESOURCES
Set rst = Nothing: Set conn = Nothing
```
InformationsquelleAutor Parfait

Grande solution, merci Parfait!

Juste une petite correction rapide, vous avez réellement besoin de faire:

rst.Open strSQL, conn, 1, 1

De cette façon, la solution complète serait:

Dim conn As Object, rst As Object

Set conn = CreateObject("ADODB.Connection")
Set rst = CreateObject("ADODB.Recordset")

' OPEN CONNECTION
conn.Open "DRIVER=SQLite3 ODBC Driver;Database=C:\Path\To\SQLite\Database.db;"

strSQL = "SELECT Vessels.vsl_name, Vessels.dwt FROM Vessels GROUP BY Vessels.vsl_name, Vessels.dwt ORDER BY Vessels.vsl_name ;"

' OPEN RECORDSET
rst.Open strSQL, conn, 1, 1

' OUTPUT TO WORKSHEET
Worksheets("results").Range("A1").CopyFromRecordset rst
rst.Close

' FREE RESOURCES
Set rst = Nothing: Set conn = Nothing

Cela fera de la tvd contenir la totalité de la table que vous avez obtenu à partir de la requête.

InformationsquelleAutor pcamadini

Vous devez vous connecter pour publier un commentaire.