le découpage d'une chaîne de texte en lignes séparées en VBA

Je ne sais pas comment faire pour vous donner un indice qui peut vous aider à ajuster votre macro, donc j'ai codé ce que je pense que vous êtes après.

Vous parler d'écraser les données dans la 2e ou à la 3e rangée, donc je suppose que vous avez plusieurs lignes contenant les données dans ce format. J'ai donc converti votre code dans une boucle qui fonctionne bas de la colonne jusqu'à ce qu'il trouve une ligne vide.

- Je éviter d'écraser les données ci-dessous de la ligne actuelle par l'insertion de lignes que nécessaire.

J'ai changé votre code dans les moyens que je crois que rend le code plus facile à maintenir. J'ai expliqué mes raisons pour
ces changements.

Je n'ai pas expliqué la nouvelle déclarations que j'ai utilisées. Il est généralement facile de regarder une déclaration une fois que vous savez qu'il existe mais ne poser des questions si quelque chose n'est pas clair.

J'espère que cette aide.

Option Explicit
Sub splitcells()
' * With VBA, Integer declares a 16-bit value while Long declares a 32-bit
'   value. 16-bit values require special processing and are slower. So
'   Long is preferred.
' * I do not like variable names such as i.  It does not really matter with
'   a tiny macro but with a larger macro it does.  It does not matter now
'   but it matters when you return to this macro in 6 or 12 months to amend
'   it.  You want to be able to look at variables and immediately know what
'   they are.  I have named variables according to my system.  I am not
'   asking you to like my system but to have a system.  I can return to
'   macros I wrote years ago and immediately recognise all the variables.
Dim InxSplit As Long
' Dim i As Integer
' * Split returns a string array.  A Variant can be hold a string array but
'   access is slower.  Variants can be very useful but only use then when
'   you need the flexibility they offer.
Dim SplitCell() As String
' Dim cell1 As Variant
Dim RowCrnt As Long
' * "Range" operates on the active worksheet.  You are relying on the correct
'   worksheet being active when the macro is called.  Also, when you return
'   to the macro in 6 or 12 months will you remember which worksheet is
'   supposed to be active.  ".Range" operates on the worksheet specified in
'   the With statement.  It doe not matter which worksheet is active and it
'   is absolutely clear which worksheet is the target of this code.
With Worksheets("Sheet1")
RowCrnt = 1         ' The first row containing data.
Do While True
' * I use .Cells(row, column) rather than .Range because it is more
'   convenient when you need to change the row and/or column numbers.
' * Note the column value can be a number or a column identifier.
'   A = 1, B=2, Z=26, AA = 27, etc.  I am not doing arithmetic with
'   the columns so I have used "A" and "B" which I find more
'   meaningful than 1 and 2.
If .Cells(RowCrnt, "A").Value = "" Then
Exit Do
End If
SplitCell = Split(.Cells(RowCrnt, "A").Value, ",")
If UBound(SplitCell) > 0 Then
' The cell contained a comma so this row is to be spread across
' two or more rows.
' Update the current row
.Cells(RowCrnt, "A").Value = SplitCell(0)
' For each subsequent element of the split value, insert a row
' and place the appropriate values within it.
For InxSplit = 1 To UBound(SplitCell)
RowCrnt = RowCrnt + 1
' Push the rest of the worksheet down
.Rows(RowCrnt).EntireRow.Insert
' Select the appropriate part of the original cell for this row
.Cells(RowCrnt, "A").Value = SplitCell(InxSplit)
' Copy the value from column B from the previous row
.Cells(RowCrnt, "B").Value = .Cells(RowCrnt - 1, "B").Value
Next
End If
RowCrnt = RowCrnt + 1
Loop
End With
End Sub