L'assemblage, l'impression ascii

J'ai un problème avec mon code assembleur. Je veux imprimer numéro mémorisé dans le registre cx, mais quand j'ai essayé de l'imprimer, imprimer de caractères ascii au lieu de l'ascii numéro, j'ai donc décidé d'écrire une procédure pour convertir les caractères ascii dans le fichier ascii de la valeur.
Problème, c'est que lorsque j'essaie d'appeler cette procédure, le programme se bloque et je dois redémarrer dosbox. Personne ne sait quoi de mal avec ce code? Merci.

P4      PROC                
            MOV AX,CX           ;CX = VALUE THAT I WANT TO CONVERT
            MOV BX,10           
    ASC2:
            DIV BX              ;DIV AX/10
            ADD DX,48           ;ADD 48 TO REMAINDER TO GET ASCII CHARACTER OF NUMBER 
            PUSH AX             ;SAVE AX
            MOV AH,2            ;PRINT REMAINDER STORED IN DX
            INT 21H             ;INTERRUP
            POP AX              ;POP AX BACK
            CMP AX,0            
            JZ EXTT             ;IF AX=0, END OF THE PROCEDURE
            JMP ASC2            ;ELSE REPEAT
    EXTT:
            RET
    P4      ENDP

Vous devez effacer DX avant de se diviser. DIV BX divise DX:AX par BX.
En dehors de ce que @user786653 dit, vous avez aussi le problème que vous aurez l'impression que les chiffres dans l'ordre inverse. E. g. 123 figure en tant que 321 avec votre code.

InformationsquelleAutor aron23 | 2013-03-25

4

Quelque chose comme ça pourrait fonctionner mieux pour l'impression d'une valeur décimale (le nouveau code est en minuscules):
```
        mov byte [buffer+9],'$'
        lea si,[buffer+9]

        MOV AX,CX           ;CX = VALUE THAT I WANT TO CONVERT
        MOV BX,10         
ASC2:
        mov dx,0            ; clear dx prior to dividing dx:ax by bx
        DIV BX              ;DIV AX/10
        ADD DX,48           ;ADD 48 TO REMAINDER TO GET ASCII CHARACTER OF NUMBER 
        dec si              ; store characters in reverse order
        mov [si],dl
        CMP AX,0            
        JZ EXTT             ;IF AX=0, END OF THE PROCEDURE
        JMP ASC2            ;ELSE REPEAT
EXTT:
        mov ah,9            ; print string
        mov dx,si
        int 21h
        RET

buffer: resb 10
```
Au lieu de l'impression de chaque personnage directement, il ajoute les caractères dans un tampon dans l'ordre inverse. Pour la valeur 123 il serait ajouter '3' au tampon[8], '2' au tampon[7] et de '1' à tampon[6] - ainsi, si vous imprimez la chaîne de départ au tampon+6, vous obtenez "123".
Je suis l'aide de MSNA de la syntaxe, mais j'espère que ça doit être assez clair.
- Hey! puis-je obtenir de l'aide sur celui-ci? J'ai essayé d'ajouter cette pièce dans mon code, mais il me lance l'erreur undefined var: byte [buffer+9] logique, mais ne peux pas comprendre ce depuis sa de ma première journée de l'apprentissage de l'assemblée, et je suis déjà bloqué à "comment faire pour convertir un nombre décimal en chaîne et l'imprimer sur l'écran"
InformationsquelleAutor Michael
1

Que Michael a écrit dans son code, vous devez effacer de la DX , c'est à dire le mettre à 0, avant de vous diviser.

Mais si vous me demandez, si vous avez seulement besoin d'afficher un nombre de la forme ASCII (pas d'obtenir un smiley quand vous voulez un certain nombre à être affiché). La conversion de la valeur ASCII à l'interne peut être assez gênant.

Pourquoi ne pas simplement utiliser un tableau défini dans le début du programme, qui a toutes les valeurs ASCII des chiffres et de choisir celle qui correspond à l'.

pour eg. DB arr '0123456789'
et de comparer chaque numéro de la position et de l'impression que l'on. Ça fait vraiment longtemps que je l'ai codé en 8086, mais je me souviens à l'aide de cette logique pour un programme qui m'a obligé à imprimer d'une valeur ASCII d'un nombre hexadécimal. J'ai donc utilisé un tableau qui avait 0123456789ABCDEF et il a parfaitement fonctionné.

Juste mes deux cents. Depuis que vous avez voulu seulement le résultat. n'a pas vraiment d'importance comment vous le calculer.

InformationsquelleAutor umayneverknow

Pensé que je devrais poster une mise à jour de cette. Ce post m'a vraiment aidé à sortir la recherche d'un moyen pour obtenir la clé d'entrée pour CLI PHP scripts. Je ne pouvais pas trouver Windows/DOS de la solution de n'importe où, alors j'ai opté pour un programme externe.

Je suis à l'aide d'une très ancienne version de l'a86 à l'assembleur de sorte que le code est assez basique.

( et comment puis-je désactiver l'option "Exécuter" Extrait de Code? )

CSS:

;Key input for scripts that can use some "shell" function.
;Waits for a keypress then returns a string "key:scan"
;if "key" is 0 then you can check "scan" for arrow keys
;or other non-ASCII keys this way.

  mov ah,0
  int 16h

  push ax
  mov ah,0
  mov cx,ax
  call ASC

  mov dx,':'
  call COUT
  pop ax
  shr ax,8
  mov ah,0
  mov cx,ax
  call ASC
  jp EXIT

COUT:
  mov ah,2
  int 21h
  ret

STROUT:			
  mov ah,9 					
  mov dx,si
  int 21h
  ret

ASC:
  mov byte [buffer+9],'$'
  lea si,[buffer+9]
  mov ax,cx
  mov bx,10 

ASC_LOOP:
  mov dx,0
  div bx
  add dx,48
  dec si
  mov [si],dl
  cmp ax,0            
  jz STROUT
  jmp ASC_LOOP

EXIT:
  mov ah,4ch
  int 21h
  ret

buffer: db "          " ; 10 spaces.  no "resb" in my assembler.

Un exemple de script PHP pour tester dans:

HTML:

<?php

function getKey() {
	return shell_exec("getkey.com");
}

print "Press [ESC] to exit.\n\n";

$key = "";
while (ord($key) != 27) {
	$getch = explode(":",getKey());
	$key = chr($getch[0]);
	$scan = $getch[1];
	if (ord($key) != 0) {
		print $key;
	} else {
		print "SCAN:$scan\n";
	}
}

?>

Certes après tout a été dit et fait, j'ai réalisé que j'aurais pu faire la même chose en C++. Mais j'ai appris beaucoup plus sur l'ASM, cette fois.

Donc merci encore a tous!!

InformationsquelleAutor

Voici la bien testé le code pour le nombre d'impression

.186
.model SMALL
.STACK 100h
.data
    HelloMessage db 'Hello World', 13, 10, '$'
    SuperNumber dw 13565
.code

; Writes word number from AX to output
; Usage
; .186
; ....
; mov ax, 13444
; call PRINT_NUMBER

PRINT_NUMBER PROC NEAR  ; Outputs integer word number stored in AX registry. Requires CPU
    ; Save state of registers.
    PUSHA       ; Save all general purpose registers
    PUSH BP     ; We're going to change that.

    ; we need variables

    ; word number;      2 bytes
    ; byte digitsCount; 1 byte

    ; reserving space for variables on stack (3 bytes)
    mov bp, sp; ; bp := address of the top of a stack
    sub sp, 3*8 ; allocate 3 bytes on stack. Addresses of variables will be
            ; number:   WORD PTR [rbp - 2*8]
            ; digitsCount:  BYTE PTR [rbp - 3*8]

    ; Getting digits
    ; number = ax;
    ; digitsCount = 0;
    ; do
    ; {
    ;   push number%10;
    ;   digitsCount++;
    ;   number = number /10;
    ; }
    ; while (number > 0)
    mov WORD PTR [bp - 2*8], ax ; number = ax;
    mov BYTE PTR [bp - 3*8], 0  ; digitsCount = 0;

    getDigits:          ; do
        mov ax, WORD PTR [bp - 2*8]; number/10: ax = number /10, dx: number % 10
        ;cwd
        mov dx, 0
        mov bx, 10
        div bx

        push dx         ; push number%10
        mov WORD PTR[bp - 2*8], ax; number = number/10;
        inc byte PTR[bp - 3*8]  ; digitsCount++;

        cmp WORD PTR[bp - 2*8], 0; compare number and 0
        je getDigitsEnd     ; if number == 0 goto getDigitsEnd
        jmp getDigits       ; goto getDigits;
    getDigitsEnd:

    mov ah, 9
    mov dx, offset HelloMessage
    int 21h


    ;while (digitsCount > 0)
    ;{
    ;   pop digit into ax
    ;   print digit
    ;   digitsCount--;
    ;}
    printDigits:
        cmp BYTE PTR[bp - 3*8], 0; compare digits count and 0
        je printDigitsEnd   ; if digitsCount == 0 goto printDigitsEnd

        pop ax          ; pop digit into al
        add al, 30h     ; get character from digit into al

        mov ah, 0eh     ; wanna print digit!
        int 10h         ; BIOS, do it!

        dec BYTE PTR[bp - 3*8]  ; digitsCount--

        jmp printDigits     ; goto printDigits
    printDigitsEnd:

    ; Deallocate local variables back.
    mov sp, bp

    ; Restore state of registers in reverse order.
    POP BP
    POPA

    ; Exit from procedure.
    RET

PRINT_NUMBER ENDP

start:
    mov ax, @data
    mov ds, ax

    mov ah, 9
    mov dx, offset HelloMessage
    int 21h

    mov ax, 64454   
    call Print_Number

    mov ah, 4ch
    int 21h
end start

InformationsquelleAutor Siarhei Kuchuk

Vous devez vous connecter pour publier un commentaire.