Le meilleur moyen d'obtenir la couleur où une souris a été cliquée dans AS3

J'ai une image (mx) et je veux obtenir le uint du pixel qui a été cliqué.

Des idées?

source d'informationauteur Cameron A. Ellis

  1. 8

    Voici un moyen encore plus simple de mise en œuvre. Tout ce que vous faire est de prendre un instantané de la scène à l'aide de la draw() méthode bitmapData, puis utilisez getPixel() sur le pixel situé sous la souris. L'avantage de ceci est que vous pouvez goûter à tout ce qui a été dessiné à la scène, pas seulement un bitmap.

    import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.events.*;

stage.addEventListener(MouseEvent.CLICK, getColorSample);

function getColorSample(e:MouseEvent):void {
    var bd:BitmapData = new BitmapData(stage.width, stage.height);
    bd.draw(stage);
    var b:Bitmap = new Bitmap(bd);
    trace(b.bitmapData.getPixel(stage.mouseX,stage.mouseX));
}

    Espère que c'est utile!

    Modifier:

    Cette version utilise un seul BitmapDataet supprime l'étape inutile de créer un Bitmap. Si vous êtes d'échantillonnage de la couleur sur MOUSE_MOVE puis c'est essentiel pour éviter des problèmes de mémoire.

    Remarque: si vous utilisez un curseur personnalisé sprite que vous aurez à utiliser un objet autre que l'état, sinon vous allez être d'échantillonnage de la couleur de la custom sprite à la place de ce qui est en dessous.

    import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.events.*;

private var _stageBitmap:BitmapData;

stage.addEventListener(MouseEvent.CLICK, getColorSample);

function getColorSample(e:MouseEvent):void 
{
    if (_stageBitmap == null) {
        _stageBitmap = new BitmapData(stage.width, stage.height);
    }
    _stageBitmap.draw(stage);

    var rgb:uint = _stageBitmap.getPixel(stage.mouseX,stage.mouseY);

    var red:int =  (rgb >> 16 & 0xff);
    var green:int =  (rgb >> 8 & 0xff);
    var blue:int =  (rgb & 0xff);

    trace(red + "," + green + "," + blue);
}
  2. 10

    Quelques minutes sur le BitmapData LiveDoc Page va vous emmener là où vous devez aller. Une fois que vous avez votre image chargée dans un Bitmap variable, vous pouvez accéder à sa propriété BitmapData. Ajouter un De La Souris Cliquez Sur L'Événement Auditeur à l'image et d'utiliser BitmapData::getPixel. L'exemple de la méthode getPixel montre comment convertir le uint réponse rgb, hex code.

    Voici une modification de l'Exemple donné sur le BitmapData page qui a fonctionné pour moi (à l'aide de mxmlc - YMMV):

    package {
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.net.URLRequest;
public class BitmapDataExample extends Sprite {
private var url:String = "santa-drunk1.jpg";
private var size:uint = 200;
private var image:Bitmap;
public function BitmapDataExample() {
configureAssets();
}
private function configureAssets():void {
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
var request:URLRequest = new URLRequest(url);
loader.load(request);
addChild(loader);
}
private function completeHandler(event:Event):void {
var loader:Loader = Loader(event.target.loader);
this.image = Bitmap(loader.content);
this.addEventListener(MouseEvent.CLICK, this.clickListener);
}
private function clickListener(event:MouseEvent):void {
var pixelValue:uint = this.image.bitmapData.getPixel(event.localX, event.localY)
trace(pixelValue.toString(16));
}
}
}
  3. 8

    Ce n'est pas spécifique à la flexion ou mx:l'Image, et permet de saisir une couleur de pixel valeur à partir d'une image bitmap objet dessiné (à condition d'avoir l'autorisation):

    private const bitmapData:BitmapData = new BitmapData(1, 1);
private const matrix:Matrix = new Matrix();
private const clipRect:Rectangle = new Rectangle(0, 0, 1, 1);
public function getColor(drawable:IBitmapDrawable, x:Number, y:Number):uint
{
matrix.setTo(1, 0, 0, 1, -x, -y)
bitmapData.draw(drawable, matrix, null, null, clipRect);
return bitmapData.getPixel(0, 0);
}

    Vous pouvez facilement saisir un pixel de la scène ou de votre mx:l'Image de l'instance. Il est beaucoup plus efficace que le dessin de l'ensemble de la scène (ou de l'objet dessiné), et devrait être assez rapide pour accrocher jusqu'à MouseEvent.MOUSE_MOVE pour un retour visuel instantané.