L'aide OU les fonctions Logiques avec SUMIFS dans Excel

J'ai deux classeurs dans excel qui je copie les colonnes de l'un à l'autre.
Je voudrais copier le numéro d'une colonne, dire, SI une autre colonne, disons B, est égal à "Outil de Test" ou "Dur Outil". J'ai écrit ce code et ne peut pas le faire fonctionner, il me donne juste la somme zéro, ce qui est faux. Le dernier argument n'a pas d'importance, donc l'ignorer.

"=SUMIFS('Tooling forecast template'!R6C17:R500C17,'Tooling forecast template'!R6C7:R500C7,""OR(=Test Tool, =Hard Tool)"" ,'Tooling forecast template'!R6C6:R500C6,""<>Actual tool/equipment change"")"
  • Les Questions sont plus faciles à digérer si simplifié à leurs éléments essentiels. Un équivalent exemple qui saute la feuille de références, utilise de plus simple, les références de cellule, et évite inutilisés arguments est préférable.
InformationsquelleAutor Jonas | 2011-07-26
  1. 2
     =IF(OR(CellToCheck="Test Tool", CellToCheck="Hard Tool"), CellToCopy, 0)
    • Ok, alors comment voulez-vous insérer ce code dans la mienne? J'ai un SUMIFS fonction.
    • Mettre cette fonction dans une autre colonne (masqué si vous le souhaitez) - et puis pointez l'SUMIFs expression de la nouvelle colonne
    • Bien sûr, ce n'était pas exactement ce que je cherchais, mais je pense que son plus proche à la solution que je peux entrer, je vous donne la bonne réponse.
    InformationsquelleAutor BonyT
  2. 4

    Voici une méthode qui vous permet d'économiser de taper un grand nombre de SUMIF états, bien qu'il ne s'arrête pas Excel avoir à calculer les multiples SUMIFs...

    =SUM( SUMIFS('Tooling forecast template'!R6C17:R500C17,'Tooling forecast template'!R6C7:R500C7, {"Test Tool", "Hard Tool"} ,'Tooling forecast template'!R6C6:R500C6,"<>Actual tool/equipment change") )

    Fondamentalement, vous devez calculer la SUMIF avec un tableau de valeurs à vos critères, puis les envelopper que SUMIF une SOMME de sorte que les réponses multiples sont additionnés.

    Cet exemple est assez difficile à lire à cause de la longueur des noms de variables. Voici un exemple simple, où vous voulez ajouter des numéros de la lettre correspondante est soit A soit B...

    Le chemin le plus long:

    =SUMIFS(B1:B5, A1:A5, "A") + SUMIFS(B1:B5, A1:A5, "B")

    Le chemin court:

    =SUM( SUMIFS(B1:B5, A1:A5, {"A","B"}) )
    InformationsquelleAutor Iain S
  3. 2

    Il suffit d'ajouter les deux SUMIFS ensemble, c'est la même chose!

    =SUMIFS('Tooling forecast template'!R6C17:R500C17,'Tooling forecast template'!R6C7:R500C7,"=Test Tool" ,'Tooling forecast template'!R6C6:R500C6,"<>Actual tool/equipment change") + SUMIFS('Tooling forecast template'!R6C17:R500C17,'Tooling forecast template'!R6C7:R500C7,"=Hard Tool" ,'Tooling forecast template'!R6C6:R500C6,"<>Actual tool/equipment change")
    • Merci mais qu'est ce que je cherche à éviter 🙂
    • La raison pour laquelle je veux éviter c'est parce que je vais en ajouter un de plus OU de fonction dans le SUMIFS et je n'aime pas les 4 SUMIFS 🙂 j'ai cette fonction 107 fois! 4*107 = mauvais
    InformationsquelleAutor klonq
  4. 1

    Utiliser le fait que A OU B est la même chose que de ne PAS ((NON A) et (NON B)). Par exemple, la somme des entrées dans Un si B=1 ou C=1 à l'aide de SUMIFS:

    =SUM(A1:A10) - SUMIFS(A1:A10,B1:B10,"<>0",C1:C10,"<>0")

    Vous pouvez obtenir le même résultat avec SUMPRODUCT:

    =SUM(A1:A10) - SUMPRODUCT(A1:A10,--(B1:B10<>0),--(C1:C10<>0))
    InformationsquelleAutor kalu
  5. 0

    Ne serait-ce pas le travail aussi bien?

    Note:
    En supposant que le Col d'Une des maisons les valeurs pour être additionnées.
    En supposant que le Col B maisons de l'outil de types.

    =SUM(SUMIFS(A:A,B:B,"hard tool"),SUMIFS(A:A,B:B,"test tool"))
    • Cela ne fonctionne pas si les conditions proviennent de différentes colonnes et il y a chevauchement entre les deux. Aussi, il n'est pas très compact en général, surtout si vous avez des 20 catégories à combiner.
    InformationsquelleAutor Prej1