Laisser les guillemets lors de la copie à partir de la cellule

J'ai juste eu ce problème et l'emballage de chaque cellule avec la CLEAN de fonction fixes pour moi. Cela devrait être relativement facile à faire en faisant =CLEAN(, la sélection de votre cellule, puis autofilling le reste de la colonne. Après je l'ai fait, colle dans le bloc-notes ou tout autre programme n'avait plus de double quotes.

Si vous souhaitez sélectionner plusieurs cellules et de copier leurs valeurs dans le presse-papiers sans tous ces ennuyeux cite le code suivant peut être utile. C'est une amélioration du code donné ci-dessus à partir de user3616725.

Sub CopyCells()
 'Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
 'Then set a keyboard shortcut to the CopyCells Macro (eg Crtl T)
 Dim objData As New DataObject
 Dim cell As Object
 Dim concat As String
 Dim cellValue As String
 CR = ""
  For Each cell In Selection
  If IsNumeric(cell.Value) Then
   cellValue = LTrim(Str(cell.Value))
  Else
   cellValue = cell.Value
  End If
  concat = concat + CR + cellValue
  CR = Chr(13)
 Next
 objData.SetText (concat)
 objData.PutInClipboard
End Sub

Possible problème par rapport à la réponse "user3616725":

Im sur Windows 8.1 et il semble y avoir un problème avec le lié du code VBA de accepté de la réponse "user3616725":

Sub CopyCellContents()
 ' !!! IMPORTANT !!!:
 ' CREATE A REFERENCE IN THE VBE TO "Microsft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 ' DO THIS BY (IN VBA EDITOR) CLICKING TOOLS -> REFERENCES & THEN TICKING "Microsoft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 Dim objData As New DataObject
 Dim strTemp As String
 strTemp = ActiveCell.Value
 objData.SetText (strTemp)
 objData.PutInClipboard
End Sub

Détails:

L'exécution de code ci-dessus et coller le presse-papier dans une cellule dans Excel j'obtiens deux symboles composé de carrés avec un point d'interrogation à l'intérieur, comme ceci: ⍰⍰. Les coller dans le bloc-notes n'a même pas montrer quoi que ce soit.

Solution:

Après avoir cherché pendant un certain temps, j'ai trouvé un autre script VBA à partir d'utilisateur "Nepumuk" ce qui rend l'utilisation de l'API Windows. Voici son code qui a finalement fonctionné pour moi:

Option Explicit

Private Declare Function OpenClipboard Lib "user32.dll" ( _
    ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function SetClipboardData Lib "user32.dll" ( _
    ByVal wFormat As Long, _
    ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32.dll" ( _
    ByVal wFlags As Long, _
    ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" ( _
    ByVal lpStr1 As Any, _
    ByVal lpStr2 As Any) As Long

Private Const CF_TEXT As Long = 1&

Private Const GMEM_MOVEABLE As Long = 2

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Private Sub StringToClipboard(strText As String)
    Dim lngIdentifier As Long, lngPointer As Long
    lngIdentifier = GlobalAlloc(GMEM_MOVEABLE, Len(strText) + 1)
    lngPointer = GlobalLock(lngIdentifier)
    Call lstrcpy(ByVal lngPointer, strText)
    Call GlobalUnlock(lngIdentifier)
    Call OpenClipboard(0&)
    Call EmptyClipboard
    Call SetClipboardData(CF_TEXT, lngIdentifier)
    Call CloseClipboard
    Call GlobalFree(lngIdentifier)
End Sub

À utiliser de la même façon comme le premier code VBA à partir de ci-dessus, les Sous "Beispiel()" de l':

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

À:

Sub CopyCellContents()
    Call StringToClipboard(ActiveCell.Value)
End Sub

Et de l'exécuter via une macro Excel menu comme suggéré de "user3616725" de accepté de répondre:

De retour dans Excel, allez dans Outils>Macro>les Macros et sélectionnez la macro appelée
"CopyCellContents" et puis choisissez les Options dans la boîte de dialogue. Ici, vous
peut affecter la macro à une touche de raccourci (par exemple, Ctrl+c normal
copie) - j'ai utilisé Ctrl+q.

Ensuite, lorsque vous souhaitez copier une cellule unique sur le bloc-notes et où,
juste faire Ctrl+q (ou de ce que vous avez choisi) puis faire un Ctrl+v ou
Edit>Coller dans votre choix de destination.

Modifier (21 novembre en 2015):

@ commentaire de "dotctor":

Non, sérieusement n'est pas une question! À mon avis c'est un bon complément pour la accepté de répondre que ma réponse se penche sur les problèmes que vous pouvez rencontrer lors de l'utilisation du code à partir de la accepté de répondre. Si j'aurais le plus de réputation, j'aurais créé un commentaire.


@ commentaire de "Teepeemm":

Oui, vous êtes de droite, les réponses en commençant avec le titre "Problème:" sont trompeuses. Changé: "problème Possible par rapport à la réponse "user3616725":". Comme un commentaire, j'aurais certainement écrit beaucoup plus compact.

À conserver les sauts de ligne lors de la coller dans le bloc-notes, remplacez cette ligne dans la macro:

strTemp = ActiveCell.Value

par:

strTemp = Replace(ActiveCell.Value, Chr(10), vbCrLf)

Vous pouvez le faire dans une macro Excel via VBA, envoyer les résultats vers un fichier:

Sub SimpleVBAWriteToFileWithoutQuotes()
    Open "c:\TEMP\Excel\out.txt" For Output As #1
    Print #1, Application.ActiveSheet.Cells(2, 3)
    Close #1
End Sub

Et si vous êtes désireux d'obtenir des noms de fichier et le contenu en plusieurs fichiers, voici un court extrait qui évite les doubles guillemets autour de la sortie.

Sub DumpCellDataToTextFilesWithoutDoubleQuotes()
    ' this will work for filename and content in two different columns such as:
    ' filename column       data column
    ' 101                   this is some data
    ' 102                   this is more data

    Dim rngData As Range
    Dim strData As String
    Dim strTempFile As String
    Dim strFilename As String
    Dim i As Long
    Dim intFilenameColumn As Integer
    Dim intDataColumn As Integer
    Dim intStartingRow As Integer

    intFilenameColumn = 1     ' the column number containing the filenames
    intDataColumn = 3         ' the column number containing the data
    intStartingRow = 2        ' the row number to start gathering data


    For i = intStartingRow To Range("A1", Range("A1").End(xlDown)).Rows.Count

        ' copy the data cell's value
        Set rngData = Application.ActiveSheet.Cells(i, intDataColumn)

        ' get the base filename
        strFilename = Application.ActiveSheet.Cells(i, intFilenameColumn)

        ' assemble full filename and path
        strTempFile = "w:\TEMP\Excel\" & strFilename & ".txt"

        ' write to temp file
        Open strTempFile For Output As #1
        Print #1, rngData
        Close #1

    Next i

    ' goto home cell
    Application.ActiveSheet.Cells(1, 1).Select
    Range("A1").ClearOutline
End Sub