Le filtrage de la Colonne en Fonction de la Portée VBA

Je suis actuellement un travail avec des données à partir d'un ordinateur central, pas contrairement aux données présentées ici. Dans ce cas, tout ce que j'ai sont des chaînes de caractères s'apparente à 100 AAA pour mes critères et mon objectif de l'ensemble de données. J'ai cherché une solution similaire, mais je n'ai pas trouvé directe filtre de l'aire de question pour VBA sur DONC.

J'essaie de filtrer un grand jeu de données basé sur un ensemble de critères. A l'origine, j'ai commencé à jouer avec des collections dans des classes séparées ou sous-programmes, mais ensuite j'ai compressé à l'utilisation des plages dans un seul sous-programme, comme suit:

Sub FilterTest1()

Dim RngOne As Range
Dim LastCell As Long

Sheets("Criteria").Activate
Sheets("Criteria").Select
Range("A1").Select

LastCell = Application.WorksheetFunction.CountA(ActiveSheet.Range("A:A"))

Set RngOne = ActiveSheet.Range("A2:A" & LastCell)

Sheets("Sheet 1").Activate
Sheets("Sheet 1").Select

With ActiveSheet
    If .FilterMode Then
    .ShowAllData
    End If
End With

Columns("A:A").Select
Selection.AutoFilter
ActiveSheet.Range("A:A").AutoFilter Field:=1, Criteria1:=RngOne, Operator:=xlOr

End Sub

Malheureusement, ma plage de cellules ne filtre pas les données, même lors de l'utilisation de critères tels que Operator:=xlOr - il simplement l'affichage de la dernière valeur de la cellule utilisée pour les critères. Le code VBA de ne pas échouer, il a juste ne filtre pas correctement en fonction de la plage.

Je suis certain qu'il existe une solution simple, mais je ne peux pas tout voir.

Avez-vous pensez à utiliser ADO de sorte que vous pouvez utiliser les commandes SQL pour faire le filtrage (mais toujours à l'aide d'Excel)? Effectuer une jointure interne entre vos critères et de l'ensemble de données peut adapter le projet de loi
Cette précédente réponse à une question similaire, aide - stackoverflow.com/a/7863452/53614 ? J'utilise ADO sur des machines au travail, où je n'ai pas les droits admin et cela fonctionne bien. YMMV, mais il vaut la peine de donner un coup de feu
Ok; je vais donner un coup de feu pendant le week-end et de voir comment elle se déploie en début de semaine prochaine. Il peut être bien utile pour utiliser ADO pour certains de mes plus grands ensembles de données, comme quoi en s'appuyant sur SQL est susceptible d'exécuter beaucoup plus rapide que dans le long terme. Si ça fonctionne bien, qui désigne un autre +1 pour ta réponse =)

InformationsquelleAutor JackOrangeLantern | 2012-08-08

8

Votre ligne actuelle:
```
ActiveSheet.Range("A:A").AutoFilter Field:=1, Criteria1:=RngOne, Operator:=xlOr
```
est d'essayer de filtrer votre premier champ par un Range objet, non pas par chaque valeur dans la gamme.

J'ai fourni un moyen de le faire ci-dessous, par le chargement de vos valeurs dans un tableau et ensuite passage du tableau à l'critères de filtre.

Quelques points intéressant de noter pour vous aider (et quelqu'un d'autre dans le futur):
- J'ai appris de la syntaxe correcte pour filtrer sur une sélection d'objets à l'aide de l'enregistreur de macro.
- Ce site m'a aidé à apprendre à propos de la matrice de truc: Tableau passe de Critères de Filtre
- J'ai aussi nettoyé votre code afin de le rendre plus efficace et plus rapide, par se débarrasser de l'inutile sélectionnez consolidés et ces. (Pas une grosse affaire pour ce petit bout de code, mais de sortir de cette pratique vous aidera à vous pour de plus grands projets!)
Code Ci-Dessous:
```
Sub FilterTest1()

Dim RngOne As Range, cell As Range
Dim LastCell As Long
Dim arrList() As String, lngCnt As Long

With Sheets("Criteria")
    LastCell = .Range("A" & Sheets("Criteria").Rows.Count).End(xlUp).Row
    Set RngOne = .Range("A2:A" & LastCell)
End With

'load values into an array
lngCnt = 0
For Each cell In RngOne
    ReDim Preserve arrList(lngCnt)
    arrList(lngCnt) = cell.Text
    lngCnt = lngCnt + 1
Next


With Sheets("Sheet 1")

    If .FilterMode Then .ShowAllData

    .Range("A:A").AutoFilter Field:=1, Criteria1:=arrList, Operator:=xlFilterValues

End With

End Sub
```
- Bonjour Scott, je crois que je vois où vous allez avec ce - utiliser un tableau de chaînes de caractères comme des critères plutôt que d'une plage. Comme pour le nettoyage de code - merci beaucoup, je fais régulièrement par le biais de 10 000 lignes à la fois. Cependant, quand j'ai testé ton code, j'ai couru dans une "incompatibilité de type" message d'erreur. Après avoir quitté dans le code et vérifier le reste de la syntaxe du code, il se produit sur la ligne 25: .Range("A:A").AutoFilter Field:=1, Criteria1:=Array(strList), Operator:=xlFilterValues . Faites-vous savez pourquoi cela pourrait être présentes? Le reste du code semble fonctionner correctement.
- Vous avez vu mon édité réponse? J'ai résolu le problème dans mon premier (mais supprimé) post.
- Je vais tester maintenant - je viens de rentrer en. =)
- Testé - une correspondance exacte pour les critères. Il ressemble à un tableau fait le travail très bien. J'avais en gros basculé le cadre de collections, des dictionnaires et des hashsets autant que possible en C# pour des fins de tri, mais les opérations que vous pouvez faire avec les tableaux semblent fonctionner mieux pour VBA. Au fond, j'ai hâte de une forte, générique OO solution, et sera susceptible de poster un Q à cette fin, peut-être sur codereview.stackexchange. Cela dit, votre réponse est excellente, et il fait le travail beaucoup plus rapide que la boucle récursive j'ai utilisé qui s'est écrasé ma feuille excel 😉
InformationsquelleAutor Scott Holtzman
3

Une chose à noter, c'est que le Criteria1 nécessite variables de chaîne de caractères comme argument. Vous pouvez affecter une plage à un tableau puis passer le string tableau des critères. Une autre remarque est que, pour passer d'un tableau à l'critères, à ma connaissance, il y a à être dans une ligne, pas une colonne par exemple. StringArray(0,3) au lieu de StringArray(3,0). C'est pourquoi vous avez été d'obtenir la dernière valeur dans votre gamme. Utilisez simplement Application.Transpose(StringArray) convertir en ligne.

De ce petit bout de code qui fonctionne pour moi, et est facilement étendu à de plus grands tableaux.
```
Sub test()
Dim StringArray(0, 1 To 3) As String 'This is a fixed dimension of an array, you can easily change to dynamic by using the ReDim statement.
ActiveSheet.AutoFilterMode = False 'To reset autofilter

Range("D3:D5").Select

For c = 1 To 3 'Step through the range that you wish to use as the criteria.
StringArray(0, c) = CStr(Selection(c, 1).Value)
Next

Range("A:A").AutoFilter Field:=1, Criteria1:=StringArray, Operator:=xlFilterValues

End Sub
```
- Votre explication est utile et s'ajoute à la accepté de répondre. +1
InformationsquelleAutor Rory

Vous devez vous connecter pour publier un commentaire.