Le format des dates dans une zone de liste déroulante liste déroulante

J'ai créé un userform simple avec une zone de liste déroulante rempli avec une plage de dates (rngWeekList) mais j'ai de sérieux maux de tête à essayer d'obtenir la liste dans la zone de liste déroulante pour apparaître dans "jj-mmm-yy" format. Voici mon code:

Private Sub UserForm_Initialize()

    ' Populate the list with the date range
    ComboBox1.List = Worksheets("Cover").Range("rngWeekList").Value

    ' Set the defulat selection (based off rngWeekIndex)
    ComboBox1.ListIndex = Worksheets("Cover").Range("rngWeekIndex").Value - 1

    ' Format
    ComboBox1 = Format(ComboBox1, "dd-mmm-yy")

End Sub

Private Sub ComboBox1_Change()
    ' Format 
    ComboBox1 = Format(ComboBox1, "dd-mmm-yy")
End Sub

Il gère pour le format de l'élément sélectionné dans la zone de liste déroulante correctement (par exemple, "02-Juil-14") mais quand j'ouvre la liste déroulante, toutes les entrées de la liste affichée dans le format par défaut "m/d/yyyy". Est-il un moyen de modifier la mise en forme pour les entrées de la liste? Il est source de confusion pour les utilisateurs qui sont habitués à voir le jour avant la fin du mois.

Merci d'avance pour votre aide, c'est très apprécié.

Ed

OriginalL'auteur satch-23 | 2014-01-29

  1. 2

    J'ai réussi à le résoudre par une boucle sur chaque élément de la comboboax et la mise en forme (n'hésitez pas à me corriger si il y a une façon plus élégante de le faire!)

    Private Sub UserForm_Initialize()
Dim i As Integer

    ' Populate the list with the date range
    ComboBox1.List = Worksheets("Cover").Range("rngWeekList").Value

    'Format all items
    For i = 0 To ComboBox1.ListCount - 1
        ComboBox1.List(i) = Format(DateValue(ComboBox1.List(i)), "dd-mmm-yy")
    Next i

    ' Set the default selection (based off rngWeekIndex)
    ComboBox1.ListIndex = Worksheets("Cover").Range("rngWeekIndex").Value - 1

End Sub

Private Sub ComboBox1_Change()
    ' Format the selection
    ComboBox1 = Format(ComboBox1, "dd-mmm-yy")
End Sub

    Désolé pour l'affichage, mais j'ai vraiment pensé que j'étais coincé.

    Merci encore,

    Ed

    OriginalL'auteur satch-23