L'API Google Maps pour le Temps et la Distance de Données (Access/VBA)

J'ai une application dans laquelle il serait très avantageux d'être en mesure
pour obtenir directement à partir de google maps, le temps et les km (conduite km)
entre deux adresses. J'ai labouré par de nombreux sites web et
documents et totalement rousseurs quant à la façon de le faire.

Quelqu'un a fait le succès de la connexion avec l'API google maps à l'aide de
Microsoft Approche et des extraits de temps et de distance? Si
ont, o ils pourraient partager le code qu'ils ont utilisé.

Je suis en train de mettre en place un pilote de système de planification d'un bénévole
les pilotes du groupe (de conduite pour les personnes wo rendez-vous médicaux qui ne peuvent pas
en voiture, ne peut pas se permettre des taxis et ne peut pas se permettre de voitures!).

Toute aide serait appréciée

John Baker

OriginalL'auteur user1327936 | 2012-04-12

  1. 8

    Voici un peu de code pour faire ce que vous voulez faire. Ne compte que Google n'ont certaines exigences d'octroi de licences/limitations sur l'utilisation de leur API. Vous êtes censé utiliser les résultats obtenus ici dans une Carte Google map. Veuillez lire attentivement les Limites d'Utilisation ici: https://developers.google.com/maps/documentation/directions/

    À noter que cela nécessite une référence à "Microsoft XML, v6.0" à moins de modifier le code pour utiliser la liaison tardive.

    Dim sXMLURL As String
sXMLURL = "http://maps.googleapis.com/maps/api/directions/xml?origin=NY,+NY&destination=Los+Angeles,+CA&sensor=false"

Dim objXMLHTTP As MSXML2.ServerXMLHTTP
Set objXMLHTTP = New MSXML2.ServerXMLHTTP

With objXMLHTTP
    .Open "GET", sXMLURL, False
    .setRequestHeader "Content-Type", "application/x-www-form-URLEncoded"
    .Send
End With

'Debug.Print objXMLHTTP.ResponseText

Dim domResponse as DOMDocument60
Set domResponse = New DOMDocument60
domResponse.loadXML objXMLHTTP.ResponseText
Dim ixnStatus
Set ixnStatus = domResponse.selectSingleNode("//status")

If ixnStatus.Text = "OK" Then
    Dim ixnDistance, ixnDuration
    Set ixnDistance = domResponse.selectSingleNode("/DirectionsResponse/route/leg/distance/text")
    Set ixnDuration = domResponse.selectSingleNode("/DirectionsResponse/route/leg/duration/text")

    Debug.Print "Distance: " & ixnDistance.Text 'Miles
    Debug.Print "Duration: " & ixnDuration.Text 'Days Hours Minutes
End If

Set domResponse = Nothing
Set objXMLHTTP = Nothing

    J'ai volontairement choisi d'utiliser XML au lieu de JSON car VBA n'est pas trop pratique avec JSON, et ne suis pas non plus I. Il existe un module, vous pouvez télécharger souvent désigné comme VBJSON mais il a une petite courbe d'apprentissage, surtout si vous n'avez jamais travaillé avec JSON avant. Je crois que XML est plus "coûteux" (la moins efficace), mais je pense que c'est aussi plus facile de travailler avec Access VBA.

    sMapURL était un artefact. 🙂 Je l'ai enlevé.

    OriginalL'auteur HK1