le script de commandes de sous-programme: Passage d'arguments

Ma compréhension est que, pour obtenir la date à partir d'un fichier passé dans un sous-programme comme un argument, vous devez re-définir cet argument comme une variable à l'intérieur de la sous-routine. Est-ce correct? Ce n'est pas faire, car pour moi, alors je me demande si je ne suis pas entièrement comprendre ce qui se passe. Je peux utiliser le passé en argument dans pratiquement n'importe quel autre sous-routine code, sauf pour la date de l'extraction.

set setupEXE=setup.exe

CALL :SUB_CheckCorrectDate %setupEXE%
GOTO EOF
::----------------------------------

:SUB_CheckCorrectDate
set filename=%1%

:: SUCCESSFUL
for %%x in (%filename%) do set FileDate=%%~tx
@For /F "tokens=1-3 delims=-/" %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A
Set file_Day=%%B
Set file_Year=%%C
)

:: GET ERROR    
for %%x in (%1%) do set FileDate=%%~tx
@For /F "tokens=1-3 delims=-/" %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A
Set file_Day=%%B
Set file_Year=%%C
)    

GOTO:EOF

:: ------------------
:EOF
InformationsquelleAutor Fractal | 2013-09-25
  1. 8

    Utilisation %1 pour accéder à ce paramètre, pas %i%.

    L'argument variables ont les mêmes modificateurs comme POUR les variables, de sorte que vous pouvez utiliser %~t1.

    Pas besoin d'exécuter une commande dans votre POUR /F. Il est plus simple de traiter un littéral de chaîne à l'aide de in ("string").

    Pas besoin de :EOF étiquette. Chaque script est implicite :eof. J'aime utiliser exit /b à la place.

    @echo off
setlocal
set "setupEXE=setup.exe"

call :SUB_CheckCorrectDate "%setupEXE%"
exit /b

::----------------------------------

:SUB_CheckCorrectDate
set "filename=%~1"
for /F "tokens=1-3 delims=-/" %%A in ("%~t1") do ( 
  set "file_Month=%%A"
  set "file_Day=%%B"
  set "file_Year=%%C"
)
exit /b
    • Vous avez ajouté setlocal. Il n'y a pas besoin de endlocal, c'est peut-être faite via le exit commande?
    • Oui, il y a toujours un implicite ENDLOCAL à la fin d'un script ou d'une sous-routine Appelée pour le reste, SETLOCAL qui ont été instancié dans cette routine et n'ont pas encore été terminé. Cela se produit même si une routine ou un script se termine parce qu'il a atteint la fin du fichier, même en l'absence explicite de SORTIE /B.
    • Ah merci, bon à savoir. Sur la page setlocal | Microsoft Docs, ils ont manqué d'ajouter le exit option. Est-ce une nouvelle fonctionnalité? Et, plus important encore, sont les environnements locaux correctement empilés les uns sur les autres?
    • Oui, ils ont de la pile correctement, et le comportement a été conforme depuis l'introduction de SETLOCAL. Et Microsoft batch/cmd.exe la documentation est généralement de la merde - charges de manque d'informations, et parfois tout simplement faux.
    InformationsquelleAutor dbenham
  2. 0

    si vous voulez sérieusement à écrire des scripts batch, vous devez prendre soin de la syntaxe:

    @echo off &setlocal
set "setupEXE=setup.exe"

CALL :SUB_CheckCorrectDate "%setupEXE%"
GOTO EOF
::----------------------------------

:SUB_CheckCorrectDate
set "filename=%~1"

:: SUCCESSFUL
for %%x in ("%filename%") do set "FileDate=%%~tx"
For /F "tokens=1-3 delims=-/" %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A"
    Set "file_Day=%%B"
    Set "file_Year=%%C"
)

:: GET ERROR    
for %%x in ("%~1") do set "FileDate=%%~tx"
For /F "tokens=1-3 delims=-/" %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A"
    Set "file_Day=%%B"
    Set "file_Year=%%C"
)    

GOTO:EOF

:: ------------------
:
    • ...et peut-être aussi prendre soin dans le droit chemin, de retour de sous-routines via exit /b
    • vous voulez sérieusement à écrire des scripts batch, vous devriez ..." utiliser Rem plutôt que des palliatifs, comme :: etc. Downvote en raison de cette mauvaise mentorat préambule.
    InformationsquelleAutor Endoro